Insert a Row
Item/Product Table, COBOL & EXEC SQL
  Table of Contents  v-18.09.15 - itqin101.htm 
  Introduction
  Programming Requirements
  Programming Overview
  CMD Member for Windows
  JCL Member using IKJEFT01
  COBOL Demonstration Program
  The COBOL Copy File
  Summary
  Software Agreement and Disclaimer
  Downloads and Links
  Current Server or Internet Access
  Internet Access Required
  Glossary of Terms
  Comments or Feedback
  Company Overview
The SimoTime Home Page 

Table of Contents Previous Section Next Section Introduction

This example uses embedded SQL in a COBOL program to INSERT rows into a table of a relational data base table. This example will read a VSAM, Keyed-Sequential-Data-Set (KSDS) to obtain the data that will be loaded into the table. In the world of programming there are many ways to solve a problem. This suite of programs is provided as a COBOL programming example of one of the possible solutions.


We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved

Table of Contents Previous Section Next Section Programming Requirements

This suite of samples programs will run on the following platforms.

1 Executes on Windows/7, Windows/XP or Windows Server using Micro Focus Net Express and the CMD file provided
2 Executes on Windows/7, Windows/XP or Windows Server using Micro Focus Mainframe Express and the JCL member provided.
3 Executes on Windows/7, Windows/XP or Windows Server using Micro Focus Server or Studio and the JCL member provided.
4 Executes on an IBM Mainframe running ZOS and DB/2.
5 May be ported to run on the Linux and UNIX platforms supported by Micro Focus COBOL.
  Systems that support the execution of the Sample Program

Table of Contents Previous Section Next Section Programming Overview

The following diagram is an overview of how the demonstration program fits into the example.

             
Entry Point
ZOS
Entry Point
Windows
Entry Points
   
   
ITQIN1J1
jcl
ITQIN1E1
cmd
Start the processing to insert rows into the table
   
   
 
 
   
   
   
SYSTSIN
instream
 
 
IKJEFT01
utl
   
Read SYSTSIN and pass control to application program
   
   
 
 
   
   
ITEMMAST
ksds
 
 
ITQIN1C1
cbl
 
 
ITEMRDB1
rdb
Read the ITEMMAST file and insert rows into the ITEMRDB1 table
   
EOJ
End-Of-Job
 
Overview of Program to Convert KSDS to a Relational Data Base Table for Item or Product Information

The main program (ITQIN1C1) will read an Indexed file (ITEMMAST) and use this information to insert new rows in a relational data base table (ITEMRDB1).

Color Associations: The  light-green  boxes are unique to SIMOTIME Technologies using an IBM Mainframe System or Micro Focus Enterprise Developer. The  light-red  boxes are unique to the SIMOTIME Technologies using a Linux, UNIX or Windows System and COBOL Technologies such as Micro Focus. The  light-yellow  boxes are SIMOTIME Technologies, Third-party Technologies, decision points or program transitions in the processing logic or program generations. The  light-blue  boxes identify the input/output data structures such as Documents, Spreadsheets, Data Files, VSAM Data Sets, Partitioned Data Set Members (PDSM's) or Relational Tables. The  light-gray  boxes identify a system function or an informational item.

Table of Contents Previous Section Next Section CMD Member for Windows

The following is the Windows Command file (ITQIN1E1.cmd) that is required to run as a job on a PC using Micro Focus Net Express.

@echo OFF
rem  * *******************************************************************
rem  *               ITQIN1E1.CMD - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text    - COBOL with embedded SQL to Insert rows into a table
rem  * Author  - SimoTime Technologies
rem  * Date    - November 11, 2003
rem  * Version - 04.03.12
rem  *
rem  * This set of programs illustrate the use of embedded SQL in a COBOL
rem  * program that Inserts rows into a Table.
rem  *
rem  * This technique provides for the use of a single COBOL source
rem  * program that will run on ZOS, Windows or Unix.
rem  *
rem  * This set of programs will run on a Personal Computer with Windows
rem  * and Micro Focus Net Express or Mainframe Express.
rem  *
rem  *
rem  *                    ************
rem  *                    * ITQIN1E1 *
rem  *                    ********cmd*
rem  *                         *
rem  *                         *
rem  *   ************     ************     ************
rem  *   * ITEMMAST *-----* ITQIN1C1 *-----* ITEMRDB1 *
rem  *   *******ksds*     ********cbl*     ********rdb*
rem  *                         *
rem  *                         *
rem  *                    ************
rem  *                    *   EOJ    *
rem  *                    ************
echo *
echo * The SQL Server must be started prior to executing this command.
echo *
     set CmdName=ITQIN1E1
     call ..\Env1BASE %CmdName%
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting JobName %CmdName%"
     set ITEMMAST=%DataLib1%\Dyn1\SIMOTIME.DATA.ITEMMAST.DAT
     run ITQIN1C1
     if errorlevel = 1 set JobStatus=0001
     if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
     call SimoNOTE "Finished JobName %CmdName%"
     goto :End
:EojNOK
     call SimoNOTE "ABENDING JobName %CmdName%"
     call SimoNOTE "ABENDING Message JobStatus %JobStatus%"
     goto :End
:End
     if not "%1" == "nopause" pause

Table of Contents Previous Section Next Section JCL Member using IKJEFT01

The following is the mainframe JCL (ITQIN1J1.jcl) that is required to run as a job on an IBM, ZOS Mainframe System, Micro Focus Mainframe Express or Micro Focus Server.

//ITQIN1J1 JOB SIMOTIME,ACCOUNT,CLASS=1,MSGCLASS=0,NOTIFY=CSIP1
//* *******************************************************************
//*        This program is provided by SimoTime Technologies          *
//*           (C) Copyright 1987-2019 All Rights Reserved             *
//*             Web Site URL:   http://www.simotime.com               *
//*                   e-mail:   helpdesk@simotime.com                 *
//* *******************************************************************
//*
//* TEXT   - Execute a COBOL program to INSERT data into a Table.
//* AUTHOR - SimoTime Technologies
//* DATE   - January 01, 1989
//*
//* This set of programs illustrate the use of a COBOL program with
//* embedded SQL syntax. This program will insert rows into a table.
//*
//* This set of programs will run on a mainframe under ZOS or on
//* a personal computer running Windows and Mainframe Express (MFE)
//* by Micro Focus.
//*
//*                    ************
//*                    * ITQIN1J1 *
//*                    ********jcl*
//*                         *
//*                         *
//*                    ************
//*                    * IKJEFT01 *
//*                    ********dbm*
//*                         *
//*                         *
//*   ************     ************     ************
//*   * ITEMMAST *-----* ITQIN1C1 *-----* ITEMRDB1 *
//*   ********ksd*     ********cbl*     ************
//*                         *
//*                         *
//*                    ************
//*                    *   EOJ    *
//*                    ************
//*
//* *******************************************************************
//* Step   1 of 1  this is a single step job.
//*
//STEP01   EXEC PGM=IKJEFT01
//ITEMMAST DD  DSN=SIMOTIME.DATA.ITEMMAST,DISP=SHR
//SYSPRINT DD  SYSOUT=*
//SYSTSPRT DD  SYSOUT=*
//SYSOUT   DD  SYSOUT=*
//SYSTSIN  DD  *
  DSN SYSTEM(XDB1)
      RUN PROG(ITQIN1C1)
  END
/*
//

Table of Contents Previous Section Next Section COBOL Demonstration Program

The following (ITQIN1C1.cbl) is a sample of the COBOL demonstration program that will insert rows into a table.

       IDENTIFICATION DIVISION.
       PROGRAM-ID.    ITQIN1C1.
       AUTHOR.        SIMOTIME TECHNOLOGIES.
      *****************************************************************
      * Copyright (C) 1987-2019 SimoTime Technologies.                *
      *                                                               *
      * All rights reserved.  Unpublished, all rights reserved under  *
      * copyright law and international treaty.  Use of a copyright   *
      * notice is precautionary only and does not imply publication   *
      * or disclosure.                                                *
      *                                                               *
      * Permission to use, copy, modify and distribute this software  *
      * for any commercial purpose requires a fee to be paid to       *
      * SimoTime Technologies. Once the fee is received by SimoTime   *
      * the latest version of the software will be delivered and a    *
      * license will be granted for use within an enterprise,         *
      * provided the SimoTime copyright notice appear on all copies   *
      * of the software. The SimoTime name or Logo may not be used    *
      * in any advertising or publicity pertaining to the use of the  *
      * software without the written permission of SimoTime           *
      * Technologies.                                                 *
      *                                                               *
      * Permission to use, copy and modify this software for a        *
      * non-commercial purpose and without fee is hereby granted,     *
      * provided the SimoTime copyright notice appear on all copies   *
      * of the software. The SimoTime name or Logo may not be used    *
      * in any advertising or publicity pertaining to the use of the  *
      * software without the written permission of SimoTime           *
      * Technologies.                                                 *
      *                                                               *
      * SimoTime Technologies makes no warranty or representations    *
      * about the suitability of the software for any purpose. It is  *
      * provided "AS IS" without any expressed or implied warranty,   *
      * including the implied warranties of merchantability, fitness  *
      * for a particular purpose and non-infringement. SimoTime       *
      * Technologies shall not be liable for any direct, indirect,    *
      * special or consequential damages resulting from the loss of   *
      * use, data or projects, whether in an action of contract or    *
      * tort, arising out of or in connection with the use or         *
      * performance of this software                                  *
      *                                                               *
      * SimoTime Technologies                                         *
      * 15 Carnoustie Drive                                           *
      * Novato, CA 94949-5849                                         *
      * 415.883.6565                                                  *
      *                                                               *
      * RESTRICTED RIGHTS LEGEND                                      *
      * Use, duplication, or disclosure by the Government is subject  *
      * to restrictions as set forth in subparagraph (c)(1)(ii) of    *
      * the Rights in Technical Data and Computer Software clause at  *
      * DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of          *
      * Commercial  Computer Software - Restricted Rights  at 48      *
      * CFR 52.227-19, as applicable.  Contact SimoTime Technologies, *
      * 15 Carnoustie Drive, Novato, CA 94949-5849.                   *
      *****************************************************************
      *        This base program was generated by SimoZAPS            *
      *             A product of SimoTime Technologies                *
      *        Our e-mail address is: helpdesk@simotime.com           *
      *     Also, visit our Web Site at http://www.simotime.com       *
      *                                                               *
      *                                   Record    Record     Key    *
      *  Function  Name     Organization  Format    Max-Min  Pos-Len  *
      *  INPUT     ITEMMAST SEQUENTIAL    FIXED      00080            *
      *  OUTPUT    CSVPUTD1 ASCII/CRLF    VARIABLE   00080            *
      *                                                               *
      *****************************************************************
       ENVIRONMENT DIVISION.
       INPUT-OUTPUT SECTION.
       FILE-CONTROL.
           SELECT ITEMMAST-FILE ASSIGN to ITEMMAST
                  ORGANIZATION  is INDEXED
                  ACCESS MODE   is SEQUENTIAL
                  RECORD KEY    is ITEM-NUMBER
                  FILE STATUS   is ITEMMAST-STATUS.

      *****************************************************************
       DATA DIVISION.
       FILE SECTION.

       FD  ITEMMAST-FILE.
       COPY ITEMCB01.

       WORKING-STORAGE SECTION.
      *****************************************************************
      *    Data-structure for Title and Copyright...
      *    ------------------------------------------------------------
       01  SIM-TITLE.
           05  T1 pic X(11) value '* ITQIN1C1 '.
           05  T2 pic X(34) value 'Export KSDS Item File to SQL Table'.
           05  T3 pic X(10) value ' v04.02.04'.
           05  T4 pic X(24) value ' http://www.simotime.com'.
       01  SIM-COPYRIGHT.
           05  C1 pic X(11) value '* ITQIN1C1 '.
           05  C2 pic X(20) value 'Copyright 1987-2019 '.
           05  C3 pic X(28) value '    SimoTime Technologies   '.
           05  C4 pic X(20) value ' All Rights Reserved'.

       01  SIM-THANKS-01.
           05  C1 pic X(11) value '* ITQIN1C1 '.
           05  C2 pic X(32) value 'Thank you for using this program'.
           05  C3 pic X(32) value ' provided from SimoTime Technolo'.
           05  C4 pic X(04) value 'gies'.

       01  SIM-THANKS-02.
           05  C1 pic X(11) value '* ITQIN1C1 '.
           05  C2 pic X(32) value 'Please send all inquires or sugg'.
           05  C3 pic X(32) value 'estions to the helpdesk@simotime'.
           05  C4 pic X(04) value '.com'.

       01  ITEMMAST-STATUS.
           05  ITEMMAST-STATUS-L   pic X.
           05  ITEMMAST-STATUS-R   pic X.
       01  ITEMMAST-EOF            pic X       value 'N'.
       01  ITEMMAST-OPEN-FLAG      pic X       value 'C'.

       01  IO-STATUS.
           05  IO-STAT1            pic X.
           05  IO-STAT2            pic X.
       01  TWO-BYTES.
           05  TWO-BYTES-LEFT      pic X.
           05  TWO-BYTES-RIGHT     pic X.
       01  TWO-BYTES-BINARY        redefines TWO-BYTES pic 9(4) comp.
       01  IO-STATUS-4             pic 9(4)  value 0.
       01  IO-STATUS-4A            redefines IO-STATUS-4 pic X(4).

      *****************************************************************
      * Message Buffer used by the Z-DISPLAY-MESSAGE-TEXT routine.    *
      *****************************************************************
       01  MESSAGE-BUFFER.
           05  MESSAGE-HEADER      pic X(11)   value '* ITQIN1C1 '.
           05  MESSAGE-TEXT.
               10  MESSAGE-TEXT-1  pic X(68)   value SPACES.
               10  MESSAGE-TEXT-2  pic X(188)  value SPACES.
       01  MESSAGE-BUFFER-SIZE     pic 9(3)    value 267.
       01  MSG-PTR                 pic 9(3)    value 0.
       01  MSG-LEN                 pic 9(3)    value 0.

       01  APPL-RESULT             pic S9(9)   comp.
           88  APPL-AOK            value 0.
           88  APPL-EOF            value 16.

      *    ------------------------------------------------------------
           EXEC SQL BEGIN DECLARE SECTION END-EXEC.

           EXEC SQL INCLUDE ITEMCQ01      END-EXEC.

           EXEC SQL END DECLARE SECTION   END-EXEC.

           EXEC SQL INCLUDE SQLCA         END-EXEC.

      *****************************************************************
       PROCEDURE DIVISION.

           perform Z-POST-COPYRIGHT

           perform ITEMMAST-OPEN

           perform until ITEMMAST-STATUS not = '00'
               perform ITEMMAST-READ
      *        If a successful read of the input file
      *        and the input item number is not equal to SPACES
      *        then create an output.
               if  ITEMMAST-STATUS = '00'
               and ITEM-NUMBER not = SPACES
                   display ITEM-NUMBER ' - ' ITEM-DESCRIPTION
                   move ITEM-RECORD      to ITQ1-RECORD
                   perform ITEMRDB1-INSERT
               end-if
           end-perform

           perform ITEMMAST-CLOSE

           perform Z-THANK-YOU

           GOBACK.

      *****************************************************************
       ITEMRDB1-INSERT.
           EXEC SQL
                INSERT INTO ITEMRDB1
                 (
                  ITQ1_NUMBER,
                  ITQ1_DESCRIPTION,
                  ITQ1_UNIT_MEASURE,
                  ITQ1_COST,
                  ITQ1_PRICE
                 )
                VALUES
                 (
                  :ITQ1-NUMBER,
                  :ITQ1-DESCRIPTION,
                  :ITQ1-UNIT-OF-MEASURE,
                  :ITQ1-COST,
                  :ITQ1-PRICE
                 )
           END-EXEC

           if SQLCODE = 0
              display 'Finished for INSERT into ITEMRDB1 '
                      'SQLCODE = ' SQLCODE
                      ' ITEM = ' ITQ1-NUMBER
           else
              display 'ABENDING for INSERT into ITEMRDB1 '
                      'SQLCODE = ' SQLCODE
                      ' ITEM = ' ITQ1-NUMBER
              add 16 to ZERO giving RETURN-CODE
           end-if

           exit.

      *****************************************************************
      * I/O ROUTINES FOR ITEMMAST...                                  *
      *****************************************************************
       ITEMMAST-CLOSE.
           add 8 to ZERO giving APPL-RESULT.
           close ITEMMAST-FILE
           if  ITEMMAST-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               add 12 to ZERO giving APPL-RESULT
           end-if
           if  APPL-AOK
               CONTINUE
           else
               move 'ITEMMAST-Failure-CLOSE...' to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TEXT
               move ITEMMAST-STATUS to IO-STATUS
               perform Z-DISPLAY-IO-STATUS
               perform Z-ABEND-PROGRAM
           end-if
           exit.
      *---------------------------------------------------------------*
       ITEMMAST-READ.
           read ITEMMAST-FILE
           if  ITEMMAST-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               if  ITEMMAST-STATUS = '10'
                   add 16 to ZERO giving APPL-RESULT
               else
                   add 12 to ZERO giving APPL-RESULT
               end-if
           end-if
           if  APPL-AOK
               CONTINUE
           else
               if  APPL-EOF
                   move 'Y' to ITEMMAST-EOF
               else
                   move 'ITEMMAST-Failure-GET...' to MESSAGE-TEXT
                   perform Z-DISPLAY-MESSAGE-TEXT
                   move ITEMMAST-STATUS to IO-STATUS
                   perform Z-DISPLAY-IO-STATUS
                   perform Z-ABEND-PROGRAM
               end-if
           end-if
           exit.
      *---------------------------------------------------------------*
       ITEMMAST-OPEN.
           add 8 to ZERO giving APPL-RESULT.
           open input ITEMMAST-FILE
           if  ITEMMAST-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
               move 'O' to ITEMMAST-OPEN-FLAG
           else
               add 12 to ZERO giving APPL-RESULT
           end-if
           if  APPL-AOK
               CONTINUE
           else
               move 'ITEMMAST-Failure-OPEN...' to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TEXT
               move ITEMMAST-STATUS to IO-STATUS
               perform Z-DISPLAY-IO-STATUS
               perform Z-ABEND-PROGRAM
           end-if
           exit.


      *****************************************************************
      * The following Z-ROUTINES provide administrative functions     *
      * for this program.                                             *
      *****************************************************************
      *
      *****************************************************************
      * ABEND the program, post a message to the console and issue    *
      * a STOP RUN.                                                   *
      *****************************************************************
       Z-ABEND-PROGRAM.
           if  MESSAGE-TEXT not = SPACES
               perform Z-DISPLAY-MESSAGE-TEXT
           end-if
           move 'PROGRAM-IS-ABENDING...'  to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TEXT
           add 12 to ZERO giving RETURN-CODE
           STOP RUN.
      *    exit.

      *****************************************************************
      * Display CONSOLE messages...                                   *
      *****************************************************************
       Z-DISPLAY-MESSAGE-TEXT.
           display MESSAGE-BUFFER upon console
           move all SPACES to MESSAGE-TEXT
           exit.

      *****************************************************************
      * Display the file status bytes. This routine will display as   *
      * four digits. If the full two byte file status is numeric it   *
      * will display as 00nn. If the 1st byte is a numeric nine (9)   *
      * the second byte will be treated as a binary number and will   *
      * display as 9nnn.                                              *
      *****************************************************************
       Z-DISPLAY-IO-STATUS.
           if  IO-STATUS not NUMERIC
           or  IO-STAT1 = '9'
               subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
               move IO-STAT2 to TWO-BYTES-RIGHT
               add TWO-BYTES-BINARY to ZERO giving IO-STATUS-4
               move IO-STAT1 to IO-STATUS-4A(1:1)
               move 'File Status is: nnnn' to MESSAGE-TEXT
               move IO-STATUS-4A to MESSAGE-TEXT(17:4)
               perform Z-DISPLAY-MESSAGE-TEXT
           else
               move '0000' to IO-STATUS-4A
               move IO-STATUS to IO-STATUS-4A(3:2)
               move 'File Status is: nnnn' to MESSAGE-TEXT
               move IO-STATUS-4A to MESSAGE-TEXT(17:4)
               perform Z-DISPLAY-MESSAGE-TEXT
           end-if
           exit.

      *****************************************************************
       Z-POST-COPYRIGHT.
           display SIM-TITLE     upon console
           display SIM-COPYRIGHT upon console
           exit.

      *****************************************************************
       Z-THANK-YOU.
           display SIM-THANKS-01 upon console
           display SIM-THANKS-02 upon console
           exit.

      *****************************************************************
      *                 This program is provided by:                  *
      *                    SimoTime Technologies                      *
      *         (C) Copyright 1987-2019 All Rights Reserved           *
      *           Web Site URL:   http://www.simotime.com             *
      *                 e-mail:   helpdesk@simotime.com               *
      *****************************************************************

Table of Contents Previous Section Next Section The COBOL Copy File

The following (ITEMCQ01.cpy) is a sample of the COBOL copy file used to define the table row structure.

      *****************************************************************
      *               ITEMCQ01.CPY - a COBOL Copy File                *
      *       A Item or Product File used by the Demo programs.       *
      *   This is an SQL Declare with primary key and unique index.   *
      *         Copyright (C) 1987-2019 SimoTime Technologies         *
      *                     All Rights Reserved                       *
      *              Provided by SimoTime Technologies                *
      *        Our e-mail address is: helpdesk@simotime.com           *
      *     Also, visit our Web Site at http://www.simotime.com       *
      *****************************************************************
           EXEC SQL DECLARE ITEMRDB1 TABLE
           (
                 ITQ1_NUMBER            CHAR (12)      NOT NULL
                                                       PRIMARY KEY,
                 ITQ1_DESCRIPTION       CHAR (48)      NOT NULL,
                 ITQ1_QTY_ONHAND        INTEGER        NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_QTY_ALLOCATED     INTEGER        NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_UNIT_MEASURE      CHAR (16)      NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_COST              DECIMAL (9, 2) NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_PRICE             DECIMAL (9, 2) NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_LADATE            CHAR (8)       NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_LATIME            CHAR (8)       NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_TOKEN             CHAR (8)       NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_D_CODE_1          CHAR (1)       NOT NULL
                                                       WITH DEFAULT,
                 ITQ1_D_PERCENT_1       CHAR (7)       NOT NULL
                                                       WITH DEFAULT
           )
           END-EXEC.

       01  ITQ1-RECORD.
           05  ITQ1-NUMBER              PIC X(12).
           05  ITQ1-DATA.
               10  ITQ1-DESCRIPTION     PIC X(48).
               10  ITQ1-QTY-ONHAND      PIC 9(7)            COMP.
               10  ITQ1-QTY-ALLOCATED   PIC 9(7)            COMP.
               10  ITQ1-UNIT-OF-MEASURE PIC X(16).
               10  ITQ1-COST            PIC S9(7)V9(2)      COMP-3.
               10  ITQ1-PRICE           PIC S9(7)V9(2)      COMP-3.
               10  ITQ1-LADATE          PIC X(8).
               10  ITQ1-LATIME          PIC X(8).
               10  ITQ1-TOKEN           PIC X(3).
               10  ITQ1-D-CODE-1        PIC X.
               10  ITQ1-D-PERCENT-1     PIC S9(3)V9(4).
      *        10  ITQ1-D-CODE-2        PIC X.
      *        10  ITQ1-D-PERCENT-2     PIC S9(3)V9(4).
      *        10  ITQ1-D-CODE-3        PIC X.
      *        10  ITQ1-D-PERCENT-3     PIC S9(3)V9(4).
      *        10  FILLER               PIC X(375).
      *
      ***  ITEMCQ01 - End-of-Copy File - - - - - - - - - - - ITEMCQ01 *
      *****************************************************************
      *

Table of Contents Previous Section Next Section Summary

The purpose of this program is to provide examples using embedded SQL in a COBOL program to create, manipulate and delete relational data base tables. This document may be used as a tutorial for new programmers or as a quick reference for experienced programmers.

In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a greater awareness of the Data Management and Application Processing alternatives.

The documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.

SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please send an e-mail to: helpdesk@simotime.com or call 415 883-6565. We appreciate hearing from you.

Table of Contents Previous Section Next Section Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Table of Contents Previous Section Next Section Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Note: A SimoTime License is required for the items to be made available on a local system or server.

Table of Contents Previous Section Next Section Current Server or Internet Access

The following links may be to the current server or to the Internet.

Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the Link to Internet icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the Link to Server icon.

Link to Internet   Link to Server   Explore the Structure and Access Methods of a Relational Table that contains "Item or Product" information. This white paper provides an oveview of the programs available for managing a Relational Table containing Item or Product information.

Link to Internet   Link to Server   Explore how to Sequentially Access a Relational Table using a COBOL program with Cursor Processing. This program accesses a Relational Table containing Item or Product information and provides an example of how to use cursor processing to access a table sequentially by key accessing one row at a time.

Link to Internet   Link to Server   Explore how to Create a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to create a table and create an index using a unique primary key.

Link to Internet   Link to Server   Explore how to Delete a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to delete (or Drop) an index and a table.

Link to Internet   Link to Server   Explore how to Insert a row into a Relational Table using a COBOL program. This example accesses a Relational Table containing Item or Product information and shows how to insert a new row into a table.

Link to Internet   Link to Server   Explore how to Update a row in a Relational Table using a COBOL program. This sample accesses a Relational Table containing Item or Product information and shows how to update an existing row within a table.

Link to Internet   Link to Server   Explore the SQL Connection for more examples of how to create, manipulate and delete Relational Data Bases. The COBOL programs are written to compile and execute on a Windows System with SQL Server and Micro Focus Enterprise Server or an IBM Mainframe System with DB2.

Link to Internet   Link to Server   Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

Link to Internet   Link to Server   Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and/or QSAM files.

Table of Contents Previous Section Next Section Internet Access Required

The following links will require an internet connect.

This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products and services available from Micro Focus. This link requires an Internet Connection.

Table of Contents Previous Section Next Section Glossary of Terms

Link to Internet   Link to Server   Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Table of Contents Previous Section Next Section Comments or Feedback

This document was created and is copyrighted and maintained by SimoTime Technologies.

If you have any questions, suggestions, comments or feedback please call at 1 415 827-7045 or send an e-mail to: helpdesk@simotime.com

We appreciate hearing from you.

Table of Contents Previous Section Next Section Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com


Return-to-Top
Item or Product, Insert a Row using a COBOL with Embedded SQL Statements
Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved
When technology complements business
http://www.simotime.com