| |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Entry Points |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Start the processing to update or insert rows into the table |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Read SYSTSIN and pass control to application program |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Read the ITEMMAST file and update existing or insert new rows into the ITEMRDB1 table |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
End-Of-Job |
| |
|
|
|
|
|
|
|
|
Read a KSDS and update existing or insert new rows into a Relational Data Base Table for Item or Product Information
|
The main program (ITQUP1C1) will read an Indexed file (ITEMMAST) and use this information to update an existing row in a relational data base table (ITEMRDB1). If a row with a matching key does not exist then a new row will be inserted.
Color Associations: The light-green boxes are unique to SIMOTIME Technologies using an IBM Mainframe System or Micro Focus Enterprise Developer.
The light-red boxes are unique to the SIMOTIME Technologies using a Linux, UNIX or Windows System and COBOL Technologies such as Micro Focus.
The light-yellow boxes are SIMOTIME Technologies, Third-party Technologies, decision points or program transitions in the processing logic or program generations.
The light-blue boxes identify the input/output data structures such as Documents, Spreadsheets, Data Files, VSAM Data Sets, Partitioned Data Set Members (PDSM's) or Relational Tables.
The light-gray boxes identify a system function or an informational item.
CMD Member for Windows
The following is the Windows Command file (ITQUP1E1.cmd) that is required to run as a job on a PC using Micro Focus Net Express.
@echo OFF
rem * *******************************************************************
rem * ITQUP1E1.CMD - a Windows Command File *
rem * This program is provided by SimoTime Technologies *
rem * (C) Copyright 1987-2019 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - COBOL with embedded SQL to Update rows in a table
rem * Author - SimoTime Technologies
rem * Date - November 11, 2003
rem * Version - 04.03.12
rem *
rem * This set of programs illustrate the use of embedded SQL in a COBOL
rem * program that Update rows in a Table.
rem *
rem * This technique provides for the use of a single COBOL source
rem * program that will run on ZOS, Windows or Unix.
rem *
rem * This set of programs will run on a Personal Computer with Windows
rem * and Micro Focus Net Express or Mainframe Express.
rem *
rem *
rem * ************
rem * * ITQUP1E1 *
rem * ********cmd*
rem * *
rem * *
rem * ************ ************ ************
rem * * ITEMMAST *-----* ITQUP1C1 *-----* ITEMRDB1 *
rem * *******ksds* ********cbl* ********rdb*
rem * *
rem * *
rem * ************
rem * * EOJ *
rem * ************
echo *
echo * The SQL Server must be started prior to executing this command.
echo *
set CmdName=ITQUP1E1
call ..\Env1BASE %CmdName%
call SimoNOTE "*******************************************************%CmdName%"
call SimoNOTE "Starting JobName %CmdName%"
set ITEMMAST=%DataLib1%\Dyn1\SIMOTIME.DATA.ITEMMAST.DAT
run ITQUP1C1
if errorlevel = 1 set JobStatus=0001
if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
call SimoNOTE "Finished JobName %CmdName%"
goto :End
:EojNOK
call SimoNOTE "ABENDING JobName %CmdName%"
call SimoNOTE "ABENDING Message JobStatus %JobStatus%"
goto :End
:End
if not "%1" == "nopause" pause
JCL Member using IKJEFT01
The following is the mainframe JCL (ITQUP1J1.jcl) that is required to run as a job on an IBM, ZOS Mainframe System, Micro Focus Mainframe Express or Micro Focus Server.
//ITQUP1J1 JOB SIMOTIME,ACCOUNT,CLASS=1,MSGCLASS=0,NOTIFY=CSIP1
//* *******************************************************************
//* This program is provided by SimoTime Technologies *
//* (C) Copyright 1987-2019 All Rights Reserved *
//* Web Site URL: http://www.simotime.com *
//* e-mail: helpdesk@simotime.com *
//* *******************************************************************
//*
//* TEXT - Execute a COBOL program to UPDATE data within a Table.
//* AUTHOR - SimoTime Technologies
//* DATE - January 01, 1989
//*
//* This set of programs illustrate the use of a COBOL program with
//* embedded SQL syntax. This program will UPDATE rows into a table.
//*
//* This set of programs will run on a mainframe under ZOS or on
//* a personal computer running Windows and Mainframe Express (MFE)
//* by Micro Focus.
//*
//* ************
//* * ITQUP1J1 *
//* ********jcl*
//* *
//* *
//* ************
//* * IKJEFT01 *
//* ********dbm*
//* *
//* *
//* ************ ************ ************
//* * ITEMMAST *-----* ITQUP1C1 *-----* ITEMRDB1 *
//* ********ksd* ********cbl* ********rdb*
//* *
//* *
//* ************
//* * EOJ *
//* ************
//*
//* *******************************************************************
//* Step 1 of 1 this is a single step job.
//*
//STEP01 EXEC PGM=IKJEFT01
//ITEMMAST DD DSN=SIMOTIME.DATA.ITEMMAST,DISP=SHR
//SYSPRINT DD SYSOUT=*
//SYSTSPRT DD SYSOUT=*
//SYSOUT DD SYSOUT=*
//SYSTSIN DD *
DSN SYSTEM(XDB1)
RUN PROG(ITQUP1C1)
END
/*
//
COBOL Demonstration Program
The following (ITQUP1C1.cbl) is a sample of the COBOL demonstration program that will update existing rows or insert new rows into a table.
IDENTIFICATION DIVISION.
PROGRAM-ID. ITQUP1C1.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy and modify this software for a *
* non-commercial purpose and without fee is hereby granted, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
*****************************************************************
* This program will read the Item File (originally a VSAM, KSDS
* downloaded to be a Micro Focus Keyed-Indexed file) and insert
* or update rows into a table.
*
* ************
* * ITQUP1J1 *
* ********jcl*
* *
* *
* ************
* * IKJEFT01 *
* ********dbm*
* *
* *
* ************ ************ ************
* * ITEMMAST *-----* ITQUP1C1 *-----* ITEMRDB1 *
* ********ksd* ********cbl* ********rdb*
* *
* *
* ************
* * EOJ *
* ************
*
*****************************************************************
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
* The LINE SEQUENTIAL file organization is Micro Fcus
* syntax for an ASCII/Text file.
SELECT ITEMMAST-FILE ASSIGN to ITEMMAST
ORGANIZATION is indexed
ACCESS MODE is SEQUENTIAL
RECORD KEY is ITEM-NUMBER
FILE STATUS is ITEMMAST-STATUS.
*****************************************************************
DATA DIVISION.
FILE SECTION.
FD ITEMMAST-FILE.
COPY ITEMCB01.
WORKING-STORAGE SECTION.
*****************************************************************
* Data-structure for Title and Copyright...
* ------------------------------------------------------------
01 SIM-TITLE.
05 T1 pic X(11) value '* ITQUP1C1 '.
05 T2 pic X(34) value 'Read KSDS, Update or Insert SQL '.
05 T3 pic X(10) value ' v04.12.14'.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* ITQUP1C1 '.
05 C2 pic X(20) value 'Copyright 1987-2019 '.
05 C3 pic X(28) value ' SimoTime Technologies '.
05 C4 pic X(20) value ' All Rights Reserved'.
01 SIM-THANKS-01.
05 C1 pic X(11) value '* ITQUP1C1 '.
05 C2 pic X(32) value 'Thank you for using this program'.
05 C3 pic X(32) value ' provided from SimoTime Technolo'.
05 C4 pic X(04) value 'gies'.
01 SIM-THANKS-02.
05 C1 pic X(11) value '* ITQUP1C1 '.
05 C2 pic X(32) value 'Please send all inquires or sugg'.
05 C3 pic X(32) value 'estions to the helpdesk@simotime'.
05 C4 pic X(04) value '.com'.
01 ITEMMAST-STATUS.
05 ITEMMAST-STATUS-L pic X.
05 ITEMMAST-STATUS-R pic X.
01 ITEMMAST-EOF pic X value 'N'.
01 ITEMMAST-OPEN-FLAG pic X value 'C'.
01 CSVPUTD1-STATUS.
05 CSVPUTD1-STATUS-L pic X.
05 CSVPUTD1-STATUS-R pic X.
01 CSVPUTD1-OPEN-FLAG pic X value 'C'.
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 TWO-BYTES.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 TWO-BYTES-BINARY redefines TWO-BYTES pic 9(4) comp.
01 IO-STATUS-4 pic 9(4) value 0.
01 IO-STATUS-4A redefines IO-STATUS-4 pic X(4).
*****************************************************************
* Message Buffer used by the Z-DISPLAY-MESSAGE-TEXT routine. *
*****************************************************************
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* ITQUP1C1 '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(68) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
01 MESSAGE-BUFFER-SIZE pic 9(3) value 267.
01 MSG-PTR pic 9(3) value 0.
01 MSG-LEN pic 9(3) value 0.
01 WORK-DATE.
05 WORK-DATE-08 pic X(8).
01 WORK-TIME pic X(8).
01 EDIT-TIMESTAMP.
05 EDIT-DATE pic X(10) value 'yyyy-nn-nn'.
05 filler pic X value '-'.
05 EDIT-TIME pic X(11) value 'nn:nn:nn:nn'.
05 filler pic X(4) value SPACES.
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
* ------------------------------------------------------------
EXEC SQL BEGIN DECLARE SECTION END-EXEC.
EXEC SQL INCLUDE ITEMCQ01 END-EXEC.
EXEC SQL end DECLARE SECTION END-EXEC.
EXEC SQL INCLUDE SQLCA END-EXEC.
*****************************************************************
PROCEDURE DIVISION.
perform Z-POST-COPYRIGHT
perform ITEMMAST-OPEN
perform until ITEMMAST-STATUS not = '00'
perform ITEMMAST-READ
* * If a successful read of the input file
* * and the input item number is not equal to SPACES
* * then create an output.
if ITEMMAST-STATUS = '00'
and ITEM-NUMBER not = SPACES
display ITEM-NUMBER ' - ' ITEM-DESCRIPTION
move ITEM-RECORD to ITQ1-RECORD
perform Z-GET-DATE-AND-TIME
perform ITEMRDB1-SELECT
if SQLCODE = ZERO
perform MOVE-DATA-FOR-UPDATE
perform ITEMRDB1-UPDATE
else
perform MOVE-DATA-FOR-UPDATE
perform ITEMRDB1-INSERT
end-if
end-if
end-perform
perform ITEMMAST-CLOSE
perform Z-THANK-YOU
GOBACK.
*****************************************************************
MOVE-DATA-FOR-UPDATE.
move ITEM-NUMBER to ITQ1-NUMBER
move ITEM-DESCRIPTION to ITQ1-DESCRIPTION
move ITEM-UNIT-OF-MEASURE to ITQ1-UNIT-OF-MEASURE
move ITEM-COST to ITQ1-COST
move ITEM-PRICE to ITQ1-PRICE
move WORK-DATE to ITQ1-LADATE
move WORK-TIME to ITQ1-LATIME
move ZERO to ITQ1-TOKEN
exit.
*****************************************************************
ITEMRDB1-SELECT.
EXEC SQL
SELECT ITQ1_NUMBER,
ITQ1_DESCRIPTION,
ITQ1_UNIT_MEASURE,
ITQ1_COST,
ITQ1_PRICE
INTO :ITQ1-NUMBER,
:ITQ1-DESCRIPTION,
:ITQ1-UNIT-OF-MEASURE,
:ITQ1-COST,
:ITQ1-PRICE
FROM ITEMRDB1
WHERE ITQ1_NUMBER = :ITQ1-NUMBER
END-EXEC
if SQLCODE NOT = ZERO
initialize ITQ1-RECORD
end-if
exit.
*---------------------------------------------------------------*
ITEMRDB1-INSERT.
EXEC SQL
INSERT into ITEMRDB1
(
ITQ1_NUMBER,
ITQ1_DESCRIPTION,
ITQ1_UNIT_MEASURE,
ITQ1_COST,
ITQ1_PRICE,
ITQ1_LADATE,
ITQ1_LATIME,
ITQ1_TOKEN
)
VALUES
(
:ITQ1-NUMBER,
:ITQ1-DESCRIPTION,
:ITQ1-UNIT-OF-MEASURE,
:ITQ1-COST,
:ITQ1-PRICE,
:ITQ1-LADATE,
:ITQ1-LATIME,
:ITQ1-TOKEN
)
END-EXEC
if SQLCODE = 0
display 'INSERTED ON INSERT FOR ITEMMAST '
'SQLCODE = ' SQLCODE
' ITEM = ' ITQ1-NUMBER
else
display 'ABENDING ON INSERT FOR ITEMMAST '
'SQLCODE = ' SQLCODE
' ITEM = ' ITQ1-NUMBER
add 16 to ZERO giving RETURN-CODE
end-if
exit.
*---------------------------------------------------------------*
ITEMRDB1-UPDATE.
EXEC SQL
UPDATE ITEMRDB1
SET ITQ1_NUMBER = :ITQ1-NUMBER,
ITQ1_DESCRIPTION = :ITQ1-DESCRIPTION,
ITQ1_UNIT_MEASURE = :ITQ1-UNIT-OF-MEASURE,
ITQ1_COST = :ITQ1-COST,
ITQ1_PRICE = :ITQ1-PRICE,
ITQ1_LADATE = :ITQ1-LADATE,
ITQ1_LATIME = :ITQ1-LATIME,
ITQ1_TOKEN = :ITQ1-TOKEN
WHERE ITQ1_NUMBER = :ITQ1-NUMBER
END-EXEC.
if SQLCODE = 0
display 'Finished UPDATING of ITEMRDB1 for item '
ITQ1-NUMBER
else
display 'ABENDING OF UPDATE FOR ITEMRDB1 '
'SQLCODE = ' SQLCODE
' ITEM = ' ITQ1-NUMBER
add 16 to ZERO giving RETURN-CODE
end-if
exit.
*****************************************************************
* I/O ROUTINES FOR ITEMMAST... *
*****************************************************************
ITEMMAST-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close ITEMMAST-FILE
if ITEMMAST-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'ITEMMAST-Failure-CLOSE...' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move ITEMMAST-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
ITEMMAST-READ.
read ITEMMAST-FILE
if ITEMMAST-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if ITEMMAST-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'Y' to ITEMMAST-EOF
else
move 'ITEMMAST-Failure-GET...' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move ITEMMAST-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
end-if
exit.
*---------------------------------------------------------------*
ITEMMAST-OPEN.
add 8 to ZERO giving APPL-RESULT.
open input ITEMMAST-FILE
if ITEMMAST-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'O' to ITEMMAST-OPEN-FLAG
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'ITEMMAST-Failure-OPEN...' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move ITEMMAST-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-ROUTINES provide administrative functions *
* for this program. *
*****************************************************************
*
*****************************************************************
* ABEND the program, post a message to the console and issue *
* a STOP RUN. *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-MESSAGE-TEXT
end-if
move 'PROGRAM-IS-ABENDING...' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
add 12 to ZERO giving RETURN-CODE
STOP RUN.
* exit.
*****************************************************************
* Display CONSOLE messages... *
*****************************************************************
Z-DISPLAY-MESSAGE-TEXT.
display MESSAGE-BUFFER upon console
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* four digits. If the full two byte file status is numeric it *
* will display as 00nn. If the 1st byte is a numeric nine (9) *
* the second byte will be treated as a binary number and will *
* display as 9nnn. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
add TWO-BYTES-BINARY to ZERO giving IO-STATUS-4
move IO-STAT1 to IO-STATUS-4A(1:1)
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-4A to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
else
move '0000' to IO-STATUS-4A
move IO-STATUS to IO-STATUS-4A(3:2)
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-4A to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
end-if
exit.
*****************************************************************
Z-GET-DATE-AND-TIME.
accept WORK-DATE from DATE YYYYMMDD
accept WORK-TIME from TIME
move WORK-DATE(1:4) to EDIT-DATE(1:4)
move WORK-DATE(5:2) to EDIT-DATE(6:2)
move WORK-DATE(7:2) to EDIT-DATE(9:2)
move WORK-TIME(1:2) to EDIT-TIME(1:2)
move WORK-TIME(3:2) to EDIT-TIME(4:2)
move WORK-TIME(5:2) to EDIT-TIME(7:2)
move WORK-TIME(7:2) to EDIT-TIME(10:2)
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE upon console
display SIM-COPYRIGHT upon console
exit.
*****************************************************************
Z-THANK-YOU.
display SIM-THANKS-01 upon console
display SIM-THANKS-02 upon console
exit.
*****************************************************************
* This program is provided by: *
* SimoTime Technologies *
* (C) Copyright 1987-2019 All Rights Reserved *
* Web Site URL: http://www.simotime.com *
* e-mail: helpdesk@simotime.com *
*****************************************************************
The COBOL Copy File
The following (ITEMCQ01.cpy) is a sample of the COBOL copy file used to define the table row structure.
*****************************************************************
* ITEMCQ01.CPY - a COBOL Copy File *
* A Item or Product File used by the Demo programs. *
* This is an SQL Declare with primary key and unique index. *
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
EXEC SQL DECLARE ITEMRDB1 TABLE
(
ITQ1_NUMBER CHAR (12) NOT NULL
PRIMARY KEY,
ITQ1_DESCRIPTION CHAR (48) NOT NULL,
ITQ1_QTY_ONHAND INTEGER NOT NULL
WITH DEFAULT,
ITQ1_QTY_ALLOCATED INTEGER NOT NULL
WITH DEFAULT,
ITQ1_UNIT_MEASURE CHAR (16) NOT NULL
WITH DEFAULT,
ITQ1_COST DECIMAL (9, 2) NOT NULL
WITH DEFAULT,
ITQ1_PRICE DECIMAL (9, 2) NOT NULL
WITH DEFAULT,
ITQ1_LADATE CHAR (8) NOT NULL
WITH DEFAULT,
ITQ1_LATIME CHAR (8) NOT NULL
WITH DEFAULT,
ITQ1_TOKEN CHAR (8) NOT NULL
WITH DEFAULT,
ITQ1_D_CODE_1 CHAR (1) NOT NULL
WITH DEFAULT,
ITQ1_D_PERCENT_1 CHAR (7) NOT NULL
WITH DEFAULT
)
END-EXEC.
01 ITQ1-RECORD.
05 ITQ1-NUMBER PIC X(12).
05 ITQ1-DATA.
10 ITQ1-DESCRIPTION PIC X(48).
10 ITQ1-QTY-ONHAND PIC 9(7) COMP.
10 ITQ1-QTY-ALLOCATED PIC 9(7) COMP.
10 ITQ1-UNIT-OF-MEASURE PIC X(16).
10 ITQ1-COST PIC S9(7)V9(2) COMP-3.
10 ITQ1-PRICE PIC S9(7)V9(2) COMP-3.
10 ITQ1-LADATE PIC X(8).
10 ITQ1-LATIME PIC X(8).
10 ITQ1-TOKEN PIC X(3).
10 ITQ1-D-CODE-1 PIC X.
10 ITQ1-D-PERCENT-1 PIC S9(3)V9(4).
* 10 ITQ1-D-CODE-2 PIC X.
* 10 ITQ1-D-PERCENT-2 PIC S9(3)V9(4).
* 10 ITQ1-D-CODE-3 PIC X.
* 10 ITQ1-D-PERCENT-3 PIC S9(3)V9(4).
* 10 FILLER PIC X(375).
*
*** ITEMCQ01 - End-of-Copy File - - - - - - - - - - - ITEMCQ01 *
*****************************************************************
*
Summary
The purpose of this program is to provide examples using embedded SQL in a COBOL program to create, manipulate and delete relational data base tables. This document may be used as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the  icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the  icon.
Explore the Structure and Access Methods of a Relational Table that contains "Item or Product" information. This white paper provides an oveview of the programs available for managing a Relational Table containing Item or Product information.
Explore how to Sequentially Access a Relational Table using a COBOL program with Cursor Processing. This program accesses a Relational Table containing Item or Product information and provides an example of how to use cursor processing to access a table sequentially by key accessing one row at a time.
Explore how to Create a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to create a table and create an index using a unique primary key.
Explore how to Delete a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to delete (or Drop) an index and a table.
Explore how to Insert a row into a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to insert a new row into a table.
Explore how to Update a row in a Relational Table using a COBOL program. This sample accesses a Relational Table containing Item or Product information and shows how to update an existing row within a table.
Explore the SQL Connection for more examples of how to create, manipulate and delete Relational Data Bases. The COBOL programs are written to compile and execute on a Windows System with SQL Server and Micro Focus Enterprise Server or an IBM Mainframe System with DB2.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License.
Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is
The SimoTime Home Page
for access to white papers, program examples and product information. This link requires an Internet Connection
Explore
The Micro Focus Web Site
for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
|
1.
|
Send an e-mail to our helpdesk.
|
|
2.
|
Our telephone numbers are as follows.
|
|
2.1.
|
1 415 763-9430 office-helpdesk
|
|
2.2.
|
1 415 827-7045 mobile
|
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
|
Update or Insert a Row, Item/Product Table, COBOL & EXEC SQL
|
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |
| 