Item/Product Table, COBOL & EXEC SQL
|
Cursor Processing Item/Product Table, COBOL & EXEC SQL |
|
| The SimoTime Home Page |
Introduction
The technique of retrieving data with SQL one row at a time is referred to as cursor processing. This example will show how to process a data base sequentially by key using cursor processing. In the world of programming there are many ways to solve a problem. This suite of programs is provided as a COBOL programming example of one of the possible solutions.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved
CMD, Windows Command File
The following is the Windows Command file (ITQCP1E1.cmd) that is required to run as a job on a PC using Micro Focus Net Express.
@echo OFF
rem * *******************************************************************
rem * ITQCP1E1.CMD - a Windows Command File *
rem * This program is provided by SimoTime Technologies *
rem * (C) Copyright 1987-2019 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - COBOL with embedded SQL for Cursor Processing
rem * Author - SimoTime Technologies
rem * Date - November 11, 2003
rem * Version - 08.07.25
rem *
rem * This set of programs illustrate the use of embedded SQL in a COBOL
rem * program that fetches one row at a time from the item data base. A
rem * sequential file containing one record for each row is created.
rem *
rem * This technique provides for the use of a single COBOL source
rem * program that will run on ZOS, Windows or Unix.
rem *
rem * This set of programs will run on a Personal Computer with Windows
rem * and Micro Focus Net Express or Mainframe Express.
rem *
rem * ************
rem * * ITQCP1E1 *
rem * ********cmd*
rem * *
rem * *
rem * ************ ************ ************
rem * * ITEMRDB1 *-----* ITQCP1C1 *-----* ITEMSEQ1 *
rem * ********rdb* ********cbl* *******rseq*
rem * *
rem * *
rem * ************
rem * * EOJ *
rem * ************
rem *
echo *
echo * The SQL Server must be started prior to executing this command.
echo *
set CmdName=ITQCP1E1
call ..\Env1BASE %CmdName%
call SimoNOTE "*******************************************************%CmdName%"
call SimoNOTE "Starting JobName %CmdName%"
set ITEMSEQ1=%DataLib1%\Dyn1\SIMOTIME.DATA.ITEMSEQ1.DAT
run ITQCP1C1
if errorlevel = 1 set JobStatus=0001
if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
call SimoNOTE "Finished JobName %CmdName%"
goto :End
:EojNOK
call SimoNOTE "ABENDING JobName %CmdName%"
call SimoNOTE "ABENDING Message JobStatus %JobStatus%"
goto :End
:End
if not "%1" == "nopause" pause
rem * End-of-Command-File...
JCL Member
The following is the mainframe JCL (ITQCP1J1.jcl) that is required to run as a job on the mainframe or as a Mainframe Express project on the PC.
//ITQCP1J1 JOB SIMOTIME,ACCOUNT,CLASS=1,MSGCLASS=0,NOTIFY=CSIP1
//* *******************************************************************
//* This JCL member is provided by SimoTime Technologies *
//* (C) Copyright 1987-2019 All Rights Reserved *
//* Web Site URL: http://www.simotime.com *
//* e-mail: helpdesk@simotime.com *
//* *******************************************************************
//*
//* TEXT - Execute COBOL program, use CURSOR Processing of a Table.
//* AUTHOR - SimoTime Technologies
//* DATE - January 01, 1989
//*
//* This set of programs illustrate the use of a COBOL program with
//* embedded SQL syntax. This program will FETCH one row at a time
//* using Cursor Processing.
//*
//* This set of programs will run on a mainframe under ZOS or on
//* a personal computer running Windows and Mainframe Express (MFE)
//* by Micro Focus.
//*
//* ************
//* * ITQCP1J1 *
//* ********jcl*
//* *
//* *
//* ************
//* * IKJEFT01 *
//* ********dbm*
//* *
//* *
//* ************ ************ ************
//* * ITEMRDB1 *-----* ITQCP1C1 *-----* ITEMLIST *
//* ********rdb* ********cbl* ********dat*
//* *
//* *
//* ************
//* * EOJ *
//* ************
//*
/* *******************************************************************
//* Step 1 of 2 Delete any previously created file...
//*
//SEQ1DELT EXEC PGM=IEFBR14
//ITEMSEQ1 DD DSN=SIMOTIME.DATA.ITEMSEQ1,DISP=(MOD,DELETE,DELETE),
// STORCLAS=MFI,
// SPACE=(TRK,5),
// DCB=(RECFM=FB,LRECL=512,BLKSIZE=5120,DSORG=PS)
//* *******************************************************************
//* Step 2 of 2 Start the relational data base step.
//*
//FETCH EXEC PGM=IKJEFT01
//ITEMSEQ1 DD DSN=SIMOTIME.DATA.ITEMSEQ1,DISP=(NEW,CATLG,DELETE),
// STORCLAS=MFI,
// SPACE=(TRK,5),
// DCB=(RECFM=FB,LRECL=512,BLKSIZE=5120,DSORG=PS)
//SYSPRINT DD SYSOUT=*
//SYSTSPRT DD SYSOUT=*
//SYSOUT DD SYSOUT=*
//SYSTSIN DD *
DSN SYSTEM(XDB1)
RUN PROG(ITQCP1C1)
END
/*
//
The COBOL Test Program
The following (ITQCP1C1.cbl) is a sample of the COBOL test program that processes a table one row at a time. The program uses the SQL FETCH statement to sequentially access the rows in the table.
IDENTIFICATION DIVISION.
PROGRAM-ID. ITQCP1C1.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy and modify this software for a *
* non-commercial purpose and without fee is hereby granted, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
*****************************************************************
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
*****************************************************************
SELECT ITEMSEQ1-FILE
ASSIGN to ITEMSEQ1
ORGANIZATION is SEQUENTIAL
ACCESS MODE is SEQUENTIAL
FILE STATUS is ITEMSEQ1-STATUS.
*****************************************************************
DATA DIVISION.
FILE SECTION.
FD ITEMSEQ1-FILE.
COPY ITEMSQ01.
WORKING-STORAGE SECTION.
*****************************************************************
* Data-structure for Title and Copyright...
* ------------------------------------------------------------
01 SIM-TITLE.
05 T1 pic X(11) value '* ITQCP1C1 '.
05 T2 pic X(34) value 'Cursor Processing, Item Data Base '.
05 T3 pic X(10) value ' v04.11.24'.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* ITQCP1C1 '.
05 C2 pic X(20) value 'Copyright 1987-2019 '.
05 C3 pic X(28) value ' SimoTime Technologies '.
05 C4 pic X(20) value ' All Rights Reserved'.
01 SIM-THANKS-01.
05 C1 pic X(11) value '* ITQCP1C1 '.
05 C2 pic X(32) value 'Thank you for using this program'.
05 C3 pic X(32) value ' provided from SimoTime Technolo'.
05 C4 pic X(04) value 'gies'.
01 SIM-THANKS-02.
05 C1 pic X(11) value '* ITQCP1C1 '.
05 C2 pic X(32) value 'Please send all inquires or sugg'.
05 C3 pic X(32) value 'estions to the helpdesk@simotime'.
05 C4 pic X(04) value '.com'.
01 ITEMSEQ1-STATUS.
05 ITEMSEQ1-STAT1 pic X.
05 ITEMSEQ1-STAT2 pic X.
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 TWO-BYTES.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 TWO-BYTES-BINARY redefines TWO-BYTES pic 9(4) comp.
01 END-OF-FILE pic X(3) value 'NO '.
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
*****************************************************************
* Buffer used for posting messages to the console.
* ------------------------------------------------------------
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* ITQCP1C1 '.
05 MESSAGE-TEXT pic X(245).
01 DISPLAY-LINE-01.
05 filler pic X(8) value 'Item #: '.
05 DISPLAY-NUMBER pic X(12) value SPACES.
05 filler pic X(3) value ' - '.
05 DISPLAY-DESCRIPTION pic X(48) value SPACES.
01 FETCH-SUMMARY.
05 filler pic X(19) value 'Data Base FETCH... '.
05 FETCH-COUNT pic 9(7) value 0.
01 ITEMRDB1-EOF pic X value 'N'.
*****************************************************************
EXEC SQL BEGIN DECLARE SECTION END-EXEC.
EXEC SQL
INCLUDE ITEMCQ01
END-EXEC.
EXEC SQL DECLARE ITEMRDB1Cursor Cursor for
SELECT ITQ1_NUMBER,
ITQ1_DESCRIPTION,
ITQ1_UNIT_MEASURE,
ITQ1_COST,
ITQ1_PRICE
FROM ITEMRDB1
END-EXEC
EXEC SQL INCLUDE
SQLCA
END-EXEC.
*****************************************************************
PROCEDURE DIVISION.
perform Z-POST-COPYRIGHT
perform ITEMRDB1-OPEN-CURSOR
perform ITEMSEQ1-OPEN.
perform until ITEMRDB1-EOF not = 'N'
perform ITEMRDB1-FETCH
if ITEMRDB1-EOF = 'N'
move ITQ1-RECORD to ITS1-RECORD
perform ITEMSEQ1-WRITE
end-if
end-perform
perform ITEMSEQ1-CLOSE.
perform ITEMRDB1-CLOSE-CURSOR
move FETCH-SUMMARY to MESSAGE-TEXT
perform Z-POST-MESSAGE
perform Z-THANK-YOU.
GOBACK.
*****************************************************************
ITEMRDB1-OPEN-CURSOR.
EXEC SQL OPEN ITEMRDB1Cursor END-EXEC
evaluate SQLCODE
when 0 move 0 to RETURN-CODE
when +100
move 'Y' to ITEMRDB1-EOF
display '* Finished: End-of-File' upon console
when OTHER
move 'A' to ITEMRDB1-EOF
add 16 to ZERO giving RETURN-CODE
display '* ABENDING: '
SQLCODE
' Error OPEN ITEMRDB1Cursor'
upon console
perform Z-POST-SQL-MESSAGE
end-evaluate
exit.
*---------------------------------------------------------------*
ITEMRDB1-FETCH.
EXEC SQL FETCH ITEMRDB1Cursor
INTO :ITQ1-NUMBER,
:ITQ1-DESCRIPTION,
:ITQ1-UNIT-OF-MEASURE,
:ITQ1-COST,
:ITQ1-PRICE
END-EXEC
evaluate SQLCODE
when 0 move 0 to RETURN-CODE
add 1 to FETCH-COUNT
when +100
move 'Y' to ITEMRDB1-EOF
display '* Finished: End-of-File' upon console
when OTHER
move 'A' to ITEMRDB1-EOF
add 16 to ZERO giving RETURN-CODE
display '* ABENDING: I/O Error' upon console
end-evaluate
exit.
*---------------------------------------------------------------*
ITEMRDB1-CLOSE-CURSOR.
EXEC SQL CLOSE ITEMRDB1Cursor END-EXEC
exit.
*****************************************************************
ITEMSEQ1-GET.
read ITEMSEQ1-FILE
if ITEMSEQ1-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if ITEMSEQ1-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'YES' to END-OF-FILE
end-if
end-if
exit.
*---------------------------------------------------------------*
ITEMSEQ1-WRITE.
write ITS1-RECORD
if ITEMSEQ1-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if ITEMSEQ1-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'YES' to END-OF-FILE
else
move 'ITADDC01 ITEMSEQ1-FAILURE-WRITE...'
to MESSAGE-TEXT
move ITEMSEQ1-STATUS to IO-STATUS
perform Z-POST-MESSAGE
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
end-if
exit.
*---------------------------------------------------------------*
ITEMSEQ1-REWRITE.
REWRITE ITS1-RECORD
if ITEMSEQ1-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if ITEMSEQ1-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'YES' to END-OF-FILE
else
move 'ITADDC01 ITEMSEQ1-FAILURE-REWRITE...'
to MESSAGE-TEXT
move ITEMSEQ1-STATUS to IO-STATUS
perform Z-POST-MESSAGE
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
end-if
exit.
*---------------------------------------------------------------*
ITEMSEQ1-OPEN.
add 8 to ZERO giving APPL-RESULT.
open OUTPUT ITEMSEQ1-FILE
if ITEMSEQ1-STATUS = '35'
move 'ITADDC01 ITEMSEQ1-FAILURE-OPEN-IO...'
to MESSAGE-TEXT
perform Z-POST-MESSAGE
move ITEMSEQ1-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
move 'ITADDC01 ITEMSEQ1-ATTEMPT-OPEN-OUTPUT...'
to MESSAGE-TEXT
perform Z-POST-MESSAGE
open output ITEMSEQ1-FILE
end-if
if ITEMSEQ1-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'ITADDC01 ITEMSEQ1-FAILURE-OPEN...'
to MESSAGE-TEXT
move ITEMSEQ1-STATUS to IO-STATUS
perform Z-POST-MESSAGE
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
ITEMSEQ1-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close ITEMSEQ1-FILE
if ITEMSEQ1-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'ITADDC01 ITEMSEQ1-FAILURE-CLOSE...'
to MESSAGE-TEXT
move ITEMSEQ1-STATUS to IO-STATUS
perform Z-POST-MESSAGE
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative tasks *
* for this program. *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-POST-MESSAGE
end-if
move 'ITADDC01 PROGRAM-IS-ABENDING...' to MESSAGE-TEXT
perform Z-POST-MESSAGE
add 12 to ZERO giving RETURN-CODE
GOBACK.
* exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* two digits if the full two byte file status is numeric. If *
* second byte is non-numeric then it will be treated as a *
* binary number. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
display '* ITADDC01 FILE-STATUS-' IO-STAT1 '/'
TWO-BYTES-BINARY upon console
else
display '* ITADDC01 FILE-STATUS-' IO-STATUS upon console
end-if
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE upon console
display SIM-COPYRIGHT upon console
exit.
*****************************************************************
Z-POST-MESSAGE.
if MESSAGE-BUFFER(81:176) = SPACES
display MESSAGE-BUFFER(1:80) upon console
else
display MESSAGE-BUFFER upon console
end-if
move SPACES to MESSAGE-TEXT
exit.
*****************************************************************
Z-POST-SQL-MESSAGE.
move 'ABENDING: ' to MESSAGE-TEXT
if SQLERRML > 0
and SQLERRML < 71
move SQLERRMC(1:SQLERRML) to MESSAGE-TEXT(11:SQLERRML)
else
move SQLERRMC(1:SQLERRML) to MESSAGE-TEXT(11:70)
end-if
perform Z-POST-MESSAGE
exit.
*****************************************************************
Z-THANK-YOU.
display SIM-THANKS-01 upon console
display SIM-THANKS-02 upon console
exit.
*****************************************************************
* This example is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The COBOL Copy File
The following (ITEMCQ01.cpy) is a sample of the COBOL copy file used to define the table row structure.
*****************************************************************
* ITEMCQ01.CPY - a COBOL Copy File *
* A Item or Product File used by the Demo programs. *
* This is an SQL Declare with primary key and unique index. *
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
EXEC SQL DECLARE ITEMRDB1 TABLE
(
ITQ1_NUMBER CHAR (12) NOT NULL
PRIMARY KEY,
ITQ1_DESCRIPTION CHAR (48) NOT NULL,
ITQ1_QTY_ONHAND INTEGER NOT NULL
WITH DEFAULT,
ITQ1_QTY_ALLOCATED INTEGER NOT NULL
WITH DEFAULT,
ITQ1_UNIT_MEASURE CHAR (16) NOT NULL
WITH DEFAULT,
ITQ1_COST DECIMAL (9, 2) NOT NULL
WITH DEFAULT,
ITQ1_PRICE DECIMAL (9, 2) NOT NULL
WITH DEFAULT,
ITQ1_LADATE CHAR (8) NOT NULL
WITH DEFAULT,
ITQ1_LATIME CHAR (8) NOT NULL
WITH DEFAULT,
ITQ1_TOKEN CHAR (8) NOT NULL
WITH DEFAULT,
ITQ1_D_CODE_1 CHAR (1) NOT NULL
WITH DEFAULT,
ITQ1_D_PERCENT_1 CHAR (7) NOT NULL
WITH DEFAULT
)
END-EXEC.
01 ITQ1-RECORD.
05 ITQ1-NUMBER PIC X(12).
05 ITQ1-DATA.
10 ITQ1-DESCRIPTION PIC X(48).
10 ITQ1-QTY-ONHAND PIC 9(7) COMP.
10 ITQ1-QTY-ALLOCATED PIC 9(7) COMP.
10 ITQ1-UNIT-OF-MEASURE PIC X(16).
10 ITQ1-COST PIC S9(7)V9(2) COMP-3.
10 ITQ1-PRICE PIC S9(7)V9(2) COMP-3.
10 ITQ1-LADATE PIC X(8).
10 ITQ1-LATIME PIC X(8).
10 ITQ1-TOKEN PIC X(3).
10 ITQ1-D-CODE-1 PIC X.
10 ITQ1-D-PERCENT-1 PIC S9(3)V9(4).
* 10 ITQ1-D-CODE-2 PIC X.
* 10 ITQ1-D-PERCENT-2 PIC S9(3)V9(4).
* 10 ITQ1-D-CODE-3 PIC X.
* 10 ITQ1-D-PERCENT-3 PIC S9(3)V9(4).
* 10 FILLER PIC X(375).
*
*** ITEMCQ01 - End-of-Copy File - - - - - - - - - - - ITEMCQ01 *
*****************************************************************
*
Summary
The purpose of this program is to provide examples using embedded SQL in a COBOL program to create, manipulate and delete relational data base tables. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the 
icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the 
icon.
Explore the Structure and Access Methods of a Relational Table that contains "Item or Product" information. This white paper provides an oveview of the programs available for managing a Relational Table containing Item or Product information.
Explore how to Sequentially Access a Relational Table using a COBOL program with Cursor Processing. This program accesses a Relational Table containing Item or Product information and provides an example of how to use cursor processing to access a table sequentially by key accessing one row at a time.
Explore how to Create a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to create a table and create an index using a unique primary key.
Explore how to Delete a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to delete (or Drop) an index and a table.
Explore how to Insert a row into a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to insert a new row into a table.
Explore how to Update a row in a Relational Table using a COBOL program. This sample accesses a Relational Table containing Item or Product information and shows how to update an existing row within a table.
Explore the SQL Connection for more examples of how to create, manipulate and delete Relational Data Bases. The COBOL programs are written to compile and execute on a Windows System with SQL Server and Micro Focus Enterprise Server or an IBM Mainframe System with DB2.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| Item or Product Database, Cursor Processing using a COBOL with Embedded SQL Statements |
| Copyright © 1987-2025 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |