EXEC CICS LOAD of a Data Array
|
Non-Executable Member EXEC CICS LOAD of a Data Array |
|
| The SimoTime Home Page |
Introduction
The transaction identifier (or TRANSID) is "T2LD" and the program is "T2LOAD". This option will do an EXEC CICS LOAD of a non-Executable member that was created from an Assembler source member.
The technique of using Mainframe Assembler (or HLASM, High-Level Assembler) to create a data table or non-executable load member would typically use a subset of the mainframe assembler operation codes (or OPCODES) that focused on the creation of data.
When moving a mainframe CICS application from the mainframe to a non-mainframe platform (such as Windows, UNIX or Linux) using Micro Focus technology this technique of creating and loading tables will require extra consideration.
Micro Focus Mainframe Express (MFE) includes mainframe assembler capability. The assembler source code for the tables may be transferred from the mainframe to the MFE environment without changes to the source code. The source code may then be compiled using the Mainframe Assembler Option of MFE. Once the members are compiled (as non-executable load members or filename.MOD) the tables may be loaded under control of the MFE CICS Option using the EXEC CICS LOAD function.
At this point it is important to emphasize the encoding format for the mainframe and MFE is EBCDIC. In addition, the Mainframe Assembler and the Assembler Option in MFE are EBCDIC-centric and may function at the bit level.
Therefore, we are faced with two (2) challenges if the target platform is Enterprise Server running in an ASCII-encoded environment.
| 1. | Net Express and Enterprise Server do not include the mainframe assembler technology. We could be limited to running in an EBCDIC-encoded environment and using the .MOD files created by MFE. |
| 2. | How do we provide on-going support for Net Express and/or Enterprise Server for Mainframe Migration in either an EBCDIC or ASCII encoded environment? |
The good news is the table data that is maintained in the form of mainframe assembler source code typically uses a very small subset of the capabilities of mainframe assembler. A program (ASMOGENR) is available that provides the capability of processing an assembler source member that uses the mainframe assembler "Define Constant" (DC) or "Define Storage" DS statements to define the structure of the data in the table. For table items that are defined as "character" the ASMOGENR program has the ability to produce a load member for an EBCDIC or ASCII encoded environment.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved
Execute
This example may be executed by typing the TRANSID at the CICS startup screen or by selecting the menu option. The following message will be displayed on the screen, "Invoke, TABLE002 Loader Transaction". The message is displayed and the keyboard should be unlocked and ready for the next user request within a sub-second response time. The transaction will write multiple messages to the log file to display the execution of the program and the content of the loaded data table (i.e. non-Executable Load Member).
The following shows the records that are written to the log file.
2014/12/17 - 13:47:13.75 - T2LOAD - Program STARTING... 2014/12/17 - 13:47:13.75 - T2LOAD - TABLE LOADED SUCCESSFULLY 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00003, TABLE002 Element Size 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00011, TABLE002 Element Count 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00001. TABLE002 Element Content = 060 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00002. TABLE002 Element Content = 010 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00003. TABLE002 Element Content = 011 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00004. TABLE002 Element Content = 01A 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00005. TABLE002 Element Content = 020 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00006. TABLE002 Element Content = 021 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00007. TABLE002 Element Content = 02A 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00008. TABLE002 Element Content = 02B 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00009. TABLE002 Element Content = 900 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00010. TABLE002 Element Content = 999 2014/12/17 - 13:47:13.75 - T2LOAD - T2LOAD - 00011. TABLE002 Element Content = 99A 2014/12/17 - 13:47:13.75 - T2LOAD - Program FINISHED...
Technical Details
This section provides additional information about the ancillary tasks that are required to prepare the environment for executing the "Write-to-Log-File" transaction.
The Log File
The log file is a VSAM, Entry-Sequenced-Data-Set (ESDS). A batch job using the DELETE/DEFINE functions of IDCAMS is provided to create the VSAM, ESDS that will be used for logging user information.
Explore how to delete and define a new Entry Sequenced Data Set (ESDS) using Mainframe JCL. Once the new ESDS is created a COBOL program is used to add records to the data set.
The COBOL Program
The following is the COBOL program (T2LOAD.cbl) is the program that is used to load a non-executable load member.
*set CICSECM(LINKAGE=NO)
IDENTIFICATION DIVISION.
PROGRAM-ID. T2LOAD.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
* MAINTENANCE
* -----------
* 1989/02/27 Simmons, Created program.
* 2013/03/15 Simmons, Ported to Micro Focus
*
*****************************************************************
*
ENVIRONMENT DIVISION.
*****************************************************************
DATA DIVISION.
WORKING-STORAGE SECTION.
01 WORK-DATE.
05 WORK-DATE-CC pic X(02).
05 WORK-DATE-YY pic 9(02).
05 WORK-DATE-MM pic X(02).
05 WORK-DATE-DD pic 9(02).
01 WORK-TIME.
05 WORK-TIME-HH pic X(02).
05 WORK-TIME-NN pic X(02).
05 WORK-TIME-SS pic X(02).
05 WORK-TIME-TT pic X(02).
01 ADDRESS-LIST.
05 PTR-001 USAGE IS POINTER.
05 PTR-002 USAGE IS POINTER.
05 FILLER PIC X(72) VALUE IS LOW-VALUES.
01 ADDRESS-LIST-SIZE PIC 9(4) COMP VALUE 80.
01 MEMBER-NAME PIC X(8) VALUE 'TABLE002'.
01 NBR-05-GROUP.
05 NBR-05-VALUE PIC 9(5) value 0.
01 IX-1 PIC 9(5) value 0.
01 IX-2 PIC 9(5) value 0.
01 WS-MESSAGES.
05 WS-BEGIN-MSG PIC X(40) VALUE
'T2LOAD - TRANSACTION STARTED '.
05 WS-END-MSG PIC X(40) VALUE
'T2LOAD - LOAD TABLE LOADED SUCCESSFULLY'.
05 WS-ERR-LOAD-PROGRAM PIC X(50) VALUE
'T2LOAD - TRAN FAILED - LOAD PROGRAM FAILED '.
05 WS-T002-MSG-SIZE PIC X(40) VALUE
'T2LOAD - &&&&&, TABLE002 Element Size '.
05 WS-T002-MSG-COUNT PIC X(40) VALUE
'T2LOAD - &&&&&, TABLE002 Element Count '.
05 WS-T002-MSG-CONTENT PIC X(50) VALUE
'T2LOAD - &&&&&. TABLE002 Element Content = &&& '.
01 LOG-MESSAGE.
05 EDIT-DATE-TIME.
10 EDIT-DATE.
15 EDIT-DATE-CC pic X(02).
15 EDIT-DATE-YY pic 9(02).
15 FILLER pic X value '/'.
15 EDIT-DATE-MM pic X(02).
15 FILLER pic X value '/'.
15 EDIT-DATE-DD pic 9(02).
10 FILLER pic X(3) value ' - '.
10 EDIT-TIME.
15 EDIT-TIME-HH pic X(02).
15 FILLER pic X value ':'.
15 EDIT-TIME-MM pic X(02).
15 FILLER pic X value ':'.
15 EDIT-TIME-SS pic X(02).
15 FILLER pic X value '.'.
15 EDIT-TIME-TT pic X(02).
10 FILLER pic X(3) value ' - '.
10 PROGRAM-NAME pic x(8) value 'T2LOAD '.
10 FILLER pic X(3) value ' - '.
10 LOG-TEXT-GROUP.
15 LOG-TEXT pic X(50) value SPACES.
15 LOG-TEXT-EXT pic X(40) value SPACES.
01 ESD128-RECORD.
05 ESD128-DATA pic X(128) value SPACES.
01 ESD128-FILE pic X(8) value 'ESDSC128'.
01 ESDS-RESP-CODE pic 9(08) comp.
01 ESD128-RIDFLD PIC S9(8) COMP VALUE +0.
COPY DFHAID.
* COPY DFHEIBLK.
*****************************************************************
LINKAGE SECTION.
01 DFHCOMMAREA.
05 ESD128-PASS-AREA.
10 ESD128-PA-REQUEST pic X(12).
10 ESD128-PA-RESPOND pic X(04).
10 ESD128-PA-BUFFER pic X(128).
01 T002-BUFFER.
05 T002-SIZE PIC 9(4) COMP.
05 T002-COUNT PIC 9(4) COMP.
05 FILLER PIC X(2).
05 T002-ELEMENTS PIC X.
*****************************************************************
PROCEDURE DIVISION using DFHCOMMAREA.
perform Z-GET-DATE-AND-TIME
move EDIT-DATE-TIME to ESD128-DATA
move 'Program STARTING...' to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
move all LOW-VALUES to ADDRESS-LIST
* Load the non-Executable Member (Data Table)...
EXEC CICS LOAD
PROGRAM('TABLE002')
SET(PTR-002)
END-EXEC
if EIBRESP NOT = DFHRESP (NORMAL)
* Post an Error Message to the Log File...
move 'Transaction FAILED - Member not loaded'
to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
else
* Post the Table Information to the Log File...
move 'TABLE LOADED SUCCESSFULLY'
to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
set address of T002-BUFFER to PTR-002
add T002-SIZE to ZERO giving NBR-05-VALUE
move WS-T002-MSG-SIZE to LOG-TEXT-GROUP
inspect LOG-TEXT-GROUP replacing
first '&&&&&'
by NBR-05-VALUE
perform POST-TO-LOG-FILE-AND-CLEAR
add T002-COUNT to ZERO giving NBR-05-VALUE
move WS-T002-MSG-COUNT to LOG-TEXT-GROUP
inspect LOG-TEXT-GROUP replacing
first '&&&&&'
by NBR-05-VALUE
perform POST-TO-LOG-FILE-AND-CLEAR
add 1 to ZERO giving IX-1
add 1 to ZERO giving IX-2
perform until IX-2 > T002-COUNT
or IX-2 > 100
move WS-T002-MSG-CONTENT to LOG-TEXT-GROUP
inspect LOG-TEXT-GROUP replacing
first '&&&&&'
by IX-2
inspect LOG-TEXT-GROUP
replacing first '&&&'
by T002-ELEMENTS(IX-1:3)
perform POST-TO-LOG-FILE-AND-CLEAR
add 3 to IX-1
add 1 to IX-2
end-perform
end-if
EXEC CICS WRITEQ TS QUEUE ('ADRLST')
FROM(ADDRESS-LIST)
LENGTH(ADDRESS-LIST-SIZE)
END-EXEC
move 'Program FINISHED...' to LOG-TEXT-GROUP
perform POST-TO-LOG-FILE-AND-CLEAR
* Return to CICS...
EXEC CICS RETURN END-EXEC
* Should never get to here...
GOBACK.
*****************************************************************
POST-TO-LOG-FILE-AND-CLEAR.
move LOG-MESSAGE to ESD128-RECORD
perform WRITE-TO-LOG-FILE
move SPACES to LOG-TEXT-GROUP
move SPACES to ESD128-RECORD
exit.
*****************************************************************
WRITE-TO-LOG-FILE.
EXEC CICS WRITE
FILE (ESD128-FILE)
FROM (ESD128-RECORD)
RIDFLD (ESD128-RIDFLD)
RBA
LENGTH (LENGTH OF ESD128-RECORD)
RESP (ESDS-RESP-CODE)
END-EXEC
if ESDS-RESP-CODE not = 0
continue
end-if
exit.
*****************************************************************
TS-READ.
EXEC CICS READQ TS QUEUE ('ADRLST')
INTO (ADDRESS-LIST)
LENGTH (ADDRESS-LIST-SIZE)
END-EXEC
if ESDS-RESP-CODE not = 0
move all LOW-VALUES to ADDRESS-LIST
end-if
exit.
*****************************************************************
Z-GET-DATE-AND-TIME.
accept WORK-DATE from DATE YYYYMMDD
accept WORK-TIME from TIME
move 'ccyy/mm/dd' to EDIT-DATE
move WORK-DATE(1:4) to EDIT-DATE(1:4)
move WORK-DATE(5:2) to EDIT-DATE(6:2)
move WORK-DATE(7:2) to EDIT-DATE(9:2)
move 'hh:mm:ss.cc' to EDIT-TIME
move WORK-TIME(1:2) to EDIT-TIME(1:2)
move WORK-TIME(3:2) to EDIT-TIME(4:2)
move WORK-TIME(5:2) to EDIT-TIME(7:2)
move WORK-TIME(7:2) to EDIT-TIME(10:2)
exit.
The Assembler Table
The following is the Assembler Source Code (TABLE002.mlc) for the non-executable load member.
***********************************************************************
* TABLE002.MLC - Test Table for ASMOGENR *
* Provided by SimoTime Technologies *
* (C) Copyright 1987-2019 All Rights Reserved *
* Web Site URL: http://www.simotime.com *
* e-mail: helpdesk@simotime.com *
***********************************************************************
*
* ..:....1....:....2....:....3....:....4....:....5....:....6....:...
*
TABLE002 CSECT 0
PARM003 DC S(ESIZE)
PARM011 DC S(ECOUNT)
DC CL1' '
ARRAY003 DS 0H
DC CL3'060'
TAG001 EQU *
ESIZE003 EQU 3
ESIZE EQU *-ARRAY003
DC CL3'010'
DC CL3'011'
DC CL3'01A'
DC CL3'020'
DC CL3'021'
DC CL3'02A'
DC CL3'02B'
DC CL3'900'
DC CL3'999'
DC CL3'99A'
ECOUNT11 EQU 11
ECOUNT EQU (*-ARRAY003)/ESIZE
TEST0003 DC S(ESIZE)
TEST0011 DC S(ECOUNT)
END
The following link describes how to generate a non-executable member for the EBCDIC or ASCII encoded environment.
Explore The technology to Generate Non-Executable Load Members from Mainframe Assembler Source Code for use with Micro Focus Enterprise Server on a Windows, Linux or UNIX System. This technology has the ability to generate a non-executable member for the EBCDIC or ASCII encoded environment.
Summary
This option will do an EXEC CICS LOAD of a non-Executable member that was created from an Assembler source member. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the icon.
Explore The technology to Generate Non-Executable Load Members from Mainframe Assembler Source Code for use with Micro Focus Enterprise Server on a Windows, Linux or UNIX System. This technology has the ability to generate a non-executable member for the EBCDIC or ASCII encoded environment.
Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.
Explore the CICS Connection for more examples of mainframe CICS coding techniques and sample code.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore an Extended List of Software Technologies that are available for review and evaluation. The software technologies (or Z-Packs) provide individual programming examples, documentation and test data files in a single package. The Z-Packs are usually in zip format to reduce the amount of time to download.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connection.
This suite of programs and documentation is available for download. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Comments or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| Non-Executable Member or Data Table |
| Copyright © 1987-2025 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |