Post JCL Information to a File
|
JCL Source Scanner Post JCL Information to a File |
|
| The SimoTime Home Page |
Introduction
This suite of programs will scan JCL members and extract file information based on the IDCAMS or DD statements. The file information will be written to a sequential file. This capability and the information it provides is quite useful when migrating a batch application and data from a Mainframe System to a Windows System using Micro Focus technologies.
The sequential file created by this suite of programs is in the format that is required to do a batch update to the File Properties Repository (a Micro Focus Key-Sequenced-Data-Set or Indexed File). For more information about how to do this refer to the File Properties and Repository Management document.
The source code, data sets and documentation are provided in a single zipped file called JCSCAN01.ZIP. This zipped file may be downloaded from the SimoTime Web site. This example illustrates the following functions.
| ||||||||||
| Functions Provided in this Suite of Programs |
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved
Quick Start
This section describes the process for scanning JCL Members, PROC's and/or Parameter Control Cards to extract file information from DD statements and the DEFINE statements of IDCAMS.
Create the List of Member Names
This job (JCSCANE1.CMD) is a three step job. The 1st step will do housekeeping to prepare the environment. The second step will delete any files left over from a previous run. The third step will create an ASCII/Text file containing a list of member names to be scanned.
C:\SimoSam1\LOADLIB>JCSCANE1
Scan Source Code for File Information
This job (JCSCANE2.cmd) is a three step job. The 1st step will do housekeeping to prepare the environment. The second step will delete any files left over from a previous run. The third step will scan the source members based on the list of member names and create a record sequential file containing information extracted from DD statements and DEFINE statements for IDCAMS.
C:\SimoSam1\LOADLIB>JCSCANE2
File Properties Repository Management
Once the File Information has been obtained from the JCL Scan the record sequential file is in a format that will feed the File Properties Repository Management System. Refer to the Catalog Population for Micro Focus and the File Properties Repository Management provided in separate documents.
Record Structure, File Repository
The following COBOL copy file (FPMASTB1.cpy) shows the record layout for the record sequential (RSEQ) file that is used to do a batch update of the File Properties Repository.
*****************************************************************
* FPMASTB1.CPY - a COBOL Copy File *
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
* Copy File for the record structure of the FPMASTER File that
* contains the properties or characteristics of non-relational
* data structures, Sequential file or VSAM Data Sets.
* This is a VSAM Keyed=Sequential-Data-Set or Key-Indexed File. *
*
01 FPMASTER-REC.
05 FPMASTER-DATA-01.
10 FPMASTER-BASE-INFO.
15 FPMASTER-LEVEL-NBR PIC 9(2). COL-A
15 FPMASTER-DSN-NAME PIC X(54). COL-B
15 FPMASTER-DD-NAME PIC X(17). COL-C
10 FPMASTER-FILE-PROPERTIES.
15 FPMASTER-DCB-DSORG PIC X(4). COL-D
15 FPMASTER-DCB-RECFM PIC X(4). COL-E
15 FPMASTER-MIN-LRECL PIC 9(5). COL-F
15 FPMASTER-MAX-LRECL PIC 9(5). COL-G
15 FPMASTER-KEY-POS PIC 9(5). COL-H
15 FPMASTER-KEY-LEN PIC 9(5). COL-I
15 FPMASTER-VSAM-DAT PIC X(44). COL-J
15 FPMASTER-VSAM-IDX PIC X(44). COL-K
10 FPMASTER-JOB-INFO.
15 FPMASTER-JCL-OVR1 PIC X(8). COL-L
15 FPMASTER-JCL-USR1 PIC X(8). COL-M
15 FPMASTER-JCL-USR2 PIC X(8). COL-N
10 FPMASTER-EXTENDED-INFO.
15 FPMASTER-EXTEND-S1 PIC X(4). COL-O
15 FPMASTER-EXTEND-S2 PIC X(4). COL-P
15 FPMASTER-EXTEND-M1 PIC X(16). COL-Q
15 FPMASTER-EXTEND-M2 PIC X(16). COL-R
15 FPMASTER-EXTEND-M3 PIC X(16). COL-S
15 FPMASTER-EXTEND-M4 PIC X(16). COL-T
15 FPMASTER-EXTEND-X1 PIC X(256). COL-U
15 FPMASTER-EXTEND-X2 PIC X(256). COL-V
10 FILLER PIC X(227).
*
*** FPMASTB1 - End-of-Copy File - - - - - - - - - - - FPMASTB1 *
*****************************************************************
*
Ancillary Tasks
This section provides technical detail about the supporting scripts and programs used or called by the primary jobs.
Set the Environment
A command file (ENV1BASE.cmd) is called from other command files to set commonly used environment variables. This provides a single point of definition. The following is a listing of the contents of the command file.
@echo OFF
rem * *******************************************************************
rem * ENV1BASE.cmd - a Windows Command File *
rem * This program is provided by SimoTime Technologies *
rem * (C) Copyright 1987-2021 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - Provide a single point to set common environment variables.
rem * Author - SimoTime Technologies
rem * Date - January 24, 1996
rem *
rem * Set the commonly used environment variables. This is used to provide
rem * a single point for managing the commonly used environment variables.
rem *
set SimoLIBR=c:\SimoLIBR
set BASELIB1=c:\SIMOSAM1\DEVL
set BASELIB8=c:\SimoSAM8
set BaseWIP1=c:\SimoSAM1\WIP1
set DATAZERO=c:\SIMODATA\DEVL\DATA\ZERO
set BASEAPP=%BaseLib1%
set BASESYS=%BaseLib1%\SYS1
set BASECAT=%BaseLib1%\DATA
set UMAPALIB=%BASECAT%\ASC1
set UMAPELIB=%BASECAT%\EBC1
set SYSLOG=%BASESYS%\LOGS\SYSLOG_USER.DAT
set SYSOUT=%BASEAPP%\LOGS\SYSOUT_SIMSAM01.txt
set SLZMSG=%BASEAPP%\LOGS\SLZMSG_USER.TXT
set PostNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
set SIMONOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.txt
set USERPOST=%BASEAPP%\LOGS\ASSIGNED_USER_POST_FILE.txt
if [%1]==[] goto NO_POST
set SYSOUT=%BaseLib1%\LOGS\SYSOUT_%1.txt
call SIMONOTE "+ ENV1BASE *"
call SIMONOTE "+ ENV1BASE ********************************************************************%1"
call SIMONOTE "+ ENV1BASE is preparing the System Environment..."
call SIMONOTE "+ SIMOLIBR is %SIMOLIBR%"
call SIMONOTE "+ MIFOSYS1 is %MIFOSYS1%"
call SIMONOTE "+ BASELIB1 is %BASELIB1%"
:NO_POST
call SIMONOTE "+ SIMONOTE Job Log File is %SIMONOTE% "
rem *
set MQBASE=C:\Program Files\IBM\WebSphere MQ
rem *
rem * Set the location for the Apache-Tomcat Server...
set CATALINA_HOME=C:\APACHETC\apache-tomcat-7.0.52
rem set CATALINA_HOME=C:\Program Files (x86)\Java\jdk1.8.0_112
rem *
rem * Set the Environment for the Java Environment...
rem set JAVABASE=C:\APACHETC\apache-tomcat-7.0.52
set JAVABASE=C:\Program Files (x86)\Java\jdk1.8.0_112
set JAVASDK="%JAVABASE%\bin"
set JAVA_HOME=%JAVABASE%
set JRE_HOME=%JAVABASE%
set SIMOTCAT=%CATALINA_HOME%\webapps\simotcat
set SIMPACKS=%CATALINA_HOME%\webapps\simotcat\WEB-INF\classes\simpacks
rem *
rem * Set the environment for the Micro Focus technology...
set MIFOEDEV=C:\Program Files (x86)\Micro Focus\Enterprise Developer
set MIFOVCBL=C:\Program Files (x86)\Micro Focus\Visual COBOL Build Tools
set MIFOESTU=C:\Program Files (x86)\Micro Focus\Studio Enterprise Edition 6.0
set MIFOEMFE="C:\Program Files (x86)\Micro Focus\Mainframe Express"
rem *
rem * Large file support, performance tuning and record locking of the File Handler
set EXTFH=%BASESYS%\CONFIG\EXTFHBIG.CFG
rem *
rem * For IMS Support
set ES_IMSLIB=%BASEAPP%\IMSLIB
set ES_ACBLIB=%BASEAPP%\IMSLIB
rem *
rem * EZASOKETS Check EZASOKETS Enabled box or set ES_EZASOKET_SUPPORT=YES
set EZACONFG=BASESYS1\CONFIG\EZACONFG.dat
rem *
rem * Resource Allocation and Performance for SORT and non-Relational Data
rem set MFJSENGINE=SYNCSORT
set SORTSCHEME=1
set SORTSPACE=750000000
set TMP=C:\SORTWORK
rem *
set ES_ALLOC_OVERRIDE=%BASESYS%\CONFIG\CATMAPA1.cfg
rem * For CORE_ON_ERROR function, ABEND Dump
rem * set COBCONFIG_=%BASESYS%\CONFIG\diagnose.cfg
rem *
rem * Consolidated Trace Facility (CTF)
rem * set MFTRACE_CONFIG=%BASESYS%\CONFIG\ctf.cfg
rem * set MFTRACE_LOGS=c:\ctflogs
rem *
rem * For Job Restart, ABEND Recovery
set MF_UCC11=Y
set ES_JES_RESTART=Y
rem *
rem * Set environment for MFBSI (Micro Focus Batch Scheduling Interface)
set ES_EMP_EXIT_1=mfbsiemx
set MFBSI_DIR=%BASESYS%\LOGS\%JESSERVERNAME%
set MFBSIEOP_CMD=ENABLE
set MFBSIEOP_CSV=ENABLE
set MFBSIEOP_HTM=ENABLE
set MFBSIEOP_XML=ENABLE
rem *
rem * Set Behavior and Trace Flags for GETJOBDD
rem * Position=12345678/12345678
set JDDFLAGS=nnnWnnnn/YYnnnnnn
rem *
rem * If not already set then set the PATH for Micro Focus Directories
if "%SIMOPATH%" == "Y" goto JUMPPATH
if "%MIFOSYS1%" == "EDEV" goto JUMPEDEV
if "%MIFOSYS1%" == "VCBL" goto JUMPVCBL
if "%MIFOSYS1%" == "ESTU" goto JUMPESTU
if "%MIFOSYS1%" == "EMFE" goto JUMPEMFE
:JUMPEDEV
set path=%BASESYS%\LOADLIB;%MIFOEDEV%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOEDEV%\CPYLIB
set MIFOBASE=%MIFOEDEV%
goto JUMPPATH
:JUMPVCBL
set path=%MIFOVCBL%\bin;%MIFOVCBL%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
set MIFOBASE=%MIFOVCBL%
goto JUMPPATH
:JUMPESTU
set MIFOBASE=%MIFOESTU%\Base
set MIFOBIN=%MIFOBASE%\bin
set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
goto JUMPPATH
:JUMPEMFE
set MIFOBASE=%MIFOEMFE%\Base
set MIFOBIN=%MIFOBASE%\bin
set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
goto JUMPPATH
rem *
:JUMPPATH
set SIMOPATH=Y
rem *
set MAINFRAME_FLOATING_POINT=true
set COBIDY=%BASEAPP%\COBIDY
set COBPATH=.;%BASEAPP%\LOADLIB;%BASEAPP%\LOADLIB\GNTS;%BASESYS%\LOADLIB;%SimoLIBR%
set LIBPATH=.;%BASEAPP%\LOADLIB;%BASEAPP%\LOADLIB\GNTS;%BASESYS%\LOADLIB;%SimoLIBR%
set TXDIR=%BASESYS%\LOADLIB;%MIFOBASE%
set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%
rem *
set USERCLASS=%BASELIB1%\LOADLIB
set CLASSPATH=.
set CLASSPATH=%CLASSPATH%;%JAVABASE%
set CLASSPATH=%CLASSPATH%;%JAVABASE%\lib
set CLASSPATH=%CLASSPATH%;\%USERCLASS%\simpacks
set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes
set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes\simpacks
rem *
if "%MIFOSYS1%" == "ESTU" set CLASSPATH=%CLASSPATH%;%MIFOBIN%
if "%MIFOSYS1%" == "EDEV" set CLASSPATH=%CLASSPATH%;%MIFOEDEV%
if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%
if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%\bin\mfcobol.jar
rem *
set JobStatus=0000
call SIMONOTE "+ ENV1BASE is returning to caller"
Display and Log Messages
The following (SimoNOTE.cmd) is a listing of the contents of the SimoNOTE command file.
@echo OFF rem * ******************************************************************* rem * SIMONOTE.cmd - a Windows Command File * rem * This program is provided by SimoTime Technologies * rem * (C) Copyright 1987-2019 All Rights Reserved * rem * Web Site URL: http://www.simotime.com * rem * e-mail: helpdesk@simotime.com * rem * ******************************************************************* rem * rem * Text - Display message on screen and write to a log file. rem * Author - SimoTime Technologies rem * rem * This script may be called from other scripts and expects a single rem * parameter enclosed in double quotes. The double quotes will be rem * removed. Before writing to the log file a date and time stamp rem * will be inserted in front of the message text. rem * rem * Note: The tilde (~) removes leading/trailing double-quotes. rem * if "%SimoNOTE%" == "" set SimoNOTE=c:\SimoLIBR\LOGS\SimoTime.LOG echo %date% %time% %~1>> %SimoNOTE% echo %~1
Technical Details
This section provides a technical overview of the Command Files (or scripts) and programs used by the JCL Scanning Application that extracts file properties from DD statements and DEFINE statements of IDCAMS.
Command Files
This section will focus on the command files.
Command Files, JCSCANE1
This job (JCSCANE1.cmd) is a multi-step job that will create an ASCII/Text file that contains a list of member names to be scanned.
@echo OFF
setlocal
set CMD_NAME=JCSCANE1
rem * *******************************************************************
rem * Batch Job Script - a Windows Command File *
rem * Provided by SimoTime Technologies aand Services *
rem * (C) Copyright 1987-2021 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - Pipe a DIR list to a file, convert to Record Sequential.
rem * Author - SimoTime Technologies and Services
rem * Date - January 15, 2021
rem *
rem * Create a list file for the JCL Members to be scanned. This procedure
rem * calls the following Windows Command Files.
rem * 1. ENV1BASE.cmd- this provides a single point for setting commonly
rem * used environment variables.
rem * 2. SIMONOTE.cmd - this provides a consistent process for posting
rem * messages to the screen or writing to a journal or
rem * log file.
rem * ************************************************************************
rem *
rem ************
rem * SET * Set the Environment Variables
rem ********jcl*
rem *
rem ************
rem * if exist * Delete previously created Files
rem ********utl*
rem *
rem ************
rem * DIR-ECHO * Create a JCL Member List
rem ********utl*
rem *
rem ************ ************ ************
rem * JCLLS080 *-----* JCSCANE2 *-----* FPRFFLD1 *
rem *******lseq* ********cmd* *******rseq*
rem *
rem ************
rem * EOJ *
rem ************
rem *
rem * ************************************************************************
rem *
call ..\ENV1BASE %CMD_NAME%
rem *
call SIMONOTE "*-----------------------------------------------------------------------------*01 of 03"
call SIMONOTE "* JOB_STEP 01 of 03, Preparing the System and Job Environment"
set JobStatus=0000
rem *
call SIMONOTE "*-----------------------------------------------------------------------------*02 of 03"
call SIMONOTE "* JOB_STEP 02 of 03, Create a list of names for JCL or Parameter Cards"
set JCSCANL1=%BASECAT%\APPL\SIMOTIME.UTIL.JCSCANL1.TXT
set JCSCANL2=%BASECAT%\APPL\SIMOTIME.UTIL.JCSCANL2.TXT
rem *
rem * Delete previously created Files
if exist %JCSCANL1% erase %JCSCANL1%
if exist %JCSCANL2% erase %JCSCANL2%
rem *
rem * Create the List of Member Names to be scanned.
rem * The DIR comand creates a list with filename.ext
rem * The FOR loop creates a member list with the
rem * fully qualified drive:\directory\filename.ext
rem *
dir /on /b /a-d %BaseLib1%\JCL\*.JCL>%JCSCANL1%
if not "%ERRORLEVEL%" == "0" set JobStatus=0020
if not "%JobStatus%" == "0000" goto :EOJTAG
for /F %%i in (%JCSCANL1%) do echo %BaseLib1%\JCL\%%i>>%JCSCANL2%
rem *
if not "%ERRORLEVEL%" == "0" set JobStatus=0022
if not "%JobStatus%" == "0000" goto :EOJTAG
rem *
:EOJTAG
call SIMONOTE "*-----------------------------------------------------------------------------*03 of 03"
call SIMONOTE "* JOB_STEP 03 of 03, End of Job Processing"
if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
call SIMONOTE "* DataMake %JCSCANL2%"
call SIMONOTE "* Finished CMD_NAME %CMD_NAME%, Job Status is %JobStatus% "
goto :End
:EojNOK
call SIMONOTE "* ABENDING CMD_NAME %CMD_NAME%, Job Status is %JobStatus% "
goto :End
:End
call SIMONOTE "* FileInfo SYSOUT=%SYSOUT%"
call SIMONOTE "* Finished JobName %CMD_NAME%.CMD"
if not "%SimoGENS%" == "BATCH" pause
endlocal
Command Files, JCSCANE2
This job (JCSCANE2.cmd) is a multi-step job that will scan source code based on a list of member names. The DD statements and DEFINE statements used by IDCAMS will be analyzed and the file properties will be written to a record in a sequential output file.
@echo OFF
rem * *******************************************************************
rem * JCSCANE2.CMD - a Windows Command File *
rem * This program is provided by SimoTime Technologies *
rem * (C) Copyright 1987-2019 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem * Scan the JCL Members using the list created in JCSCANE1 Cmd File and
rem * create a file that contain data file characteristics or Properties.
rem * The file properties are extracted from DD statements and Delete/Define
rem * statements used by IDCAMS.
rem * This procedure calls the following Windows Command Files.
rem * 1. ezSetEnv.CMD - this provides a single point for setting commonly
rem * used environment variables.
rem * 2. SimoNOTE.CMD - this provides a consistent process for displaying
rem * messages to the screen and writing to a journal or
rem * log file.
rem * ************************************************************************
rem ************
rem * SET * Set the Environment Variables
rem ********jcl*
rem *
rem ************ ************
rem * JCSCANL2 *-----* JCSCANC1 *
rem *******lseq* ********cbl*
rem * *
rem **************** *****call******
rem * *
rem * ************ ************ ************
rem * * JCLLS080 *-----* JCSCANC2 *-----* FPRFFLD1 *
rem * *******lseq* ********cbl* *******rseq*
rem * *
rem * ************
rem * * SIMOPARS *
rem * ********cbl*
rem ******************
rem *
rem ************
rem * EOJ *
rem ************
rem *
rem * ************************************************************************
rem *
setlocal
set CmdName=JCSCANE2
call ..\Env1Base
rem *
call SimoNOTE "****************************************************************%CmdName%.CMD"
call SimoNOTE "Starting JobName %CmdName%.CMD"
rem *
rem * Step 1 of 03, Prepare the Environment
rem *
set JCSCANL2=%BASECAT%\APPL\SIMOTIME.UTIL.JCSCANL2.TXT
set FPRFFLD1=%BASECAT%\APPL\SIMOTIME.UTIL.FPRFFLD1.DAT
rem *
rem * Step 2 of 03, Define a New Output File
rem *
rem * The following copy statement will create a directory entry for
rem * a file with zero records, a null file. This is a necessary step
rem * because the program used in the following step will attempt to
rem * add records to an existing file.
rem *
if NOT exist %FPRFFLD1% copy nul %FPRFFLD1%
rem *
rem * Step 3 of 03, Append Records Containing File Properties
rem *
rem * Read the List-of-Member-Names file, scan the members and append
rem * the file information from the DD statements and the DEFINE
rem * statements for IDCAMS to the previously created output file.
rem *
call SimoNOTE "InfoNote Scan the JCL or Parm Cards for File Properties"
set JCSCANBF=11100000
set SCANMODE=DATAMODE
run JCSCANC1
if not "%ERRORLEVEL%" == "0" set JobStatus=0010
if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
call SimoNOTE "DataMake %FPRFFLD1%"
call SimoNOTE "Finished CmdName %CmdName%, Job Status is %JobStatus% "
goto :End
:EojNOK
call SimoNOTE "ABENDING CmdName %CmdName%, Job Status is %JobStatus% "
goto :End
:End
call SimoNOTE "FileInfo SYSOUT=%SYSOUT%"
call SimoNOTE "Finished JobName %CmdName%.CMD"
if not "%SimoGENS%" == "BATCH" pause
endlocal
COBOL Programs
This section will focus on the COBOL programs.
COBOL Programs, JCSCANC1
This program will read the JCSCANL2 file that is a list of source members and/or parameter files (PARM CARDS) and for each record it will set an environment variable for the member name and then call JCSCANC2 to process (or scan) each member.
COBOL Programs, JCSCANC2
This program will read a source member, usually JCL, PROC or Parm Card, and produce an output containing data file properties from the DD and IDCAMS information.
Summary
This suite of programs will scan JCL members and extract file information based on the IDCAMS or DD statements. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the 
icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the 
icon.
Explore the JCL Connection for more examples of JCL functionality with programming techniques and sample code.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore how to manage a Repository of Information about Data Files used by an application or suite of applications. This link will focus on non-relational data structures such as traditional files, VSAM Data Sets, Partitioned Data Sets (PDS's) and Generation Data Groups (GDG's). The repository is a VSAM, Key-Sequenced-Data-Set (KSDS).
Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Explore the GnuCOBOL Technologies available from SourceForge. SourceForge is an Open Source community resource dedicated to helping open source projects be as successful as possible. GnuCOBOL (formerly OpenCOBOL) is a COBOL compiler with run time support. The compiler (cobc) translates COBOL source to executable using intermediate C, designated C compiler and linker. This link will require an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| JCL Scanner, Extract File Information from IDCAMS and DD Statements |
| Copyright © 1987-2025 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |