Record Layout/Structure
COBOL Copy File to HTML Document
  Table of Contents  v-14.03.28 - reclay01.htm 
  Introduction
  Execute
  Generate a Single HTML Document
  Generate Multiple HTML Documents
  Preparation
  System Environment
  Directory Structure
  Micro Focus Server Configuration
  Ancillary Functions
  Set the Environment
  Display and Log Messages
  Create HTML from COBOL Copy File
  Summary
  Software Agreement and Disclaimer
  Downloads and Links
  Current Server or Internet Access
  Internet Access Required
  Glossary of Terms
  Comments or Feedback
  Company Overview
The SimoTime Home Page 

Table of Contents Previous Section Next Section Introduction

This document will describe and demonstrate how to create multiple HTML documents for record structures (non-relational files and/or VSAM Data Sets) based on the definitions provided from the COBOL copy files. To run the jobs described in this document will require the SimoTime Enterprise License for SIMOLIBR01 or SIMOZAPS02. Also, Micro Focus Enterprise Server or Enterprise Developer is required.

An internet connection is required for Additional Information about SimoTime Products that support application and data migrations.


We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2017
SimoTime Technologies
All Rights Reserved

Table of Contents Previous Section Next Section Execute

The HTML document generation process will read a file that contains a list of COBOL copy file names (for a single HTML generation the list file should only have one (1) record) and generate an HTML document for each copy file.

The following links will show the HTML document created from a COBOL copy file that defines the record structure for a simple Customer Master File.

Link to Internet   Link to Server   Explore the Record Structure for the Customer Master File by viewing a generated HTML document based on a User-Defined COBOL copyfile.

Table of Contents Previous Section Next Section Generate a Single HTML Document

The following Command File (ADMCPY2HTMLGENRONE.cmd) will read a single COBOL copy file and create an HTML document for a record layout. The name of the COBOL copy file is supplied in an ASCII/Text file containing one record. The file name and extension are required. The file name should be a maximum of eight (8) characters and the file extension is usually .cpy.

The following statement shows the Windows Command being executed from a Command Line Window. For the command to execute correctly the current directory must be as shown below. This command will generate one HTML document.

C:\SIMOSAM1\DEVL\COMPOSER> ADMCPY2HTMLGENRONE

Note:  This command may be executed using Windows Explorer to select the directory and then double-clicking on the command.

The following is the content of the Command file that is used to generate a single HTML document.

@echo OFF
rem  * *******************************************************************
rem  *          ADMCPY2HTMLGENRONE.cmd - a Windows Command File          *
rem  *         This program is provided by SimoTime Enterprises          *
rem  *           (C) Copyright 1987-2013 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  * This procedure will create HTML documentation for record structures
rem  * (or record layouts) based on a COBOL copy file.
rem  *
rem  * The following commands use commands and programs that are provided
rem  * as part of the SimoTime Library (i.e. SIMOLIBR Folder).
rem  *
rem  * 1. Env1Base.cmd - this provides a single point for setting commonly
rem  *                   used environment variables.
rem  * 2. SimoNOTE.cmd - this provides a consistent process for displaying
rem  *                   messages to the screen and writing to a journal
rem  *                   or log file.
rem  * 3. ZCPY2HTM.cmd - this will do the actual generation of the
rem  *                   HTML document.
rem  * *******************************************************************
     call ..\Env1Base
     set CmdName=ADMCPY2HTMLGENRONE
rem  *
     call SimoNOTE "***********************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
rem  *
rem  * Set the environment variables, with SIMOGENS set to "PAUSE" the HTML
rem  * document will be displayed after it has been generated
     set AOK_Count=0
     set NOK_Count=0
     set SIMOGENS=PAUSE
     set SIMODROP=N
rem  *
     set SLIB=%BASELIB1%\CobCpy1
     set TLIB=%BASELIB1%\DATA\STRS
     for /F "eol=; tokens=1,2* delims=." %%i in (SIMOTIME.SIMOSAM1.LRECLONE.lst) do call ZCPY2HTM %SLIB%\%%i.CPY %TLIB%\%%i.htm IBM HTML
rem  *
     call SimoNOTE "AOKcount Compile Count for AOK is %AOK_Count% "
     call SimoNOTE "NOKcount Compile Count for NOK is %NOK_Count% "
     if  "%NOK_Count%" == "0" goto EOJAOK
:EOJNOK
     call SimoNOTE "ABENDING JobName %CmdName%.CMD "
     pause
     goto END
:EOJAOK
     call SimoNOTE "Finished JobName %CmdName%.CMD "
     goto END
:END
     if not "%SimoGENS%" == "BATCH" pause

Note:  The HTML document should be displayed as the last step of the generation process.

Table of Contents Previous Section Next Section Generate Multiple HTML Documents

The following Command File (ADMCPY2HTMLGENRALL.cmd) will read multiple COBOL copy files and create multiple HTML documents for many different record layouts. The member list of the COBOL copy file names is supplied in an ASCII/Text file containing one record for each copy file. The file name and extension are required. The file name should be a maximum of eight (8) characters and the file extension is usually .cpy.

The following statement shows the Windows Command being executed from a Command Line Window. For the command to execute correctly the current directory must be as shown below. This command will generate multiple HTML documents based on the member list.

C:\SIMOSAM1\DEVL\COMPOSER> ADMCPY2HTMLGENRALL

Note:  This command may be executed using Windows Explorer to select the directory and then double-clicking on the command.

The following is the content of the Command file that is used to generate multiple HTML documents.

@echo OFF
rem  * *******************************************************************
rem  *          ADMCPY2HTMLGENRALL.cmd - a Windows Command File          *
rem  *         This program is provided by SimoTime Enterprises          *
rem  *           (C) Copyright 1987-2013 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  * This procedure will create HTML documentation for record structures
rem  * (or record layouts) based on a COBOL copy file.
rem  *
rem  * The following commands use commands and programs that are provided
rem  * as part of the SimoTime Library (i.e. SIMOLIBR Folder).
rem  *
rem  * 1. Env1Base.cmd - this provides a single point for setting commonly
rem  *                   used environment variables.
rem  * 2. SimoNOTE.cmd - this provides a consistent process for displaying
rem  *                   messages to the screen and writing to a journal
rem  *                   or log file.
rem  * 3. ZCPY2HTM.cmd - this will do the actual generation of the
rem  *                   HTML document.
rem  * *******************************************************************
     call ..\Env1Base
     set CmdName=ADMCPY2HTMLGENRALL
rem  *
     call SimoNOTE "***********************************************%CmdName%.CMD"
     call SimoNOTE "Starting JobName %CmdName%.CMD"
rem  *
rem  * Set the environment variables.
     set AOK_Count=0
     set NOK_Count=0
     set SIMOGENS=PAUSE
     set SIMODROP=N
rem  *
     set SLIB=%BASELIB1%\CobCpy1
     set TLIB=%BASELIB1%\DATA\STRS
     for /F "eol=; tokens=1,2* delims=." %%i in (SIMOTIME.SIMOSAM1.LRECLALL.lst) do call ZCPY2HTM %SLIB%\%%i.CPY %TLIB%\%%i.htm IBM HTML
rem  *
     set SLIB=c:\SIMOLIBR
     set TLIB=%BASELIB1%\DATA\STRS
     for /F "eol=; tokens=1,2* delims=." %%i in (SIMOTIME.SIMOLIBR.LRECLALL.lst) do call ZCPY2HTM %SLIB%\%%i.CPY %TLIB%\%%i.htm IBM HTML
rem  *
     call SimoNOTE "AOKcount Compile Count for AOK is %AOK_Count% "
     call SimoNOTE "NOKcount Compile Count for NOK is %NOK_Count% "
     if  "%NOK_Count%" == "0" goto EOJAOK
:EOJNOK
     call SimoNOTE "ABENDING JobName %CmdName%.CMD "
     pause
     goto END
:EOJAOK
     call SimoNOTE "Finished JobName %CmdName%.CMD "
     goto END
:END
     if not "%SimoGENS%" == "BATCH" pause

Table of Contents Previous Section Next Section Preparation

WIP1

Table of Contents Previous Section Next Section System Environment

WIP2

Link to Internet   Link to Server   Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.

Table of Contents Previous Section Next Section Directory Structure

WIP2

Link to Internet   Link to Server   Explore a Directory Structure for a Development Environment that supports the execution of business applications using Micro Focus Enterprise Server.

Table of Contents Previous Section Next Section Micro Focus Server Configuration

WIP2

Link to Internet   Link to Server   Explore a Directory Structure for a Development Environment that supports the execution of business applications using Micro Focus Enterprise Server.

Table of Contents Previous Section Next Section Ancillary Functions

This section provides additional detail about Micro Focus Server and Windows usage and configuration.

Table of Contents Previous Section Next Section Set the Environment

A command file (ENV1BASE.cmd) is called from other command files to set commonly used environment variables. This provides a single point of definition. The following is a listing of the contents of the command file.

@echo OFF
rem  * *******************************************************************
rem  *               ENV1BASE.cmd - a Windows Command File               *
rem  *        This program is provided by SimoTime Technologies          *
rem  *           (C) Copyright 1987-2017 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Provide a single point to set common environment variables.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 1996
rem  *
rem  * Set the commonly used environment variables. This is used to provide
rem  * a single point for managing the commonly used environment variables.
rem  *
     set SimoLIBR=c:\SimoLIBR
     set BASELIB1=c:\SIMOSAM1\DEVL
     set BASELIB8=c:\SimoSAM8
     set BaseWIP1=c:\SimoSAM1\WIP1
     set DATAZERO=c:\SIMODATA\DEVL\DATA\ZERO
     set BASEAPP=%BaseLib1%
     set BASESYS=%BaseLib1%\SYS1
     set BASECAT=%BaseLib1%\DATA
     set SYSLOG=%BASESYS%\LOGS\SYSLOG_USER.DAT
     set SYSOUT=%BASEAPP%\LOGS\SYSOUT_SIMSAM01.TXT
     set SLZMSG=%BASEAPP%\LOGS\SLZMSG_USER.TXT
     set PostNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
     set SimoNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
     call SIMONOTE "* SIMONOTE Log File is %SIMONOTE% "
rem  *
     set MQBASE=C:\Program Files\IBM\WebSphere MQ
rem  *
rem  * Set the location for the Apache-Tomcat Server...
     set CATALINA_HOME=C:\APACHETC\apache-tomcat-7.0.52
rem  *
rem  * Set the Environment for the Java Environment...
     set JAVABASE=C:\Program Files (x86)\Java\jdk1.8.0_112
     set JAVASDK="%JAVABASE%\bin"
     set JAVA_HOME=%JAVABASE%
     set JRE_HOME=%JAVABASE%
rem  *
rem  * Set the environment for the Micro Focus technology...
     set MIFOEDEV=C:\Program Files (x86)\Micro Focus\Enterprise Developer
     set MIFOVCBL=C:\Program Files (x86)\Micro Focus\Visual COBOL
     set MIFOESTU=C:\Program Files (x86)\Micro Focus\Studio Enterprise Edition 6.0
     set MIFOEMFE="C:\Program Files (x86)\Micro Focus\Mainframe Express"
rem  *
rem  * Large file support, performance tuning and record locking of the File Handler
     set EXTFH=%BASESYS%\CONFIG\EXTFHBIG.CFG
rem  *
rem  * For IMS Support
     set ES_IMSLIB=%BASEAPP%\IMSLIB
     set ES_ACBLIB=%BASEAPP%\IMSLIB
rem  *
rem  * EZASOKETS Check EZASOKETS Enabled box or set ES_EZASOKET_SUPPORT=YES
     set EZACONFG=BASESYS1\CONFIG\EZACONFG.dat
rem  *
rem  * Resource Allocation and Performance for SORT and non-Relational Data
rem  set MFJSENGINE=SYNCSORT
     set SORTSCHEME=1
     set SORTSPACE=750000000
     set TMP=C:\SORTWORK
rem  *
     set ES_ALLOC_OVERRIDE=%BASESYS%\CONFIG\CATMAPA1.cfg
rem  * For CORE_ON_ERROR function, ABEND Dump
rem  *     set COBCONFIG_=%BASESYS%\CONFIG\diagnose.cfg
rem  *
rem  * Consolidated Trace Facility (CTF)
rem  *     set MFTRACE_CONFIG=%BASESYS%\CONFIG\ctf.cfg
rem  *     set MFTRACE_LOGS=c:\ctflogs
rem  *
rem  * For Job Restart, ABEND Recovery
     set MF_UCC11=Y
     set ES_JES_RESTART=Y
rem  *
rem  * Set environment for MFBSI (Micro Focus Batch Scheduling Interface)
     set ES_EMP_EXIT_1=mfbsiemx
     set MFBSI_DIR=%BASESYS%\LOGS\%JESSERVERNAME%
     set MFBSIEOP_CMD=ENABLE
     set MFBSIEOP_CSV=ENABLE
     set MFBSIEOP_HTM=ENABLE
     set MFBSIEOP_XML=ENABLE
rem  *
rem  * Set Behavior and Trace Flags for GETJOBDD
rem  *   Position=12345678/12345678
     set JDDFLAGS=nnnWnnnn/YYnnnnnn
rem  *
     set MAINFRAME_FLOATING_POINT=true
     set COBIDY=%BASEAPP%\COBIDY
     set COBPATH=.;%BASEAPP%\LOADLIB;%BASESYS%\LOADLIB;%SimoLIBR%
     set LIBPATH=.;%BASEAPP%\LOADLIB;%BASESYS%\LOADLIB;%SimoLIBR%
     set TXDIR=%BASESYS%\LOADLIB;%MIFOBASE%
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%
rem  *
rem  * If not already set then set the PATH for Micro Focus Directories
     if "%SIMOPATH%" == "Y" goto JUMPPATH
     if "%MIFOSYS1%" == "EDEV" goto JUMPEDEV
     if "%MIFOSYS1%" == "VCBL" goto JUMPVCBL
     if "%MIFOSYS1%" == "ESTU" goto JUMPESTU
     if "%MIFOSYS1%" == "EMFE" goto JUMPEMFE
:JUMPEDEV
     set path=%BASESYS%\LOADLIB;%MIFOEDEV%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOEDEV%\CPYLIB
     set MIFOBASE=%MIFOEDEV%
     goto JUMPPATH
:JUMPVCBL
     set path=%MIFOVCBL%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set MIFOBASE=%MIFOVCBL%
     goto JUMPPATH
:JUMPESTU
     set MIFOBASE=%MIFOESTU%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
:JUMPEMFE
     set MIFOBASE=%MIFOEMFE%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
rem  *
:JUMPPATH
     set SIMOPATH=Y
rem  *
     set USERCLASS=%BASELIB1%\LOADLIB
     set CLASSPATH=.
     set CLASSPATH=%CLASSPATH%;%JAVABASE%
     set CLASSPATH=%CLASSPATH%;%JAVABASE%\lib
     set CLASSPATH=%CLASSPATH%;\%USERCLASS%\simpacks
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes\simpacks
     if "%MIFOSYS1%" == "ESTU" set CLASSPATH=%CLASSPATH%;%MIFOBIN%
     if "%MIFOSYS1%" == "EDEV" set CLASSPATH=%CLASSPATH%;%MIFOEDEV%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%\mfcobol.jar
rem  *
     set JobStatus=0000
     call SimoNOTE "* Settings CmdName ENV1BASE.cmd, Version 14.03.28, %MIFOSYS1%"
     call SimoNOTE "* BaseAPP ..... %BASEAPP%"
rem *      call SimoNOTE "* MFBSIDIR .... %MFBSI_DIR% "
     call SimoNOTE "* MIFOSYS1 is %MIFOSYS1% "
     call SimoNOTE "* MIFOBASE is %MIFOBASE% "
     call SimoNOTE "* SIMOLIBR is %SIMOLIBR% "

Table of Contents Previous Section Next Section Display and Log Messages

The following is a listing of the contents of the (SimoNOTE.cmd) command file. This command will display a message to the screen and write a "Date/Time stamped" message to a log file.

@echo OFF
rem  * *******************************************************************
rem  *               SIMONOTE.CMD - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *            (C) Copyright 1987-2016 All Rights Reserved            *
rem  *              Web Site URL:   http://www.simotime.com              *
rem  *                    e-mail:   helpdesk@simotime.com                *
rem  * *******************************************************************
rem  *
rem  * Text    - Display message on screen and write to a log file.
rem  * Author  - SimoTime Technologies
rem  *
rem  * This script may be called from other scripts and expects a single
rem  * parameter enclosed in double quotes. The double quotes will be
rem  * removed. Before writing to the log file a date and time stamp
rem  * will be inserted in front of the message text.
rem  *
rem  * Note: The tilde (~) removes leading/trailing double-quotes.
rem  *
if "%SimoNOTE%" == "" set SimoNOTE=c:\SimoLIBR\LOGS\SimoTime.LOG
echo %date% %time% %~1>> %SimoNOTE%
echo %~1

Table of Contents Previous Section Next Section Create HTML from COBOL Copy File

The following command file (ZCPY2HTM.cmd) does the actual generation of the HTML document based on the COBOL Copy File.

@echo OFF
rem  * *******************************************************************
rem  *               ZCPY2HTM.cmd - a Windows Command File               *
rem  *         This program is provided by SimoTime Enterprises          *
rem  *           (C) Copyright 1987-2013 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  * This procedure will create HTML documentation for record structures
rem  * (or record layouts) based on a record definition provided in a
rem  * COBOL copy file.
rem  * The procedure will execute a pre-edit program to ensure the file
rem  * names for the HTML documents are lower case.
rem  * *******************************************************************
rem  *
rem  * Set the environment variable to use the default directives file.
     set TaskName=ZCPY2HTM
     call SimoNOTE "************************************************************%TaskName%"
     call SimoNOTE "Starting %TaskName% Preparation... Task=Set the Environment"
     set ConvertStatus=0000
rem  *
rem  * The following statements will read a COBOL copy file and create and
rem  * HTML document
     call SimoNOTE "Continue %TaskName% Generation.... Task=Create HTML for Record Layout"
     call REC1HTML %1 %2 IBM HTML
     if not "%ERRORLEVEL%" == "0" set ConvertStatus=0010
     if not "%ConvertStatus%" == "0000" goto :ConvertEojNOK
rem  *
rem  * The following four (4) statements will ensure the file names for
rem  * the HTML documents are in lower case.
     set FNCASEBEHAVIOR=LL\
     set CASELIST=%BASELIB1%\ADM1\CNTL\CASELIST.txt
     echo %2>%CASELIST%
     run FNCASEC1
rem  *
rem  * *******************************************************************
:ConvertEojAOK
     set /A AOK_Count=%AOK_Count% + 1
     call SimoNOTE "Complete %TaskName%, RC=%ConvertStatus%, PGM=%1"
     goto :End
rem  *
rem  * *******************************************************************
:ConvertEojNOK
     set JobStatus=%ConvertStatus%
     set /A NOK_Count=%NOK_Count% + 1
     call SimoNOTE "ABENDING %TaskName%, RC=%ConvertStatus%, PGM=%1, !!!ABENDING!!!"
     echo %1 - Error during Compile, refer to %BaseLib1%\LIST\%1.LST>%BaseLib1%\LOGS\%1.ERR
     goto :End
rem  *
rem  * *******************************************************************
:End

Table of Contents Previous Section Next Section Summary

The purpose of this document is to assist as a tutorial for new programmers or as a quick reference for experienced programmers. In the world of programming there are many ways to solve a problem. This document and the links to other documents are intended to provide a choice of alternatives.

Table of Contents Previous Section Next Section Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Table of Contents Previous Section Next Section Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Note: A SimoTime License is required for the items to be made available on a local system or server.

Table of Contents Previous Section Next Section Current Server or Internet Access

The following links may be to the current server or to the Internet.

Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the Link to Internet icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the Link to Server icon.

Link to Internet   Link to Server   Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.

Link to Internet   Link to Server   Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.

Link to Internet   Link to Server   Explore an Extended List of Software Technologies that are available for review and evaluation. The software technologies (or Z-Packs) provide individual programming examples, documentation and test data files in a single package. The Z-Packs are usually in zip format to reduce the amount of time to download.

Link to Internet   Link to Server   Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

Link to Internet   Link to Server   Explore The File Status Return Codes to interpret the results of accessing VSAM data sets and/or QSAM files.

Table of Contents Previous Section Next Section Internet Access Required

The following links will require an internet connection.

This suite of programs and documentation is available for download. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products and services available from Micro Focus. This link requires an Internet Connection.

Table of Contents Previous Section Next Section Glossary of Terms

Link to Internet   Link to Server   Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Table of Contents Previous Section Next Section Comments or Feedback

This document was created and is copyrighted and maintained by SimoTime Technologies.

If you have any questions, suggestions, comments or feedback please call or send an e-mail to: helpdesk@simotime.com

We appreciate hearing from you.

Table of Contents Previous Section Next Section Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com


Return-to-Top
Record Layout or Structure, COBOL Copy File to HTML Document
Copyright © 1987-2017
SimoTime Technologies and Services
All Rights Reserved
When technology complements business
http://www.simotime.com