Update/Insert a Row
Customer Table, COBOL & EXEC SQL
  Table of Contents  v-16.01.01 - cuqup101.htm 
  Introduction
  Programming Requirements
  Programming Overview
  CMD Member for Batch Job
  JCL Member using IKJEFT01
  COBOL Demonstration Program
  The COBOL Copy File
  Summary
  Software Agreement and Disclaimer
  Downloads and Links
  Current Server or Internet Access
  Internet Access Required
  Glossary of Terms
  Comments or Feedback
  Company Overview
The SimoTime Home Page 

Table of Contents Previous Section Next Section Introduction

This example uses embedded SQL in a COBOL program to update a row within a table. This example sequentially reads the records in a VSAM, Keyed-Sequential-Data-Set (KSDS) and uses the information to update the relational data base. If an existing row with a matching primary key cannot be selected then a new row will be inserted. In the world of programming there are many ways to solve a problem. This suite of programs is provided as a COBOL programming example of one of the possible solutions.


We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved

Table of Contents Previous Section Next Section Programming Requirements

This suite of samples programs will run on the following platforms.

1 Executes on Windows/7, Windows/XP or Windows Server using Micro Focus Net Express and the CMD file provided
2 Executes on Windows/7, Windows/XP or Windows Server using Micro Focus Mainframe Express and the JCL member provided.
3 Executes on Windows/7, Windows/XP or Windows Server using Micro Focus Server or Studio and the JCL member provided.
4 Executes on an IBM Mainframe running ZOS and DB/2.
5 May be ported to run on the Linux and UNIX platforms supported by Micro Focus COBOL.
  Systems that support the execution of the Sample Program

Table of Contents Previous Section Next Section Programming Overview

The following diagram is an overview of how the demonstration program fits into the example.

             
Entry Point
ZOS
Entry Point
Windows
Entry Points
   
   
CUQUP1J1
jcl
CUQUP1E1
cmd
Start the processing to update or insert rows into the table
   
   
 
 
   
   
   
SYSTSIN
instream
 
 
IKJEFT01
utl
   
Read SYSTSIN and pass control to application program
   
   
 
 
   
   
CUSTMAST
ksds
 
 
CUQUP1C1
cbl
 
 
CUSTRDB1
rdb
Read the CUSTMAST file and update existing or insert new rows into the CUSTRDB1 table
   
EOJ
End-Of-Job
 
Read a KSDS and update existing or insert new rows into a Relational Data Base Table

The main program (CUQUP1C1) will read an Indexed file (CUSTMAST) and use this information to update an existing row in a relational data base table (CUSTRDB1). If a row with a matching key does not exist then a new row will be inserted.

Color Associations: The  light-green  boxes are unique to SIMOTIME Technologies using an IBM Mainframe System or Micro Focus Enterprise Developer. The  light-red  boxes are unique to the SIMOTIME Technologies using a Linux, UNIX or Windows System and COBOL Technologies such as Micro Focus. The  light-yellow  boxes are SIMOTIME Technologies, Third-party Technologies, decision points or program transitions in the processing logic or program generations. The  light-blue  boxes identify the input/output data structures such as Documents, Spreadsheets, Data Files, VSAM Data Sets, Partitioned Data Set Members (PDSM's) or Relational Tables. The  light-gray  boxes identify a system function or an informational item.

Table of Contents Previous Section Next Section CMD Member for Batch Job

The following is the Windows Command file (CUQUP1E1.cmd) that is required to run as a job on a PC using Micro Focus Net Express.

@echo OFF
rem  * *******************************************************************
rem  *               CUQUP1E1.CMD - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text    - COBOL with embedded SQL to Update rows in a table
rem  * Author  - SimoTime Technologies
rem  * Date    - November 11, 2003
rem  * Version - 08.07.12
rem  *
rem  * This set of programs illustrate the use of embedded SQL in a COBOL
rem  * program that Update rows in a Table.
rem  *
rem  * This technique provides for the use of a single COBOL source
rem  * program that will run on ZOS, Windows or Unix.
rem  *
rem  * This set of programs will run on a Personal Computer with Windows
rem  * and Micro Focus Net Express or Mainframe Express.
rem  *
rem  *
rem  *                    ************
rem  *                    * CUQUP1E1 *
rem  *                    ********cmd*
rem  *                         *
rem  *                         *
rem  *   ************     ************     ************
rem  *   * CUSTMAST *-----* CUQUP1C1 *-----* CUSTMRDB1 *
rem  *   *******ksds*     ********cbl*     ********rdb*
rem  *                         *
rem  *                         *
rem  *                    ************
rem  *                    *   EOJ    *
rem  *                    ************
echo *
echo * The SQL Server must be started prior to executing this command.
echo *
     set CmdName=CUQUP1E1
     call ..\Env1BASE %CmdName%
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting JobName %CmdName%"
     set CUSTMAST=%DataLib1%\Dyn1\SIMOTIME.DATA.CUSTMAST.DAT
     run CUQUP1C1
     if errorlevel = 1 set JobStatus=0001
     if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
     call SimoNOTE "Finished JobName %CmdName%"
     goto :End
:EojNOK
     call SimoNOTE "ABENDING JobName %CmdName%"
     call SimoNOTE "ABENDING Message JobStatus %JobStatus%"
     goto :End
:End
     if not "%1" == "nopause" pause

Table of Contents Previous Section Next Section JCL Member using IKJEFT01

The following is the mainframe JCL (CUQUP1J1.jcl) that is required to run as a job on an IBM, ZOS Mainframe System, Micro Focus Mainframe Express or Micro Focus Server.

//CUQUP1J1 JOB SIMOTIME,ACCOUNT,CLASS=1,MSGCLASS=0,NOTIFY=&SYSUID
//* *******************************************************************
//*       CUQUP1J1.JCL - a JCL Member for Batch Job Processing        *
//*       This JCL Member is provided by SimoTime Technologies        *
//*           (C) Copyright 1987-2019 All Rights Reserved             *
//*             Web Site URL:   http://www.simotime.com               *
//*                   e-mail:   helpdesk@simotime.com                 *
//* *******************************************************************
//*
//* TEXT   - Execute a COBOL program to UPDATE data within a Table.
//* AUTHOR - SimoTime Technologies
//* DATE   - January 01, 1989
//*
//* This set of programs illustrate the use of a COBOL program with
//* embedded SQL syntax. This program will UPDATE rows into a table.
//*
//* This set of programs will run on a mainframe under ZOS or on
//* a personal computer running Windows and Mainframe Express (MFE)
//* by Micro Focus.
//*
//*                    ************
//*                    * CUQUP1J1 *
//*                    ********jcl*
//*                         *
//*                         *
//*                    ************
//*                    * IKJEFT01 *
//*                    ********dbm*
//*                         *
//*                         *
//*   ************     ************     ************
//*   * CUSTMAST *-----* CUQUP1C1 *-----* CUSTRDB1 *
//*   *******ksds*     ********cbl*     ********rdb*
//*                         *
//*                         *
//*                    ************
//*                    *   EOJ    *
//*                    ************
//*
//* *******************************************************************
//* Step 1 of 1, this is a single step job.
//*
//STEP01   EXEC PGM=IKJEFT01
//CUSTMAST DD  DSN=SIMOTIME.DATA.CUSTMAST,DISP=SHR
//SYSPRINT DD  SYSOUT=*
//SYSTSPRT DD  SYSOUT=*
//SYSOUT   DD  SYSOUT=*
//SYSTSIN  DD  *
  DSN SYSTEM(ACC1)
      RUN PROG(CUQUP1C1)
  END
/*
//

Table of Contents Previous Section Next Section COBOL Demonstration Program

The following (CUQUP1C1.cbl) is a sample of the COBOL demonstration program that will update existing rows or insert new rows into a table.

       IDENTIFICATION DIVISION.
       PROGRAM-ID.    CUQUP1C1.
       AUTHOR.        SIMOTIME TECHNOLOGIES.
      *****************************************************************
      * Copyright (C) 1987-2019 SimoTime Technologies.                *
      *                                                               *
      * All rights reserved.  Unpublished, all rights reserved under  *
      * copyright law and international treaty.  Use of a copyright   *
      * notice is precautionary only and does not imply publication   *
      * or disclosure.                                                *
      *                                                               *
      * Permission to use, copy, modify and distribute this software  *
      * for any commercial purpose requires a fee to be paid to       *
      * SimoTime Technologies. Once the fee is received by SimoTime   *
      * the latest version of the software will be delivered and a    *
      * license will be granted for use within an enterprise,         *
      * provided the SimoTime copyright notice appear on all copies   *
      * of the software. The SimoTime name or Logo may not be used    *
      * in any advertising or publicity pertaining to the use of the  *
      * software without the written permission of SimoTime           *
      * Technologies.                                                 *
      *                                                               *
      * Permission to use, copy and modify this software for a        *
      * non-commercial purpose and without fee is hereby granted,     *
      * provided the SimoTime copyright notice appear on all copies   *
      * of the software. The SimoTime name or Logo may not be used    *
      * in any advertising or publicity pertaining to the use of the  *
      * software without the written permission of SimoTime           *
      * Technologies.                                                 *
      *                                                               *
      * SimoTime Technologies makes no warranty or representations    *
      * about the suitability of the software for any purpose. It is  *
      * provided "AS IS" without any expressed or implied warranty,   *
      * including the implied warranties of merchantability, fitness  *
      * for a particular purpose and non-infringement. SimoTime       *
      * Technologies shall not be liable for any direct, indirect,    *
      * special or consequential damages resulting from the loss of   *
      * use, data or projects, whether in an action of contract or    *
      * tort, arising out of or in connection with the use or         *
      * performance of this software                                  *
      *                                                               *
      * SimoTime Technologies                                         *
      * 15 Carnoustie Drive                                           *
      * Novato, CA 94949-5849                                         *
      * 415.883.6565                                                  *
      *                                                               *
      * RESTRICTED RIGHTS LEGEND                                      *
      * Use, duplication, or disclosure by the Government is subject  *
      * to restrictions as set forth in subparagraph (c)(1)(ii) of    *
      * the Rights in Technical Data and Computer Software clause at  *
      * DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of          *
      * Commercial  Computer Software - Restricted Rights  at 48      *
      * CFR 52.227-19, as applicable.  Contact SimoTime Technologies, *
      * 15 Carnoustie Drive, Novato, CA 94949-5849.                   *
      *****************************************************************
      * This program will read the Item File (originally a VSAM, KSDS
      * downloaded to be a Micro Focus Keyed-Indexed file) and insert
      * or update rows into a table.
      *
      *                    ************
      *                    * CUQUP1J1 *
      *                    ********jcl*
      *                         *
      *                         *
      *                    ************
      *                    * IKJEFT01 *
      *                    ********dbm*
      *                         *
      *                         *
      *   ************     ************     ************
      *   * CUSTMAST *-----* CUQUP1C1 *-----* CUSTACC1 *
      *   ********ksd*     ********cbl*     ********rdb*
      *                         *
      *                         *
      *                    ************
      *                    *   EOJ    *
      *                    ************
      *
      *****************************************************************
       ENVIRONMENT DIVISION.
       INPUT-OUTPUT SECTION.
       FILE-CONTROL.
      *    The LINE SEQUENTIAL file organization is Micro Fcus
      *    syntax for an ASCII/Text file.
           SELECT CUSTMAST-FILE ASSIGN to CUSTMAST
                  ORGANIZATION  is indexed
                  ACCESS MODE   is SEQUENTIAL
                  RECORD KEY    is CUST-NUMBER
                  FILE STATUS   is CUSTMAST-STATUS.

      *****************************************************************
       DATA DIVISION.
       FILE SECTION.

       FD  CUSTMAST-FILE.
       COPY CUSTCB01.

       WORKING-STORAGE SECTION.
      *****************************************************************
      *    Data-structure for Title and Copyright...
      *    ------------------------------------------------------------
       01  SIM-TITLE.
           05  T1 pic X(11) value '* CUQUP1C1 '.
           05  T2 pic X(34) value 'Read KSDS, Update or Insert SQL   '.
           05  T3 pic X(10) value ' v09.02.12'.
           05  T4 pic X(24) value ' http://www.simotime.com'.
       01  SIM-COPYRIGHT.
           05  C1 pic X(11) value '* CUQUP1C1 '.
           05  C2 pic X(20) value 'Copyright 1987-2019 '.
           05  C3 pic X(28) value '    SimoTime Technologies   '.
           05  C4 pic X(20) value ' All Rights Reserved'.

       01  SIM-THANKS-01.
           05  C1 pic X(11) value '* CUQUP1C1 '.
           05  C2 pic X(32) value 'Thank you for using this program'.
           05  C3 pic X(32) value ' provided from SimoTime Technolo'.
           05  C4 pic X(04) value 'gies'.

       01  SIM-THANKS-02.
           05  C1 pic X(11) value '* CUQUP1C1 '.
           05  C2 pic X(32) value 'Please send all inquires or sugg'.
           05  C3 pic X(32) value 'estions to the helpdesk@simotime'.
           05  C4 pic X(04) value '.com'.

       01  CUSTMAST-STATUS.
           05  CUSTMAST-STATUS-L   pic X.
           05  CUSTMAST-STATUS-R   pic X.
       01  CUSTMAST-EOF            pic X       value 'N'.
       01  CUSTMAST-OPEN-FLAG      pic X       value 'C'.


       01  CSVPUTD1-STATUS.
           05  CSVPUTD1-STATUS-L   pic X.
           05  CSVPUTD1-STATUS-R   pic X.
       01  CSVPUTD1-OPEN-FLAG      pic X       value 'C'.

       01  IO-STATUS.
           05  IO-STAT1            pic X.
           05  IO-STAT2            pic X.
       01  TWO-BYTES.
           05  TWO-BYTES-LEFT      pic X.
           05  TWO-BYTES-RIGHT     pic X.
       01  TWO-BYTES-BINARY        redefines TWO-BYTES pic 9(4) comp.
       01  IO-STATUS-4             pic 9(4)  value 0.
       01  IO-STATUS-4A            redefines IO-STATUS-4 pic X(4).

      *****************************************************************
      * Message Buffer used by the Z-DISPLAY-MESSAGE-TEXT routine.    *
      *****************************************************************
       01  MESSAGE-BUFFER.
           05  MESSAGE-HEADER      pic X(11)   value '* CUQUP1C1 '.
           05  MESSAGE-TEXT.
               10  MESSAGE-TEXT-1  pic X(68)   value SPACES.
               10  MESSAGE-TEXT-2  pic X(41)   value SPACES.
       01  MESSAGE-BUFFER-SIZE     pic 9(3)    value 120.

       01  MSG-SQL-CODE.
           05  FILLER              pic X(12)   value ' SQLCODE is '.
           05  MSG-SQL-VALUE       pic S9(12)  SIGN LEADING SEPARATE
                                               value 0.

       01  WORK-DATE.
           05  WORK-DATE-08        pic X(8).
       01  WORK-TIME               pic X(8).

       01  EDIT-TIMESTAMP.
           05  EDIT-DATE           pic X(10)   value 'yyyy-nn-nn'.
           05  filler              pic X       value '-'.
           05  EDIT-TIME           pic X(11)   value 'nn:nn:nn:nn'.
           05  filler              pic X(4)    value SPACES.

       01  APPL-RESULT             pic S9(9)   comp.
           88  APPL-AOK            value 0.
           88  APPL-EOF            value 16.

       01  DEBUG-FLAG              pic X       value 'N'.
       01  CONNECT-FLAG            pic X       value 'N'.

      *    ------------------------------------------------------------
           EXEC SQL BEGIN DECLARE SECTION END-EXEC.

           EXEC SQL INCLUDE CUSTCQ01      END-EXEC.

       01  dbname PIC X(8)      value 'CUSTACC1'.
       01  userid PIC X(8)      value SPACES.
       01  p-word.
           49 L PIC S9(4) COMP-5   value 0.
           49 D PIC X(18)          value SPACES.

           EXEC SQL end DECLARE SECTION   END-EXEC.

           EXEC SQL INCLUDE SQLCA         END-EXEC.

      *****************************************************************
       PROCEDURE DIVISION.

           perform Z-POST-COPYRIGHT

           perform CUSTMAST-OPEN

           if  CONNECT-FLAG = 'Y'
      *        Do an explicit connect. Otherwise, operating system or
      *        Micro Focus sub-system should manage the connect.
               perform CUSTACC1-CONNECT
           end-if

           perform until CUSTMAST-STATUS not = '00'
               perform CUSTMAST-READ
      *        If a successful read of the input file and the
      *        input Customer Number is not equal to SPACES
      *        then create an output.
               if  CUSTMAST-STATUS = '00'
               and CUST-NUMBER not = SPACES
                   if  DEBUG-FLAG = 'Y'
                       display CUST-NUMBER ' - ' CUST-LAST-NAME
                   end-if
                   move CUST-RECORD      to CUQ1-RECORD
                   perform Z-GET-DATE-AND-TIME
                   perform CUSTACC1-SELECT
                   if  SQLCODE = ZERO
                   or  SQLCODE = 1
                       perform MOVE-DATA-FOR-UPDATE
                       perform CUSTACC1-UPDATE
                   else
                       perform MOVE-DATA-FOR-UPDATE
                       perform CUSTACC1-INSERT
                   end-if
               end-if
           end-perform

           if  CONNECT-FLAG = 'Y'
      *        Do an explicit connect. Otherwise, operating system or
      *        Micro Focus sub-system should manage the connect.
               perform CUSTACC1-DISCONNECT
           end-if

           perform CUSTMAST-CLOSE

           perform Z-THANK-YOU

           GOBACK.

      *****************************************************************
       CUSTACC1-CONNECT.
           EXEC SQL CONNECT TO 'CUSTACC1' END-EXEC
           evaluate SQLCODE
             when 0
               move 0 to RETURN-CODE
               move 'Y' to CONNECT-FLAG
               move '* CONNECT is Successful'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TEXT
             when OTHER
               move '* ABENDING: CONNECT attempt Failed'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TEXT
               perform Z-DISPLAY-SQL-CODE
               add 16 to ZERO giving RETURN-CODE
               perform Z-ABEND-PROGRAM
           end-evaluate

           EXEC SQL BEGIN TRANSACTION END-EXEC
           exit.

      *****************************************************************
       CUSTACC1-DISCONNECT.
           EXEC SQL COMMIT TRANSACTION END-EXEC

           EXEC SQL DISCONNECT CURRENT END-EXEC
           move 'N' to CONNECT-FLAG
           exit.

      *****************************************************************
       MOVE-DATA-FOR-UPDATE.
           move CUST-NUMBER          to CUQ1-NUMBER
           move CUST-STATUS          to CUQ1-STATUS
           move CUST-LAST-NAME       to CUQ1-LAST-NAME
           move CUST-FIRST-NAME      to CUQ1-FIRST-NAME
           move CUST-MID-NAME        to CUQ1-MID-NAME
           move CUST-ADDRESS-1       to CUQ1-ADDRESS-1
           move CUST-ADDRESS-2       to CUQ1-ADDRESS-2
           move CUST-CITY            to CUQ1-CITY
           move CUST-STATE           to CUQ1-STATE
           move CUST-POSTAL-CODE     to CUQ1-POSTAL-CODE
           move CUST-PHONE-HOME      to CUQ1-PHONE-HOME
           move CUST-PHONE-WORK      to CUQ1-PHONE-WORK
           move CUST-PHONE-CELL      to CUQ1-PHONE-CELL

           move WORK-DATE            to CUQ1-LADATE
           move WORK-TIME            to CUQ1-LATIME
           move ZERO                 to CUQ1-TOKEN
           exit.

      *****************************************************************
       CUSTACC1-SELECT.
           EXEC SQL
                SELECT CUQ1_NUMBER,
                       CUQ1_STATUS,
                       CUQ1_LAST_NAME,
                       CUQ1_FIRST_NAME,
                       CUQ1_MID_NAME,
                       CUQ1_ADDRESS_1,
                       CUQ1_ADDRESS_2,
                       CUQ1_CITY,
                       CUQ1_STATE,
                       CUQ1_POSTAL_CODE,
                       CUQ1_PHONE_HOME,
                       CUQ1_PHONE_WORK,
                       CUQ1_PHONE_CELL,
                       CUQ1_LADATE,
                       CUQ1_LATIME,
                       CUQ1_TOKEN
                INTO :CUQ1-NUMBER,
                     :CUQ1-STATUS,
                     :CUQ1-LAST-NAME,
                     :CUQ1-FIRST-NAME,
                     :CUQ1-MID-NAME,
                     :CUQ1-ADDRESS-1,
                     :CUQ1-ADDRESS-2,
                     :CUQ1-CITY,
                     :CUQ1-STATE,
                     :CUQ1-POSTAL-CODE,
                     :CUQ1-PHONE-HOME,
                     :CUQ1-PHONE-WORK,
                     :CUQ1-PHONE-CELL,
                     :CUQ1-LADATE,
                     :CUQ1-LATIME,
                     :CUQ1-TOKEN
                FROM CUSTACC1
                WHERE CUQ1_NUMBER = :CUQ1-NUMBER
           END-EXEC

           if  DEBUG-FLAG = 'Y'
               display 'CUSTACC1 Last Name = ' CUQ1-LAST-NAME
               if SQLCODE = 0
               or SQLCODE = 1
                  if SQLCODE = 0
                     display 'SELECT row entry found'
                             ' Customer = ' CUQ1-NUMBER
                  else
                     display 'SELECT row entry found with NULLS'
                             ' Customer = ' CUQ1-NUMBER
                  end-if
                  perform Z-DISPLAY-SQL-CODE
               else
                  display 'SELECT row entry NOT found'
                          ' Customer = ' CUQ1-NUMBER
                  perform Z-DISPLAY-SQL-CODE
               end-if
           end-if

           if  SQLCODE NOT = ZERO
               initialize CUQ1-RECORD
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTACC1-INSERT.
           EXEC SQL
                INSERT into CUSTACC1
                 (
                  CUQ1_NUMBER,
                  CUQ1_STATUS,
                  CUQ1_LAST_NAME,
                  CUQ1_FIRST_NAME,
                  CUQ1_MID_NAME,
                  CUQ1_ADDRESS_1,
                  CUQ1_ADDRESS_2,
                  CUQ1_CITY,
                  CUQ1_STATE,
                  CUQ1_POSTAL_CODE,
                  CUQ1_PHONE_HOME,
                  CUQ1_PHONE_WORK,
                  CUQ1_PHONE_CELL,
                  CUQ1_LADATE,
                  CUQ1_LATIME,
                  CUQ1_TOKEN
                 )
                VALUES
                 (
                  :CUQ1-NUMBER,
                  :CUQ1-STATUS,
                  :CUQ1-LAST-NAME,
                  :CUQ1-FIRST-NAME,
                  :CUQ1-MID-NAME,
                  :CUQ1-ADDRESS-1,
                  :CUQ1-ADDRESS-2,
                  :CUQ1-CITY,
                  :CUQ1-STATE,
                  :CUQ1-POSTAL-CODE,
                  :CUQ1-PHONE-HOME,
                  :CUQ1-PHONE-WORK,
                  :CUQ1-PHONE-CELL,
                  :CUQ1-LADATE,
                  :CUQ1-LATIME,
                  :CUQ1-TOKEN
                 )
           END-EXEC

           if SQLCODE = 0
               if  DEBUG-FLAG = 'Y'
                   display 'Complete, INSERT FOR CUSTACC1'
                           'SQLCODE = ' SQLCODE
                           ' Customer = ' CUQ1-NUMBER
               end-if
           else
              display 'ABENDING! INSERT FOR CUSTACC1'
                      ' Customer = ' CUQ1-NUMBER
              perform Z-DISPLAY-SQL-CODE
              add 16 to ZERO giving RETURN-CODE
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTACC1-UPDATE.
           EXEC SQL
                UPDATE CUSTACC1
                SET CUQ1_NUMBER = :CUQ1-NUMBER,
                    CUQ1_STATUS = :CUQ1-STATUS,
                    CUQ1_LAST_NAME = :CUQ1-LAST-NAME,
                    CUQ1_FIRST_NAME = :CUQ1-FIRST-NAME,
                    CUQ1_MID_NAME = :CUQ1-MID-NAME,
                    CUQ1_ADDRESS_1 = :CUQ1-ADDRESS-1,
                    CUQ1_ADDRESS_2 = :CUQ1-ADDRESS-2,
                    CUQ1_CITY = :CUQ1-CITY,
                    CUQ1_STATE = :CUQ1-STATE,
                    CUQ1_POSTAL_CODE = :CUQ1-POSTAL-CODE,
                    CUQ1_PHONE_HOME = :CUQ1-PHONE-HOME,
                    CUQ1_PHONE_WORK = :CUQ1-PHONE-WORK,
                    CUQ1_PHONE_CELL = :CUQ1-PHONE-CELL,
                    CUQ1_LADATE = :CUQ1-LADATE,
                    CUQ1_LATIME = :CUQ1-LATIME,
                    CUQ1_TOKEN = :CUQ1-TOKEN
                WHERE CUQ1_NUMBER = :CUQ1-NUMBER
           END-EXEC.

           if  SQLCODE = 0
               if  DEBUG-FLAG = 'Y'
                   display 'Complete, UPDATE FOR CUSTACC1'
                           CUQ1-NUMBER
               end-if
           else
               display 'ABENDING, UPDATE FOR CUSTACC1 '
                       ' Customer = ' CUQ1-NUMBER
               perform Z-DISPLAY-SQL-CODE
               add 16 to ZERO giving RETURN-CODE
           end-if
           exit.

      *****************************************************************
      * I/O ROUTINES FOR CUSTMAST...                                  *
      *****************************************************************
       CUSTMAST-CLOSE.
           add 8 to ZERO giving APPL-RESULT.
           close CUSTMAST-FILE
           if  CUSTMAST-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               add 12 to ZERO giving APPL-RESULT
           end-if
           if  APPL-AOK
               CONTINUE
           else
               move 'CUSTMAST-Failure-CLOSE...' to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TEXT
               move CUSTMAST-STATUS to IO-STATUS
               perform Z-DISPLAY-IO-STATUS
               perform Z-ABEND-PROGRAM
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTMAST-READ.
           read CUSTMAST-FILE
           if  CUSTMAST-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               if  CUSTMAST-STATUS = '10'
                   add 16 to ZERO giving APPL-RESULT
               else
                   add 12 to ZERO giving APPL-RESULT
               end-if
           end-if
           if  APPL-AOK
               CONTINUE
           else
               if  APPL-EOF
                   move 'Y' to CUSTMAST-EOF
               else
                   move 'CUSTMAST-Failure-GET...' to MESSAGE-TEXT
                   perform Z-DISPLAY-MESSAGE-TEXT
                   move CUSTMAST-STATUS to IO-STATUS
                   perform Z-DISPLAY-IO-STATUS
                   perform Z-ABEND-PROGRAM
               end-if
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTMAST-OPEN.
           add 8 to ZERO giving APPL-RESULT.
           open input CUSTMAST-FILE
           if  CUSTMAST-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
               move 'O' to CUSTMAST-OPEN-FLAG
           else
               add 12 to ZERO giving APPL-RESULT
           end-if
           if  APPL-AOK
               CONTINUE
           else
               move 'CUSTMAST-Failure-OPEN...' to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TEXT
               move CUSTMAST-STATUS to IO-STATUS
               perform Z-DISPLAY-IO-STATUS
               perform Z-ABEND-PROGRAM
           end-if
           exit.


      *****************************************************************
      * The following Z-ROUTINES provide administrative functions     *
      * for this program.                                             *
      *****************************************************************
      *
      *****************************************************************
      * ABEND the program, post a message to the console and issue    *
      * a STOP RUN.                                                   *
      *****************************************************************
       Z-ABEND-PROGRAM.
           if  MESSAGE-TEXT not = SPACES
               perform Z-DISPLAY-MESSAGE-TEXT
           end-if
           move 'PROGRAM-IS-ABENDING...'  to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TEXT
           add 12 to ZERO giving RETURN-CODE
           STOP RUN.
      *    exit.

      *****************************************************************
      * Display CONSOLE messages...                                   *
      *****************************************************************
       Z-DISPLAY-MESSAGE-TEXT.
           if  MESSAGE-TEXT-2 = SPACES
               display MESSAGE-BUFFER(1:79)
           else
               display MESSAGE-BUFFER
           end-if
           move all SPACES to MESSAGE-TEXT
           exit.

      *****************************************************************
       Z-DISPLAY-SQL-CODE.
           add SQLCODE to ZERO giving MSG-SQL-VALUE
           move MSG-SQL-CODE to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TEXT
           if SQLCODE not = 0
              move sqlerrmc to MESSAGE-TEXT
              perform Z-DISPLAY-MESSAGE-TEXT
           end-if
           exit.

      *****************************************************************
      * Display the file status bytes. This routine will display as   *
      * four digits. If the full two byte file status is numeric it   *
      * will display as 00nn. If the 1st byte is a numeric nine (9)   *
      * the second byte will be treated as a binary number and will   *
      * display as 9nnn.                                              *
      *****************************************************************
       Z-DISPLAY-IO-STATUS.
           if  IO-STATUS not NUMERIC
           or  IO-STAT1 = '9'
               subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
               move IO-STAT2 to TWO-BYTES-RIGHT
               add TWO-BYTES-BINARY to ZERO giving IO-STATUS-4
               move IO-STAT1 to IO-STATUS-4A(1:1)
               move 'File Status is: nnnn' to MESSAGE-TEXT
               move IO-STATUS-4A to MESSAGE-TEXT(17:4)
               perform Z-DISPLAY-MESSAGE-TEXT
           else
               move '0000' to IO-STATUS-4A
               move IO-STATUS to IO-STATUS-4A(3:2)
               move 'File Status is: nnnn' to MESSAGE-TEXT
               move IO-STATUS-4A to MESSAGE-TEXT(17:4)
               perform Z-DISPLAY-MESSAGE-TEXT
           end-if
           exit.

      *****************************************************************
       Z-GET-DATE-AND-TIME.
           accept WORK-DATE from DATE YYYYMMDD
           accept WORK-TIME from TIME

           move WORK-DATE(1:4) to EDIT-DATE(1:4)
           move WORK-DATE(5:2) to EDIT-DATE(6:2)
           move WORK-DATE(7:2) to EDIT-DATE(9:2)

           move WORK-TIME(1:2) to EDIT-TIME(1:2)
           move WORK-TIME(3:2) to EDIT-TIME(4:2)
           move WORK-TIME(5:2) to EDIT-TIME(7:2)
           move WORK-TIME(7:2) to EDIT-TIME(10:2)

           exit.

      *****************************************************************
       Z-POST-COPYRIGHT.
           display SIM-TITLE     upon console
           display SIM-COPYRIGHT upon console
           exit.

      *****************************************************************
       Z-THANK-YOU.
           display SIM-THANKS-01 upon console
           display SIM-THANKS-02 upon console
           exit.

      *****************************************************************
      *                 This program is provided by:                  *
      *                    SimoTime Technologies                      *
      *         (C) Copyright 1987-2019 All Rights Reserved           *
      *           Web Site URL:   http://www.simotime.com             *
      *                 e-mail:   helpdesk@simotime.com               *
      *****************************************************************

Table of Contents Previous Section Next Section The COBOL Copy File

The following (CUSTCQ01.cpy) is a sample of the COBOL copy file used to define the table row structure.

      *****************************************************************
      *               CUSTCQ01.CPY - a COBOL Copy File                *
      *       A Customer Master File used by the Demo programs.       *
      *   This is an SQL Declare with primary key and unique index.   *
      *         Copyright (C) 1987-2019 SimoTime Technologies         *
      *                     All Rights Reserved                       *
      *              Provided by SimoTime Technologies                *
      *        Our e-mail address is: helpdesk@simotime.com           *
      *     Also, visit our Web Site at http://www.simotime.com       *
      *****************************************************************
           EXEC SQL DECLARE CUSTACC1 TABLE
                (
                 CUQ1_NUMBER            CHAR (12)      NOT NULL
                                                       PRIMARY KEY,
                 CUQ1_STATUS            CHAR (1)       NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_LAST_NAME         CHAR (28)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_FIRST_NAME        CHAR (20)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_MID_NAME          CHAR (20)      NOT NULL
                                                       WITH DEFAULT
                                                       SPACES,
                 CUQ1_ADDRESS_1         CHAR (48)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_ADDRESS_2         CHAR (48)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_CITY              CHAR (28)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_STATE             CHAR (28)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_POSTAL_CODE       CHAR (12)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_PHONE_HOME        CHAR (18)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_PHONE_WORK        CHAR (18)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_PHONE_CELL        CHAR (18)      NOT NULL
                                                       WITH DEFAULT,
      *          CUQ1_CREDIT_LIMIT      DECIMAL (7,0)  NOT NULL
      *                                                WITH DEFAULT,
      *          CUQ1_DISCOUNT_CODE_1   INTEGER        NOT NULL
      *                                                WITH DEFAULT,
      *          CUQ1_DISCOUNT_RATE_1   NUMBER (2,3)   NOT NULL
      *                                                WITH DEFAULT,
      *          CUQ1_DISCOUNT_DATE_1   CHAR (8)       NOT NULL
      *                                                WITH DEFAULT,
                 CUQ1_LADATE            CHAR (8)       NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_LATIME            CHAR (8)       NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_TOKEN             CHAR (3)       NOT NULL
                                                       WITH DEFAULT
                )
           END-EXEC.

       01  CUQ1-RECORD.
           05  CUQ1-NUMBER             PIC X(12).
           05  CUQ1-DATA.
               10  CUQ1-STATUS         PIC X.
               10  CUQ1-NAME.
                   15  CUQ1-LAST-NAME  PIC X(28).
                   15  CUQ1-FIRST-NAME PIC X(20).
                   15  CUQ1-MID-NAME   PIC X(20).
               10  CUQ1-ADDRESS-1      PIC X(48).
               10  CUQ1-ADDRESS-2      PIC X(48).
               10  CUQ1-CITY           PIC X(28).
               10  CUQ1-STATE          PIC X(28).
               10  CUQ1-POSTAL-CODE    PIC X(12).
               10  CUQ1-PHONE-HOME     PIC X(18).
               10  CUQ1-PHONE-WORK     PIC X(18).
               10  CUQ1-PHONE-CELL     PIC X(18).
               10  CUQ1-CREDIT-LIMIT   PIC 9(7)    COMP-3.
               10  CUQ1-DISCOUNT       OCCURS 3 TIMES.
                   15  CUQ1-DISCOUNT-CODE  PIC S9(3)   COMP.
                   15  CUQ1-DISCOUNT-RATE  PIC S9(2)V999.
                   15  CUQ1-DISCOUNT-DATE  PIC X(8).
               10  CUQ1-LADATE         PIC X(8).
               10  CUQ1-LATIME         PIC X(8).
               10  CUQ1-TOKEN          PIC X(3).
               10  FILLER              PIC X(145).
      *
      ***  CUSTCQ01 - End-of-Copy File - - - - - - - - - - - CUSTCQ01 *
      *****************************************************************
      *

Table of Contents Previous Section Next Section Summary

This example uses embedded SQL in a COBOL program to update a row within a table. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.

In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a greater awareness of the Data Management and Application Processing alternatives.

The documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.

SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please send an e-mail to: helpdesk@simotime.com or call 415 883-6565. We appreciate hearing from you.

Table of Contents Previous Section Next Section Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Table of Contents Previous Section Next Section Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Note: A SimoTime License is required for the items to be made available on a local system or server.

Table of Contents Previous Section Next Section Current Server or Internet Access

The following links may be to the current server or to the Internet.

Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the Link to Internet icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the Link to Server icon.

Link to Internet   Link to Server   Explore the Structure and Access Methods of a Relational Table that contains "Customer" information. This white paper provides an oveview of the programs available for managing a Relational Table containing Customer information.

Link to Internet   Link to Server   Explore how to Sequentially Access a Relational Table using a COBOL program with Cursor Processing. This program accesses a Relational Table containing Customer information and provides an example of how to use cursor processing to access a table sequentially by key accessing one row at a time.

Link to Internet   Link to Server   Explore how to Create a Relational Table using a COBOL program. This example accesses a Relational Table containing Customer information and shows how to create a table and create an index using a unique primary key.

Link to Internet   Link to Server   Explore how to Delete a Relational Table using a COBOL program. This example accesses a Relational Table containing Customer information and shows how to delete (or Drop) an index and a table.

Link to Internet   Link to Server   Explore how to Insert a row into a Relational Table using a COBOL program. This example accesses a Relational Table containing Customer information and shows how to insert a new row into a table.

Link to Internet   Link to Server   Explore how to Update a row in a Relational Table using a COBOL program. This sample accesses a Relational Table containing Customer information and shows how to update an existing row within a table.

Link to Internet   Link to Server   Explore the SQL Connection for more examples of how to create, manipulate and delete Relational Data Bases. The COBOL programs are written to compile and execute on a Windows System with SQL Server and Micro Focus Enterprise Server or an IBM Mainframe System with DB2.

Link to Internet   Link to Server   Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

Link to Internet   Link to Server   Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and/or QSAM files.

Table of Contents Previous Section Next Section Internet Access Required

The following links will require an internet connect.

This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products and services available from Micro Focus. This link requires an Internet Connection.

Table of Contents Previous Section Next Section Glossary of Terms

Link to Internet   Link to Server   Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Table of Contents Previous Section Next Section Comments or Feedback

This document was created and is copyrighted and maintained by SimoTime Technologies.

If you have any questions, suggestions, comments or feedback please call at 1 415 827-7045 or send an e-mail to: helpdesk@simotime.com

We appreciate hearing from you.

Table of Contents Previous Section Next Section Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform.

The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process.

SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call at 1 415 827-7045 or send an e-mail to: helpdesk@simotime.com

Also, check the web site at http://www.simotime.com


Return-to-Top
Customer Database, Update a Row using a COBOL with Embedded SQL Statements
Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved
When technology complements business
http://www.simotime.com