Cursor Processing
Customer Table, COBOL & EXEC SQL
  Table of Contents  v-16.01.01 - cuqcp101.htm 
  Introduction
  CMD Member for Batch Job
  JCL Member for Batch Job
  Input Specifications for IKJEFT01
  COBOL Demonstration Program
  The COBOL Copy File
  Summary
  Software Agreement and Disclaimer
  Downloads and Links
  Current Server or Internet Access
  Internet Access Required
  Glossary of Terms
  Comments or Feedback
  Company Overview
The SimoTime Home Page 

Table of Contents Previous Section Next Section Introduction

The technique of sequentially retrieving data with SQL one row at a time is referred to as cursor processing. This example will show how to process a data base table sequentially by key using cursor processing. In the world of programming there are many ways to solve a problem. This suite of programs is provided as a COBOL programming example of one of the possible solutions.


We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved

Table of Contents Previous Section Next Section CMD Member for Batch Job

The following is the Windows Command file (CUQCP1E1.cmd) that is required to run as a job on a PC using Micro Focus Net Express.

@echo OFF
rem  * *******************************************************************
rem  *               CUQCP1E1.CMD - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text    - COBOL with embedded SQL for Cursor Processing
rem  * Author  - SimoTime Technologies
rem  * Date    - November 11, 2003
rem  * Version - 08.07.25
rem  *
rem  * This set of programs illustrate the use of embedded SQL in a COBOL
rem  * program that fetches one row at a time from the CUST data base. A
rem  * sequential file containing one record for each row is created.
rem  *
rem  * This technique provides for the use of a single COBOL source
rem  * program that will run on ZOS, Windows or Unix.
rem  *
rem  * This set of programs will run on a Personal Computer with Windows
rem  * and Micro Focus Net Express or Mainframe Express.
rem  *
rem  *                    ************
rem  *                    * CUQCP1E1 *
rem  *                    ********cmd*
rem  *                         *
rem  *                         *
rem  *   ************     ************     ************
rem  *   * CUSTRDB1 *-----* CUQCP1C1 *-----* CUSTSEQ1 *
rem  *   ********rdb*     ********cbl*     *******rseq*
rem  *                         *
rem  *                         *
rem  *                    ************
rem  *                    *   EOJ    *
rem  *                    ************
rem  *
echo *
echo * The SQL Server must be started prior to executing this command.
echo *
     set CmdName=CUQCP1E1
     call ..\Env1BASE %CmdName%
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting JobName %CmdName%"
     set CUSTSEQ1=%BASECAT%\APPL\SIMOTIME.DATA.CUSTSEQ2.dat
     run CUQCP1C2
     if errorlevel = 1 set JobStatus=0001
     if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
     call SimoNOTE "Finished JobName %CmdName%"
     goto :End
:EojNOK
     call SimoNOTE "ABENDING JobName %CmdName%"
     call SimoNOTE "ABENDING Message JobStatus %JobStatus%"
     goto :End
:End
     if not "%1" == "nopause" pause
rem  * End-of-Command-File...

Table of Contents Previous Section Next Section JCL Member for Batch Job

The following is the mainframe JCL (CUQCP1J1.jcl) that is required to run as a job on the mainframe or as a Mainframe Express project on the a Windows System.

//CUQCP1J1 JOB SIMOTIME,ACCOUNT,CLASS=1,MSGCLASS=0,
//             NOTIFY=&SYSUID,
//             USER=&SYSUID
//* *******************************************************************
//*       CUQCP1J1.JCL - a JCL Member for Batch Job Processing        *
//*       This JCL Member is provided by SimoTime Technologies        *
//*           (C) Copyright 1987-2019 All Rights Reserved             *
//*             Web Site URL:   http://www.simotime.com               *
//*                   e-mail:   helpdesk@simotime.com                 *
//* *******************************************************************
//*
//* TEXT   - Execute COBOL program, use CURSOR Processing of a Table.
//* AUTHOR - SimoTime Technologies
//* DATE   - January 01, 1989
//*
//* This set of programs illustrate the use of a COBOL program with
//* embedded SQL syntax. This program will FETCH one row at a time
//* using Cursor Processing.
//*
//* This set of programs will run on a mainframe under ZOS or on
//* a personal computer running Windows and Mainframe Express (MFE)
//* by Micro Focus.
//*
//*                    ************
//*                    * CUQCP1J1 *
//*                    ********jcl*
//*                         *
//*                    ************
//*                    * IEFBR14  *
//*                    ********utl*
//*                         *
//*   ************     ************
//*   * SYSTSIN  *-----* IKJEFT01 *
//*   *******pdsm*     ********dbm*
//*                         *
//*                         *
//*   ************     ************     ************
//*   * CUSTRDB1 *-----* CUQCP1C1 *-----* CUSTSEQ2 *
//*   ********rdb*     ********cbl*     *******rseq*
//*                         *
//*                         *
//*                    ************
//*                    *   EOJ    *
//*                    ************
//*
//* Note-1: pdsm is a partitioned Data Set Member
//* Note-2: rseq is record sequential file
//*
//* *******************************************************************
//* Step 1 of 2, Delete any previously created file...
//*
//SEQ1DELT EXEC PGM=IEFBR14
//CUSTSEQ1 DD  DSN=SIMOTIME.DATA.CUSTSEQ2,DISP=(MOD,DELETE,DELETE),
//             STORCLAS=MFI,
//             SPACE=(TRK,5),
//             DCB=(RECFM=FB,LRECL=512,BLKSIZE=5120,DSORG=PS)
//* *******************************************************************
//* Step 2 of 2, Start the relational data base step.
//*
//FETCH    EXEC PGM=IKJEFT01
//CUSTSEQ1 DD  DSN=SIMOTIME.DATA.CUSTSEQ2,DISP=(NEW,CATLG,CATLG),
//             STORCLAS=MFI,
//             SPACE=(TRK,5),
//             DCB=(RECFM=FB,LRECL=512,BLKSIZE=5120,DSORG=PS)
//SYSOUT   DD  SYSOUT=*
//SYSPRINT DD  SYSOUT=*
//SYSTSPRT DD  SYSOUT=*
//SYSTSIN  DD  DSN=SIMOTIME.PDS.PARMLIB(CUQCP1X1),DISP=SHR
//

Table of Contents Previous Section Next Section Input Specifications for IKJEFT01

The SYSTSIN DD statement is used to define and allocate the input specifications that will be used by the IKJEFT01 program. The following is a Partitioned Data Set Member (PDSM) (CUQCP1X1.ctl) that contains the input specifications.

DSN SYSTEM(ACC1)
    RUN PROG(CUQCP1C1)
    END

Table of Contents Previous Section Next Section COBOL Demonstration Program

The following (CUQCP1C1.cbl) is a sample of the COBOL demonstration program that processes a table one row at a time. The program uses the SQL FETCH statement to sequentially access the rows in the table.

       IDENTIFICATION DIVISION.
       PROGRAM-ID.    CUQCP1C1.
       AUTHOR.        SIMOTIME TECHNOLOGIES.
      *****************************************************************
      * Copyright (C) 1987-2019 SimoTime Technologies.                *
      *                                                               *
      * All rights reserved.  Unpublished, all rights reserved under  *
      * copyright law and international treaty.  Use of a copyright   *
      * notice is precautionary only and does not imply publication   *
      * or disclosure.                                                *
      *                                                               *
      * Permission to use, copy, modify and distribute this software  *
      * for any commercial purpose requires a fee to be paid to       *
      * SimoTime Technologies. Once the fee is received by SimoTime   *
      * the latest version of the software will be delivered and a    *
      * license will be granted for use within an enterprise,         *
      * provided the SimoTime copyright notice appear on all copies   *
      * of the software. The SimoTime name or Logo may not be used    *
      * in any advertising or publicity pertaining to the use of the  *
      * software without the written permission of SimoTime           *
      * Technologies.                                                 *
      *                                                               *
      * Permission to use, copy and modify this software for a        *
      * non-commercial purpose and without fee is hereby granted,     *
      * provided the SimoTime copyright notice appear on all copies   *
      * of the software. The SimoTime name or Logo may not be used    *
      * in any advertising or publicity pertaining to the use of the  *
      * software without the written permission of SimoTime           *
      * Technologies.                                                 *
      *                                                               *
      * SimoTime Technologies makes no warranty or representations    *
      * about the suitability of the software for any purpose. It is  *
      * provided "AS IS" without any expressed or implied warranty,   *
      * including the implied warranties of merchantability, fitness  *
      * for a particular purpose and non-infringement. SimoTime       *
      * Technologies shall not be liable for any direct, indirect,    *
      * special or consequential damages resulting from the loss of   *
      * use, data or projects, whether in an action of contract or    *
      * tort, arising out of or in connection with the use or         *
      * performance of this software                                  *
      *                                                               *
      * SimoTime Technologies                                         *
      * 15 Carnoustie Drive                                           *
      * Novato, CA 94949-5849                                         *
      * 415.883.6565                                                  *
      *                                                               *
      * RESTRICTED RIGHTS LEGEND                                      *
      * Use, duplication, or disclosure by the Government is subject  *
      * to restrictions as set forth in subparagraph (c)(1)(ii) of    *
      * the Rights in Technical Data and Computer Software clause at  *
      * DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of          *
      * Commercial  Computer Software - Restricted Rights  at 48      *
      * CFR 52.227-19, as applicable.  Contact SimoTime Technologies, *
      * 15 Carnoustie Drive, Novato, CA 94949-5849.                   *
      *****************************************************************
       ENVIRONMENT DIVISION.
       INPUT-OUTPUT   SECTION.
       FILE-CONTROL.
      *****************************************************************
           SELECT CUSTSEQ1-FILE
               ASSIGN       to CUSTSEQ1
               ORGANIZATION is SEQUENTIAL
               ACCESS MODE  is SEQUENTIAL
               FILE STATUS  is CUSTSEQ1-STATUS.

      *****************************************************************
       DATA DIVISION.
       FILE SECTION.
       FD  CUSTSEQ1-FILE.
       COPY CUSTSQ01.

       WORKING-STORAGE SECTION.
      *****************************************************************
      *    Data-structure for Title and Copyright...
      *    ------------------------------------------------------------
       01  SIM-TITLE.
           05  T1 pic X(11) value '* CUQCP1C1 '.
           05  T2 pic X(34) value 'Cursor Processing, Customer RDB   '.
           05  T3 pic X(10) value ' v08.09.18'.
           05  T4 pic X(24) value ' http://www.simotime.com'.
       01  SIM-COPYRIGHT.
           05  C1 pic X(11) value '* CUQCP1C1 '.
           05  C2 pic X(20) value 'Copyright 1987-2019 '.
           05  C3 pic X(28) value '    SimoTime Technologies   '.
           05  C4 pic X(20) value ' All Rights Reserved'.

       01  SIM-THANKS-01.
           05  C1 pic X(11) value '* CUQCP1C1 '.
           05  C2 pic X(32) value 'Thank you for using this program'.
           05  C3 pic X(32) value ' provided from SimoTime Technolo'.
           05  C4 pic X(04) value 'gies'.

       01  SIM-THANKS-02.
           05  C1 pic X(11) value '* CUQCP1C1 '.
           05  C2 pic X(32) value 'Please send all inquires or sugg'.
           05  C3 pic X(32) value 'estions to the helpdesk@simotime'.
           05  C4 pic X(04) value '.com'.

       01  CUSTSEQ1-STATUS.
           05  CUSTSEQ1-STAT1      pic X.
           05  CUSTSEQ1-STAT2      pic X.

       01  IO-STATUS.
           05  IO-STAT1            pic X.
           05  IO-STAT2            pic X.
       01  TWO-BYTES.
           05  TWO-BYTES-LEFT      pic X.
           05  TWO-BYTES-RIGHT     pic X.
       01  TWO-BYTES-BINARY        redefines TWO-BYTES pic 9(4) comp.

       01  END-OF-FILE             pic X(3)    value 'NO '.

       01  APPL-RESULT             pic S9(9)   comp.
           88  APPL-AOK            value 0.
           88  APPL-EOF            value 16.

      *****************************************************************
      *    Buffer used for posting messages to the console.
      *    ------------------------------------------------------------
       01  MESSAGE-BUFFER.
           05  MESSAGE-HEADER      pic X(11)   value '* CUQCP1C1 '.
           05  MESSAGE-TEXT.
               10  MESSAGE-TEXT-1  pic X(68)   value SPACES.
               10  MESSAGE-TEXT-2  pic X(41)   value SPACES.
       01  MESSAGE-BUFFER-SIZE     pic 9(3)    value 120.

       01  DEBUG-FLAG              pic X       value 'Y'.
       01  CONNECT-FLAG            pic X       value 'N'.

       01  MSG-SQL-CODE.
           05  filler              pic X(2)    value '* '.
           05  FILLER              pic X(12)   value 'SQLCODE is  '.
           05  MSG-SQL-VALUE       pic S9(12)  SIGN LEADING SEPARATE
                                               value 0.

       01  MSG-SQL-STATE.
           05  filler              pic X(2)    value '* '.
           05  FILLER              pic X(12)   value 'SQLSTATE is '.
           05  MSG-SQL-STATE-5     pic X(5)    value SPACES.

       01  DISPLAY-LINE-01.
           05  filler              pic X(8)    value 'Cust #: '.
           05  DISPLAY-NUMBER      pic X(12)   value SPACES.
           05  filler              pic X(3)    value ' - '.
           05  DISPLAY-DESCRIPTION pic X(48)   value SPACES.

       01  FETCH-SUMMARY.
           05  filler      pic X(2)    value '* '.
           05  filler      pic X(23)   value 'Data Base FETCH count: '.
           05  FETCH-COUNT pic 9(7)    value 0.

       01  CUSTACC1-EOF                pic X      value 'N'.

      *****************************************************************
           EXEC SQL BEGIN DECLARE SECTION END-EXEC.

           EXEC SQL
                INCLUDE CUSTCQ01
           END-EXEC.

           EXEC SQL
              DECLARE CUCURSOR CURSOR FOR
              SELECT CUQ1_NUMBER,
                     CUQ1_STATUS,
                     CUQ1_LAST_NAME,
                     CUQ1_FIRST_NAME,
                     CUQ1_MID_NAME,
                     CUQ1_ADDRESS_1,
                     CUQ1_ADDRESS_2,
                     CUQ1_CITY,
                     CUQ1_STATE,
                     CUQ1_POSTAL_CODE,
                     CUQ1_PHONE_HOME,
                     CUQ1_PHONE_WORK,
                     CUQ1_PHONE_CELL,
                     CUQ1_LADATE,
                     CUQ1_LATIME,
                     CUQ1_TOKEN
              FROM CUSTACC1
              ORDER BY CUQ1_NUMBER
           END-EXEC.

           EXEC SQL INCLUDE
                SQLCA
           END-EXEC.

      *****************************************************************
       PROCEDURE DIVISION.

           perform Z-POST-COPYRIGHT

      *    Do an explicit connect or let the operating system or
      *    the Micro Focus sub-system manage the connect.
           if  CONNECT-FLAG = 'Y'
               perform CUSTACC1-CONNECT
           end-if

      *    EXEC SQL BEGIN TRANSACTION END-EXEC

           perform CUSTACC1-OPEN-CURSOR
           perform CUSTSEQ1-OPEN.

           perform until CUSTACC1-EOF not = 'N'
               perform CUSTACC1-FETCH
               if  CUSTACC1-EOF = 'N'
                   move CUQ1-RECORD to CUS1-RECORD
                   perform CUSTSEQ1-WRITE
               end-if
           end-perform

           perform CUSTSEQ1-CLOSE.
           perform CUSTACC1-CLOSE-CURSOR

           if  CONNECT-FLAG = 'Y'
               perform CUSTACC1-DISCONNECT
           end-if

           move FETCH-SUMMARY to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TO-CONSOLE

           perform Z-THANK-YOU.

           GOBACK.

      *****************************************************************
       CUSTACC1-CONNECT.
           EXEC SQL CONNECT TO 'CUSTACC1' user 'Admin' END-EXEC.
           evaluate SQLCODE
             when 0
               move 'Y' to CONNECT-FLAG
               move 0 to RETURN-CODE
               move '* Data Base CONNECT is Successful'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
             when OTHER
               move '* ABENDING! CONNECT attempt Failed'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
               perform Z-DISPLAY-SQL-MSGS-3
               add 16 to ZERO giving RETURN-CODE
               perform Z-ABEND-PROGRAM
           end-evaluate
           exit.

      *****************************************************************
       CUSTACC1-DISCONNECT.
           EXEC SQL DISCONNECT CURRENT END-EXEC.
           evaluate SQLCODE
             when 0
               move 'N' to CONNECT-FLAG
               move 0 to RETURN-CODE
               move '* Data Base DISCONNECT is Successful'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
             when OTHER
               move '* ABENDING! DISCONNECT attempt Failed'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
               perform Z-DISPLAY-SQL-MSGS-3
           end-evaluate
           exit.

      *****************************************************************
       CUSTACC1-OPEN-CURSOR.
           EXEC SQL OPEN CUCURSOR END-EXEC.

           evaluate SQLCODE
             when 0
               move '* Data Base OPEN CURSOR is Successful'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
             when OTHER
               move 'A' to CUSTACC1-EOF
               add 16 to ZERO giving RETURN-CODE
               move '* ABENDING! OPEN CURSOR attempt has failed'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-CONSOLE
               perform Z-DISPLAY-SQL-MSGS-3
               perform Z-ABEND-PROGRAM
           end-evaluate
           exit.
      *---------------------------------------------------------------*
       CUSTACC1-FETCH.
           initialize CUQ1-RECORD
           EXEC SQL FETCH CUCURSOR
                INTO :CUQ1-NUMBER,
                     :CUQ1-STATUS,
                     :CUQ1-LAST-NAME,
                     :CUQ1-FIRST-NAME,
                     :CUQ1-MID-NAME,
                     :CUQ1-ADDRESS-1,
                     :CUQ1-ADDRESS-2,
                     :CUQ1-CITY,
                     :CUQ1-STATE,
                     :CUQ1-POSTAL-CODE,
                     :CUQ1-PHONE-HOME,
                     :CUQ1-PHONE-WORK,
                     :CUQ1-PHONE-CELL,
                     :CUQ1-LADATE,
                     :CUQ1-LATIME,
                     :CUQ1-TOKEN
           END-EXEC.
           evaluate SQLCODE
             when 0 move 0 to RETURN-CODE
                    add 1 to FETCH-COUNT
             when 1 move 0 to RETURN-CODE
                    add 1 to FETCH-COUNT
             when +100
               move 'Y' to CUSTACC1-EOF
               move '* Data Base FETCH is at End-of-File'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
             when OTHER
               move 'A' to CUSTACC1-EOF
               add 16 to ZERO giving RETURN-CODE
               move 'ABENDING! FETCH attempt has failed'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-CONSOLE
               perform Z-DISPLAY-SQL-MSGS-3
           end-evaluate
           exit.
      *---------------------------------------------------------------*
       CUSTACC1-CLOSE-CURSOR.
           EXEC SQL CLOSE CUCURSOR END-EXEC.
           exit.

      *****************************************************************
       CUSTSEQ1-GET.
           read CUSTSEQ1-FILE
           if  CUSTSEQ1-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               if  CUSTSEQ1-STATUS = '10'
                   add 16 to ZERO giving APPL-RESULT
               else
                   add 12 to ZERO giving APPL-RESULT
               end-if
           end-if
           if  APPL-AOK
               CONTINUE
           else
               if  APPL-EOF
                   move 'YES' to END-OF-FILE
               end-if
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTSEQ1-WRITE.
           write CUS1-RECORD
           if  CUSTSEQ1-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               if  CUSTSEQ1-STATUS = '10'
                   add 16 to ZERO giving APPL-RESULT
               else
                   add 12 to ZERO giving APPL-RESULT
               end-if
           end-if
           if  APPL-AOK
               CONTINUE
           else
               if  APPL-EOF
                   move 'YES' to END-OF-FILE
               else
                   move 'CUSTSEQ1-FAILURE-WRITE...'
                     to   MESSAGE-TEXT
                   move CUSTSEQ1-STATUS to IO-STATUS
                   perform Z-DISPLAY-MESSAGE-TO-SYSOUT
                   perform Z-DISPLAY-IO-STATUS
                   perform Z-ABEND-PROGRAM
               end-if
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTSEQ1-REWRITE.
           REWRITE CUS1-RECORD
           if  CUSTSEQ1-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               if  CUSTSEQ1-STATUS = '10'
                   add 16 to ZERO giving APPL-RESULT
               else
                   add 12 to ZERO giving APPL-RESULT
               end-if
           end-if
           if  APPL-AOK
               CONTINUE
           else
               if  APPL-EOF
                   move 'YES' to END-OF-FILE
               else
                   move 'CUSTSEQ1-FAILURE-REWRITE...'
                     to   MESSAGE-TEXT
                   move CUSTSEQ1-STATUS to IO-STATUS
                   perform Z-DISPLAY-MESSAGE-TO-SYSOUT
                   perform Z-DISPLAY-IO-STATUS
                   perform Z-ABEND-PROGRAM
               end-if
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTSEQ1-OPEN.
           add 8 to ZERO giving APPL-RESULT.
           open OUTPUT CUSTSEQ1-FILE
           if  CUSTSEQ1-STATUS = '35'
               move 'CUSTSEQ1-FAILURE-OPEN-IO...'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
               move CUSTSEQ1-STATUS to IO-STATUS
               perform Z-DISPLAY-IO-STATUS
               move 'CUSTSEQ1-ATTEMPT-OPEN-OUTPUT...'
                 to MESSAGE-TEXT
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
               open output CUSTSEQ1-FILE
           end-if
           if  CUSTSEQ1-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               add 12 to ZERO giving APPL-RESULT
           end-if
           if  APPL-AOK
               CONTINUE
           else
               move 'CUSTSEQ1-FAILURE-OPEN...'
                 to MESSAGE-TEXT
               move CUSTSEQ1-STATUS to IO-STATUS
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
               perform Z-DISPLAY-IO-STATUS
               perform Z-ABEND-PROGRAM
           end-if
           exit.
      *---------------------------------------------------------------*
       CUSTSEQ1-CLOSE.
           add 8 to ZERO giving APPL-RESULT.
           close CUSTSEQ1-FILE
           if  CUSTSEQ1-STATUS = '00'
               subtract APPL-RESULT from APPL-RESULT
           else
               add 12 to ZERO giving APPL-RESULT
           end-if
           if  APPL-AOK
               CONTINUE
           else
               move 'CUSTSEQ1-FAILURE-CLOSE...'
                 to   MESSAGE-TEXT
               move CUSTSEQ1-STATUS to IO-STATUS
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
               perform Z-DISPLAY-IO-STATUS
               perform Z-ABEND-PROGRAM
           end-if
           exit.

      *****************************************************************
      * The following Z-Routines perform administrative tasks         *
      * for this program.                                             *
      *****************************************************************
       Z-ABEND-PROGRAM.
           if  MESSAGE-TEXT not = SPACES
               perform Z-DISPLAY-MESSAGE-TO-SYSOUT
           end-if
           move 'PROGRAM-IS-ABENDING...'  to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TO-SYSOUT
           if  CONNECT-FLAG = 'Y'
               perform CUSTACC1-DISCONNECT
           end-if
           add 12 to ZERO giving RETURN-CODE
           GOBACK.
      *    exit.
      *****************************************************************
      * Display the file status bytes. This routine will display as   *
      * two digits if the full two byte file status is numeric. If    *
      * second byte is non-numeric then it will be treated as a       *
      * binary number.                                                *
      *****************************************************************
       Z-DISPLAY-IO-STATUS.
           if  IO-STATUS not NUMERIC
           or  IO-STAT1 = '9'
               subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
               move IO-STAT2 to TWO-BYTES-RIGHT
               display '* CUQCP1C1 FILE-STATUS-' IO-STAT1 '/'
                       TWO-BYTES-BINARY upon console
           else
               display '* CUQCP1C1 FILE-STATUS-' IO-STATUS upon console
           end-if
           exit.
      *****************************************************************
       Z-POST-COPYRIGHT.
           display SIM-TITLE     upon console
           display SIM-COPYRIGHT upon console
           exit.

      *****************************************************************
       Z-DISPLAY-MESSAGE-TO-SYSOUT.
           if  MESSAGE-TEXT-2 = SPACES
               display MESSAGE-BUFFER(1:79) upon sysout
           else
               display MESSAGE-BUFFER       upon sysout
           end-if
           move all SPACES to MESSAGE-TEXT
           exit.

      *****************************************************************
       Z-DISPLAY-MESSAGE-TO-CONSOLE.
           if  MESSAGE-TEXT-2 = SPACES
               display MESSAGE-BUFFER(1:79) upon console
           else
               display MESSAGE-BUFFER       upon console
           end-if
           move all SPACES to MESSAGE-TEXT
           exit.

      *****************************************************************
       Z-DISPLAY-SQL-MSGS-3.
           perform Z-DISPLAY-SQL-CODE
           perform Z-DISPLAY-SQL-STATE
           perform Z-DISPLAY-SQL-ERRMC
           exit.

      *****************************************************************
       Z-DISPLAY-SQL-CODE.
           add SQLCODE to ZERO giving MSG-SQL-VALUE
           move MSG-SQL-CODE to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TO-CONSOLE
           exit.

      *****************************************************************
       Z-DISPLAY-SQL-STATE.
           move SQLSTATE to MSG-SQL-STATE-5
           move MSG-SQL-STATE to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TO-CONSOLE
           exit.

      *****************************************************************
       Z-DISPLAY-SQL-ERRMC.
           move sqlerrmc to MESSAGE-TEXT
           perform Z-DISPLAY-MESSAGE-TO-CONSOLE
           exit.

      *****************************************************************
       Z-THANK-YOU.
           display SIM-THANKS-01 upon console
           display SIM-THANKS-02 upon console
           exit.

      *****************************************************************
      *      This program is provided by SimoTime Technologies        *
      *         (C) Copyright 1987-2019 All Rights Reserved           *
      *           Web Site URL:   http://www.simotime.com             *
      *                 e-mail:   helpdesk@simotime.com               *
      *****************************************************************

Table of Contents Previous Section Next Section The COBOL Copy File

The following (CUSTCQ01.cpy) is a sample of the COBOL copy file used to define the table row structure.

      *****************************************************************
      *               CUSTCQ01.CPY - a COBOL Copy File                *
      *       A Customer Master File used by the Demo programs.       *
      *   This is an SQL Declare with primary key and unique index.   *
      *         Copyright (C) 1987-2019 SimoTime Technologies         *
      *                     All Rights Reserved                       *
      *              Provided by SimoTime Technologies                *
      *        Our e-mail address is: helpdesk@simotime.com           *
      *     Also, visit our Web Site at http://www.simotime.com       *
      *****************************************************************
           EXEC SQL DECLARE CUSTACC1 TABLE
                (
                 CUQ1_NUMBER            CHAR (12)      NOT NULL
                                                       PRIMARY KEY,
                 CUQ1_STATUS            CHAR (1)       NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_LAST_NAME         CHAR (28)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_FIRST_NAME        CHAR (20)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_MID_NAME          CHAR (20)      NOT NULL
                                                       WITH DEFAULT
                                                       SPACES,
                 CUQ1_ADDRESS_1         CHAR (48)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_ADDRESS_2         CHAR (48)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_CITY              CHAR (28)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_STATE             CHAR (28)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_POSTAL_CODE       CHAR (12)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_PHONE_HOME        CHAR (18)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_PHONE_WORK        CHAR (18)      NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_PHONE_CELL        CHAR (18)      NOT NULL
                                                       WITH DEFAULT,
      *          CUQ1_CREDIT_LIMIT      DECIMAL (7,0)  NOT NULL
      *                                                WITH DEFAULT,
      *          CUQ1_DISCOUNT_CODE_1   INTEGER        NOT NULL
      *                                                WITH DEFAULT,
      *          CUQ1_DISCOUNT_RATE_1   NUMBER (2,3)   NOT NULL
      *                                                WITH DEFAULT,
      *          CUQ1_DISCOUNT_DATE_1   CHAR (8)       NOT NULL
      *                                                WITH DEFAULT,
                 CUQ1_LADATE            CHAR (8)       NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_LATIME            CHAR (8)       NOT NULL
                                                       WITH DEFAULT,
                 CUQ1_TOKEN             CHAR (3)       NOT NULL
                                                       WITH DEFAULT
                )
           END-EXEC.

       01  CUQ1-RECORD.
           05  CUQ1-NUMBER             PIC X(12).
           05  CUQ1-DATA.
               10  CUQ1-STATUS         PIC X.
               10  CUQ1-NAME.
                   15  CUQ1-LAST-NAME  PIC X(28).
                   15  CUQ1-FIRST-NAME PIC X(20).
                   15  CUQ1-MID-NAME   PIC X(20).
               10  CUQ1-ADDRESS-1      PIC X(48).
               10  CUQ1-ADDRESS-2      PIC X(48).
               10  CUQ1-CITY           PIC X(28).
               10  CUQ1-STATE          PIC X(28).
               10  CUQ1-POSTAL-CODE    PIC X(12).
               10  CUQ1-PHONE-HOME     PIC X(18).
               10  CUQ1-PHONE-WORK     PIC X(18).
               10  CUQ1-PHONE-CELL     PIC X(18).
               10  CUQ1-CREDIT-LIMIT   PIC 9(7)    COMP-3.
               10  CUQ1-DISCOUNT       OCCURS 3 TIMES.
                   15  CUQ1-DISCOUNT-CODE  PIC S9(3)   COMP.
                   15  CUQ1-DISCOUNT-RATE  PIC S9(2)V999.
                   15  CUQ1-DISCOUNT-DATE  PIC X(8).
               10  CUQ1-LADATE         PIC X(8).
               10  CUQ1-LATIME         PIC X(8).
               10  CUQ1-TOKEN          PIC X(3).
               10  FILLER              PIC X(145).
      *
      ***  CUSTCQ01 - End-of-Copy File - - - - - - - - - - - CUSTCQ01 *
      *****************************************************************
      *

Table of Contents Previous Section Next Section Summary

This example will show how to process a data base table sequentially by key using cursor processing. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.

In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a greater awareness of the Data Management and Application Processing alternatives.

The documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.

SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please send an e-mail to: helpdesk@simotime.com or call 415 883-6565. We appreciate hearing from you.

Table of Contents Previous Section Next Section Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Table of Contents Previous Section Next Section Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Note: A SimoTime License is required for the items to be made available on a local system or server.

Table of Contents Previous Section Next Section Current Server or Internet Access

The following links may be to the current server or to the Internet.

Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the Link to Internet icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the Link to Server icon.

Link to Internet   Link to Server   Explore the Structure and Access Methods of a Relational Table that contains "Customer" information. This white paper provides an oveview of the programs available for managing a Relational Table containing Customer information.

Link to Internet   Link to Server   Explore how to Sequentially Access a Relational Table using a COBOL program with Cursor Processing. This program accesses a Relational Table containing Customer information and provides an example of how to use cursor processing to access a table sequentially by key accessing one row at a time.

Link to Internet   Link to Server   Explore how to Create a Relational Table using a COBOL program. This example accesses a Relational Table containing Customer information and shows how to create a table and create an index using a unique primary key.

Link to Internet   Link to Server   Explore how to Delete a Relational Table using a COBOL program. This example accesses a Relational Table containing Customer information and shows how to delete (or Drop) an index and a table.

Link to Internet   Link to Server   Explore how to Insert a row into a Relational Table using a COBOL program. This example accesses a Relational Table containing Customer information and shows how to insert a new row into a table.

Link to Internet   Link to Server   Explore how to Update a row in a Relational Table using a COBOL program. This sample accesses a Relational Table containing Customer information and shows how to update an existing row within a table.

Link to Internet   Link to Server   Explore the SQL Connection for more examples of how to create, manipulate and delete Relational Data Bases. The COBOL programs are written to compile and execute on a Windows System with SQL Server and Micro Focus Enterprise Server or an IBM Mainframe System with DB2.

Link to Internet   Link to Server   Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

Link to Internet   Link to Server   Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and/or QSAM files.

Table of Contents Previous Section Next Section Internet Access Required

The following links will require an internet connect.

This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products and services available from Micro Focus. This link requires an Internet Connection.

Table of Contents Previous Section Next Section Glossary of Terms

Link to Internet   Link to Server   Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Table of Contents Previous Section Next Section Comments or Feedback

This document was created and is copyrighted and maintained by SimoTime Technologies.

If you have any questions, suggestions, comments or feedback please call at 1 415 827-7045 or send an e-mail to: helpdesk@simotime.com

We appreciate hearing from you.

Table of Contents Previous Section Next Section Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform.

The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process.

SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call at 1 415 827-7045 or send an e-mail to: helpdesk@simotime.com

Also, check the web site at http://www.simotime.com


Return-to-Top
Customer Database, Cursor Processing using a COBOL with Embedded SQL Statements
Copyright © 1987-2019
SimoTime Technologies and Services
All Rights Reserved
When technology complements business
http://www.simotime.com