EZ* and SYS1* Commands Server Access and Operations

Introduction

This document is an introduction or overview of the EZ Series and SYS1 Series of Windows Command files that may be used to start a region within Enterprise Server, submit or schedule batch jobs to a region within Enterprise Server or stop a region within Enterprise Server. There are four (4) primary command files used in the EZ Series and SYS1 Series of command files

Note: The EZ Series of commands start with the letters EZ and are intended for use by the application programmers and business users. The SYS1 Series of commands start with the letters SYS1 and are intended for use by the operations staff and systems programmers.

The preceding command files will call the following command files.

The preceding command files are called from the primary command files to perform common processes in a consistent manner.

We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved

Quick Start

The "Quick Start" provides a quick summary of how to use the most common command files of the EZ Series and SYS1 Series of commands. The EZ Series is primarily intended for use by business users that need to access and use the applications. The SYS1 Series is intended for use by the Operations Staff and Systems Programmers to support and maintain the Micro Focus Enterprise Server and the User Configured Application Servers.

Quick Start, Start a Server

The SYS1START command file calls the ENV1BASE command file to set commonly used environment variables. It then calls the SYS1BAKConsole command file to provide a backup of the previously created "console.log" file. It then starts the specified server based on the first parameter of the command line. The following is an example of the command line syntax. The first parameter is the name of the server to be started.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB> SYS1START ServerName

Quick Start, Stop a Server

The SYS1STOP command file calls the ENV1BASE command file to set commonly used environment variables. It then stops the specified server based on the first parameter of the command line. The following is an example of the command line syntax. The first parameter is the name of the server to be stopped.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB> SYS1STOP ServerName

Quick Start, Submit a Job

The EZSUB command file calls the ENV1BASE command file to set commonly used environment variables. It then submits the job name that is specified as the second parameter to the specified server based on the first parameter of the command line. The following is an example of the command line syntax. The first parameter is the name of the server and the second parameter is the job name (i.e. JCL member).

C:\SIMOSAM1\DEVL\LOADLIB> EZSUB ServerName JobName

Note: A specified job will be submitted to the server. When the server accepts the job control is returned to the user with a zero return code.

Quick Start, Schedule a Job

The ezSCHEDULE command file calls the ENV1BASE command file to set commonly used environment variables. It then submits the job name that is specified as the second parameter to the specified server based on the first parameter on the command line. The following is an example of the command line syntax. The first parameter is the name of the server and the second parameter is the job name (i.e. JCL member).

C:\SIMOSAM1\DEVL\LOADLIB> EZSCHEDULE ServerName JobName

Note-1: A specified job will be submitted to the server. After the job is executed control is returned to the user with a return code that reflects the job completion code.

Note-2: A prerequisite for running this command is the Micro Focus Batch Scheduler Interface (or MFBSI).

EZname & SYS1name Commands

The commands and associated programs in this section provide additional capability and/or specialized functions that are complimentary to the base programs included in this package.

Run a COBOL Program without JCL

This command (EZEXEC.cmd) is available in a separate package. This utility program provides a specialized function. It provides for the execution of a COBOL program without using JCL. The COBOL program may expect a parameter via its LINKAGE SECTION to be in the standard format as if it were executed by JCL. This utility program will read the parameter string from the Windows Command line and re-format to the JCL format and call the COBOL program. The COBOL program does not know it was executed from a non-JCL environment.

C:\SIMOSAM1\DEVL\LOADLIB>  EZEXEC ProgramName Parameter

Force a Server to Stop (Terminate)

This command (SYS1FORCE.cmd) calls the ENV1BASE command file to set commonly used environment variables. It then stops (or terminates) the specified server based on the first parameter of the command line. The following is an example of the command line syntax. The first parameter is the name of the server to be stopped.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB> SYS1FORCE ServerName

Caution!  This command should only be used when the SYS1STOP command fails to stop a server. The SYS1FORCE will terminate the server and all user jobs in active mode will be cancelled.

List the Content of a Catalog

This command (SYS1CATLIST.cmd) is available in a separate package. This utility program provides a quick and simple way to list or hex-dump the contents of the CATALOG.DAT file to an ASCII/Text file from a Windows Command. The list or hex-dump file may be viewed with NotePad. The program default will produce a list file with the binary values removed prior to writing to the text file.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB>  SYS1CATLIST

By setting the CATCTL01 environment variable to a null value the catalog list program will use the program defaults and produce a list file with the binary values removed prior to writing to the text file. The following shows the contents of a control file that will produce a dump of the catalog entries.

*
/DUMP
/NOSHOWDUMP
*
/FLAG-HDR=Y
/FLAG-EBC=N
/FLAG-HEX=Y
/FLAG-ASC=Y

The following describes the possibly records that may be included in the control file.

Note:  If a control file is not used an output file in the "LIST" format will be produced.

Export Catalog Information to CSV File

This command (SYS1CATXPORT.cmd) is available in a separate package. This utility program provides a quick and simple way to export file information that is available in the CATALOG.DAT file to a CSV File that is easily imported into a Microsoft Excel spreadsheet or relational data base such as Microsoft Access or MS/SQL

C:\SIMOSAM1\DEVL\SYS1\LOADLIB>  SYS1CATXPORT

Review Results of Job Execution

This command (SYS1JESLOG.cmd) and the associated utility program provides a quick and simple way to create and view a list of Job summary information that includes job start, stop and elapsed times.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB>  SYS1JESLOG

The following is an example of the output for the SYS1JESLOG utility program.

20110718,12:25:11,JOB01895,UVBR00J1,                 ,SIMOTIME,JOB ,STARTED ,        ,
20110718,12:25:11,JOB01895,UVBR00J1,                 ,SIMOTIME,JOB ,ENDED   ,0000    ,00:00:00
20110718,12:28:24,JOB01896,UVBR00J1,                 ,SIMOTIME,JOB ,STARTED ,        ,
20110718,12:28:24,JOB01896,UVBR00J1,                 ,SIMOTIME,JOB ,ENDED   ,0000    ,00:00:00
20110718,12:37:36,JOB01897,STAMLRJ1,                 ,mfuser  ,JOB ,STARTED ,        ,
20110718,12:37:40,JOB01897,STAMLRJ1,                 ,mfuser  ,JOB ,ENDED   ,0000    ,00:00:04
20110718,12:40:06,JOB01898,STAMLRJ1,                 ,mfuser  ,JOB ,STARTED ,        ,
20110718,12:40:11,JOB01898,STAMLRJ1,                 ,mfuser  ,JOB ,ENDED   ,0000    ,00:00:05
20110718,12:42:23,JOB01899,STAMLRJ1,                 ,mfuser  ,JOB ,STARTED ,        ,
20110718,12:42:28,JOB01899,STAMLRJ1,                 ,mfuser  ,JOB ,ENDED   ,0000    ,00:00:05
20110718,13:10:44,JOB01900,UVBR00J1,                 ,SIMOTIME,JOB ,STARTED ,        ,
20110718,13:10:44,JOB01900,UVBR00J1,                 ,SIMOTIME,JOB ,ENDED   ,0000    ,00:00:00
20110718,13:13:00,JOB01901,UVBR00J1,                 ,SIMOTIME,JOB ,STARTED ,        ,
20110718,13:13:01,JOB01901,UVBR00J1,                 ,SIMOTIME,JOB ,ENDED   ,0000    ,00:00:01
20110718,17:46:39,JOB01902,CUQUP1J1,                 ,mfuser  ,JOB ,STARTED ,        ,
20110718,17:47:00,JOB01902,CUQUP1J1,                 ,mfuser  ,JOB ,ENDED   ,0000    ,00:00:21
20110719,08:08:51,JOB01903,CCSRDRJ9,                 ,SIMOCICA,JOB ,STARTED ,        ,
20110719,08:08:51,JOB01903,CCSRDRJ9,                 ,SIMOCICA,JOB ,ENDED   ,0000    ,00:00:00

Get FCT Information from DFHDRDAT

This command (SYS1CSDFCTGET.cmd) and the associated utility program provides a quick and simple way to identify and obtain a list of the files defined in the CICS System Definitions (CSD) file. For the Micro Focus environment this information is stored in the DFHDRDAT file.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB>  SYS1CSDFCTGET

Additional information about the SYS1CSDFCTGET command may be found in the Technical Information section of this document.

Get PCT Information from DFHDRDAT

This command (SYS1CSDPCTGET.cmd) and the associated utility program provides a quick and simple way to identify and obtain a list of the transactions defined in the CICS System Definitions (CSD) file. For the Micro Focus environment this information is stored in the DFHDRDAT file.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB>  SYS1CSDPCTGET

Additional information about the SYS1CSDPCTGET command may be found in the Technical Information section of this document.

Disable/Close a CICS File from Batch

This command (SYS1FILEDISABLE.cmd) and the associated utility program provides a quick and simple way to close and disable a file allocated to CICS from a Batch environment.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB>  SYS1FILEDISABLE ServerName FileName

Additional information about the SYS1FILEDISABLE command may be found in the Technical Information section of this document.

Enable/Open a CICS File from Batch

This command (SYS1FILEENABLE.cmd) and the associated utility program provides a quick and simple way to enable and open a file allocated to CICS from a Batch environment.

C:\SIMOSAM1\DEVL\SYS1\LOADLIB>  SYS1FILEENABLE ServerName FileName

Additional information about the SYS1FILEENABLE command may be found in the Technical Information section of this document.

Ancillary or Secondary Functions

This section provides additional detail about Micro Focus Server usage and configuration. The commands described in this section are usually called from other commands and not called directly by a business user.

Set the Environment

A command file (ENV1BASE.cmd) is called from other command files to set commonly used environment variables. This provides a single point of definition. The following is a listing of the contents of the command file

@echo OFF
rem  * *******************************************************************
rem  *               ENV1BASE.cmd - a Windows Command File               *
rem  *        This program is provided by SimoTime Technologies          *
rem  *           (C) Copyright 1987-2021 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Provide a single point to set common environment variables.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 1996
rem  *
rem  * Set the commonly used environment variables. This is used to provide
rem  * a single point for managing the commonly used environment variables.
rem  *
     set SimoLIBR=c:\SimoLIBR
     set BASELIB1=c:\SIMOSAM1\DEVL
     set BASELIB8=c:\SimoSAM8
     set BaseWIP1=c:\SimoSAM1\WIP1
     set DATAZERO=c:\SIMODATA\DEVL\DATA\ZERO
     set BASEAPP=%BaseLib1%
     set BASESYS=%BaseLib1%\SYS1
     set BASECAT=%BaseLib1%\DATA
     set UMAPALIB=%BASECAT%\ASC1
     set UMAPELIB=%BASECAT%\EBC1
     set SYSLOG=%BASESYS%\LOGS\SYSLOG_USER.DAT
     set SYSOUT=%BASEAPP%\LOGS\SYSOUT_SIMSAM01.txt
     set SLZMSG=%BASEAPP%\LOGS\SLZMSG_USER.TXT
     set PostNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
     set SIMONOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.txt
     set USERPOST=%BASEAPP%\LOGS\ASSIGNED_USER_POST_FILE.txt
     if [%1]==[] goto NO_POST
     set SYSOUT=%BaseLib1%\LOGS\SYSOUT_%1.txt
     call SIMONOTE "+ ENV1BASE *"
     call SIMONOTE "+ ENV1BASE ********************************************************************%1"
     call SIMONOTE "+ ENV1BASE is preparing the System Environment..."
     call SIMONOTE "+ SIMOLIBR is %SIMOLIBR%"
     call SIMONOTE "+ MIFOSYS1 is %MIFOSYS1%"
     call SIMONOTE "+ BASELIB1 is %BASELIB1%"
:NO_POST
     call SIMONOTE "+ SIMONOTE Job Log File is %SIMONOTE% "
rem  *
     set MQBASE=C:\Program Files\IBM\WebSphere MQ
rem  *
rem  * Set the location for the Apache-Tomcat Server...
     set CATALINA_HOME=C:\APACHETC\apache-tomcat-7.0.52
rem     set CATALINA_HOME=C:\Program Files (x86)\Java\jdk1.8.0_112
rem  *
rem  * Set the Environment for the Java Environment...
rem     set JAVABASE=C:\APACHETC\apache-tomcat-7.0.52
     set JAVABASE=C:\Program Files (x86)\Java\jdk1.8.0_112
     set JAVASDK="%JAVABASE%\bin"
     set JAVA_HOME=%JAVABASE%
     set JRE_HOME=%JAVABASE%
     set SIMOTCAT=%CATALINA_HOME%\webapps\simotcat
     set SIMPACKS=%CATALINA_HOME%\webapps\simotcat\WEB-INF\classes\simpacks
rem  *
rem  * Set the environment for the Micro Focus technology...
     set MIFOEDEV=C:\Program Files (x86)\Micro Focus\Enterprise Developer
     set MIFOVCBL=C:\Program Files (x86)\Micro Focus\Visual COBOL Build Tools
     set MIFOESTU=C:\Program Files (x86)\Micro Focus\Studio Enterprise Edition 6.0
     set MIFOEMFE="C:\Program Files (x86)\Micro Focus\Mainframe Express"
rem  *
rem  * Large file support, performance tuning and record locking of the File Handler
     set EXTFH=%BASESYS%\CONFIG\EXTFHBIG.CFG
rem  *
rem  * For IMS Support
     set ES_IMSLIB=%BASEAPP%\IMSLIB
     set ES_ACBLIB=%BASEAPP%\IMSLIB
rem  *
rem  * EZASOKETS Check EZASOKETS Enabled box or set ES_EZASOKET_SUPPORT=YES
     set EZACONFG=BASESYS1\CONFIG\EZACONFG.dat
rem  *
rem  * Resource Allocation and Performance for SORT and non-Relational Data
rem  set MFJSENGINE=SYNCSORT
     set SORTSCHEME=1
     set SORTSPACE=750000000
     set TMP=C:\SORTWORK
rem  *
     set ES_ALLOC_OVERRIDE=%BASESYS%\CONFIG\CATMAPA1.cfg
rem  * For CORE_ON_ERROR function, ABEND Dump
rem  *     set COBCONFIG_=%BASESYS%\CONFIG\diagnose.cfg
rem  *
rem  * Consolidated Trace Facility (CTF)
rem  *     set MFTRACE_CONFIG=%BASESYS%\CONFIG\ctf.cfg
rem  *     set MFTRACE_LOGS=c:\ctflogs
rem  *
rem  * For Job Restart, ABEND Recovery
     set MF_UCC11=Y
     set ES_JES_RESTART=Y
rem  *
rem  * Set environment for MFBSI (Micro Focus Batch Scheduling Interface)
     set ES_EMP_EXIT_1=mfbsiemx
     set MFBSI_DIR=%BASESYS%\LOGS\%JESSERVERNAME%
     set MFBSIEOP_CMD=ENABLE
     set MFBSIEOP_CSV=ENABLE
     set MFBSIEOP_HTM=ENABLE
     set MFBSIEOP_XML=ENABLE
rem  *
rem  * Set Behavior and Trace Flags for GETJOBDD
rem  *   Position=12345678/12345678
     set JDDFLAGS=nnnWnnnn/YYnnnnnn
rem  *
rem  * If not already set then set the PATH for Micro Focus Directories
     if "%SIMOPATH%" == "Y" goto JUMPPATH
     if "%MIFOSYS1%" == "EDEV" goto JUMPEDEV
     if "%MIFOSYS1%" == "VCBL" goto JUMPVCBL
     if "%MIFOSYS1%" == "ESTU" goto JUMPESTU
     if "%MIFOSYS1%" == "EMFE" goto JUMPEMFE
:JUMPEDEV
     set path=%BASESYS%\LOADLIB;%MIFOEDEV%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOEDEV%\CPYLIB
     set MIFOBASE=%MIFOEDEV%
     goto JUMPPATH
:JUMPVCBL
     set path=%MIFOVCBL%\bin;%MIFOVCBL%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set MIFOBASE=%MIFOVCBL%
     goto JUMPPATH
:JUMPESTU
     set MIFOBASE=%MIFOESTU%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
:JUMPEMFE
     set MIFOBASE=%MIFOEMFE%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
rem  *
:JUMPPATH
     set SIMOPATH=Y
rem  *
     set MAINFRAME_FLOATING_POINT=true
     set COBIDY=%BASEAPP%\COBIDY
     set COBPATH=.;%BASEAPP%\LOADLIB;%BASEAPP%\LOADLIB\GNTS;%BASESYS%\LOADLIB;%SimoLIBR%
     set LIBPATH=.;%BASEAPP%\LOADLIB;%BASEAPP%\LOADLIB\GNTS;%BASESYS%\LOADLIB;%SimoLIBR%
     set TXDIR=%BASESYS%\LOADLIB;%MIFOBASE%
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%
rem  *
     set USERCLASS=%BASELIB1%\LOADLIB
     set CLASSPATH=.
     set CLASSPATH=%CLASSPATH%;%JAVABASE%
     set CLASSPATH=%CLASSPATH%;%JAVABASE%\lib
     set CLASSPATH=%CLASSPATH%;\%USERCLASS%\simpacks
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes\simpacks
rem  *
     if "%MIFOSYS1%" == "ESTU" set CLASSPATH=%CLASSPATH%;%MIFOBIN%
     if "%MIFOSYS1%" == "EDEV" set CLASSPATH=%CLASSPATH%;%MIFOEDEV%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%\bin\mfcobol.jar
rem  *
     set JobStatus=0000
     call SIMONOTE "+ ENV1BASE is returning to caller"

Display and Log Messages

The following is a listing of the contents of the SimoNOTE.cmd command file.

@echo OFF
rem  * *******************************************************************
rem  *               SIMONOTE.cmd - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *            (C) Copyright 1987-2019 All Rights Reserved            *
rem  *              Web Site URL:   http://www.simotime.com              *
rem  *                    e-mail:   helpdesk@simotime.com                *
rem  * *******************************************************************
rem  *
rem  * Text    - Display message on screen and write to a log file.
rem  * Author  - SimoTime Technologies
rem  *
rem  * This script may be called from other scripts and expects a single
rem  * parameter enclosed in double quotes. The double quotes will be
rem  * removed. Before writing to the log file a date and time stamp
rem  * will be inserted in front of the message text.
rem  *
rem  * Note: The tilde (~) removes leading/trailing double-quotes.
rem  *
if "%SimoNOTE%" == "" set SimoNOTE=c:\SimoLIBR\LOGS\SimoTime.LOG
echo %date% %time% %~1>> %SimoNOTE%
echo %~1

CONSOLE.LOG Backup, Ten Levels

A command file (SYS1BAKConsole.cmd) is called from the SYS1START.CMD file when starting a server. Enterprise Server will make a single backup copy of the console log but one level of backup is usually not enough. This command will keep ten levels of backup for the console.log file.

The following is a listing of the contents of the SYS1BAKCONSOLE.cmd command file.

@echo OFF
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Console Back up, maintain ten (10) levels
rem  *      The ezServerName environment must be set to the
rem  *      server name prior to calling this procedure
rem  *
     call ..\..\Env1base
     set SDIR=%BASESYS%\LOGS\%JESServerName%
     set TDIR=%BASESYS%\LOGS\%JESServerName%
rem  *
     call SimoNOTE "****************************************SYS1BAKConsole"
     call SimoNOTE "Starting CmdName SYS1BAKConsole, User is %USERNAME%"
rem  *
     if exist %SDIR%\Console_log_10.txt  erase %TDIR%\Console_log_10.txt
     if exist %SDIR%\Console_log_09.txt rename %TDIR%\Console_log_09.txt Console_log_10.txt
     if exist %SDIR%\Console_log_08.txt rename %TDIR%\Console_log_08.txt Console_log_09.txt
     if exist %SDIR%\Console_log_07.txt rename %TDIR%\Console_log_07.txt Console_log_08.txt
     if exist %SDIR%\Console_log_06.txt rename %TDIR%\Console_log_06.txt Console_log_07.txt
     if exist %SDIR%\Console_log_05.txt rename %TDIR%\Console_log_05.txt Console_log_06.txt
     if exist %SDIR%\Console_log_04.txt rename %TDIR%\Console_log_04.txt Console_log_05.txt
     if exist %SDIR%\Console_log_03.txt rename %TDIR%\Console_log_03.txt Console_log_04.txt
     if exist %SDIR%\Console_log_02.txt rename %TDIR%\Console_log_02.txt Console_log_03.txt
     if exist %SDIR%\Console_log_01.txt rename %TDIR%\Console_log_01.txt Console_log_02.txt
     if exist %SDIR%\console.log          copy %TDIR%\console.log %TDIR%\Console_log_01.txt
rem  *
     call SimoNOTE "Complete CmdName SYS1BAKConsole.CMD, User is %USERNAME%"
rem  *

CATALOG.DAT Backup, Ten Levels

A command file (SYS1BAKCatalog.cmd) is called from the SYS1START.CMD file when starting a server. This command will keep ten levels of backup for the CATALOG.DAT file.

The following is a listing of the contents of the SYS1BAKCATALOG.cmd command file.

@echo OFF
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Catalog Back up, maintain ten (10) levels
rem  *      The ezServerName environment must be set to the
rem  *      server name prior to calling this procedure
rem  *
     call ..\..\Env1base
     set SDIR=%BASECAT%
     set TDIR=%BASESYS%\LOGS\%JESServerName%
rem  *
     call SimoNOTE "****************************************SYS1BAKCatalog"
     call SimoNOTE "Starting CmdName SYS1BAKCatalog, User is %USERNAME%"
rem  *
     if exist %TDIR%\CATALOG_BAK_10.DAT  erase %TDIR%\CATALOG_BAK_10.DAT
     if exist %TDIR%\CATALOG_BAK_09.DAT rename %TDIR%\CATALOG_BAK_09.DAT CATALOG_BAK_10.DAT
     if exist %TDIR%\CATALOG_BAK_08.DAT rename %TDIR%\CATALOG_BAK_08.DAT CATALOG_BAK_09.DAT
     if exist %TDIR%\CATALOG_BAK_07.DAT rename %TDIR%\CATALOG_BAK_07.DAT CATALOG_BAK_08.DAT
     if exist %TDIR%\CATALOG_BAK_06.DAT rename %TDIR%\CATALOG_BAK_06.DAT CATALOG_BAK_07.DAT
     if exist %TDIR%\CATALOG_BAK_05.DAT rename %TDIR%\CATALOG_BAK_05.DAT CATALOG_BAK_06.DAT
     if exist %TDIR%\CATALOG_BAK_04.DAT rename %TDIR%\CATALOG_BAK_04.DAT CATALOG_BAK_05.DAT
     if exist %TDIR%\CATALOG_BAK_03.DAT rename %TDIR%\CATALOG_BAK_03.DAT CATALOG_BAK_04.DAT
     if exist %TDIR%\CATALOG_BAK_02.DAT rename %TDIR%\CATALOG_BAK_02.DAT CATALOG_BAK_03.DAT
     if exist %TDIR%\CATALOG_BAK_01.DAT rename %TDIR%\CATALOG_BAK_01.DAT CATALOG_BAK_02.DAT
     if exist %SDIR%\CATALOG.DAT          copy %SDIR%\CATALOG.DAT %TDIR%\CATALOG_BAK_01.DAT
rem  *
     call SimoNOTE "Complete CmdName SYS1BAKCatalog.CMD, User is %USERNAME%"
rem  *

Possibilities and Considerations

This section provides information that addresses specific items pertaining to the function and capabilities and their potential use within or beyond the author's original design objectives.

Frequently Asked Questions (FAQ's)

This section is a list of frequently asked questions preceded by a date stamp.

Technical Information

This section provides additional detail about the ezSERIES of command files.

SYS1START (Start a Server)

This command is used to start a server. The name of the server is defined in the first parameter.

SYS1START Diagram of Logic flow

The following flow chart shows the processing logic for the SYS1START command..

SYS1START Command

The following is a listing of the SYS1START.cmd command file.

@echo OFF
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Start a server (or region)
rem  *      Parameter one must be the server name
rem  *
rem  * Set the common environment variables
     set JESServerName=%1
     call ..\..\Env1BASE
rem  * Provide up to ten (10) levels of backup for the console.log
     call SYS1BAKConsole
     call SYS1BAKCatalog
     call SimoNOTE "****************************************SYS1START"
     call SimoNOTE "Starting CmdName SYS1START %JESServerName%, User is %USERNAME%"
rem  *
     set DEBUGEXIT=TRUE
     set MFJUXITLOG=%BaseLib1%\LOGS\MFJCLXIT.LOG
     set JDDFLAGS=NNNWNNNN/NNNNNNNN
rem  *
     casstart -r%1 /w
rem  *
     call SimoNOTE "Complete CmdName SYS1START %JESServerName%, User is %USERNAME%"

SYS1STOP Command

The following is a listing of the SYS1STOP.cmd command file.

@echo OFF
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Stop a server (or region)
rem  *      Parameter one must be the server name
rem  *
     set ezServerName=%1
     call ..\..\Env1BASE
rem  *
     call SimoNOTE "****************************************SYS1STOP"
     call SimoNOTE "Starting CmdName SYS1STOP %ezServerName%, User is %USERNAME%"
rem  *
     casstop -r%1
rem  *
     call SimoNOTE "Complete CmdName SYS1STOP %ezServerName%, User is %USERNAME%"

EZSUB Command

The following is a listing of the EZSUB.cmd command file.

@echo OFF
rem  * ************************************************************************
rem  *                   EZSUB.CMD - a Windows Command File                   *
rem  *           This program is provided by SimoTime Technologies            *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Submit a Job (to a Server or Region)
rem  *      Parameter 1 is Server Name
rem  *      Parameter 2 is Job Name, a JCL member name without
rem  *                  an extension
rem  *
     call ..\Env1BASE
     call SimoNOTE "****************************************ezSUB"
     call SimoNOTE "Starting CmdName ezSUB, User is %USERNAME%"
rem  *
     if "%1" == "" (set JobStatus=0091
                    goto EOJNOK)
     if "%2" == "" (set JobStatus=0092
                    goto EOJNOK)
rem  *
     call cassub -j%BaseLib1%\JCL\%2.JCL -r%1
     if not "%ERRORLEVEL%" == "0" (set JobStatus=%ERRORLEVEL%
                                    goto EOJNOK)
     goto EOJAOK
:EOJNOK
     call SimoNOTE "ABENDING CmdName ezSUB, JobStatus is %JobStatus%"
     if "%JobStatus%" == "0091" call SimoNOTE "Parameter 1 must be Server Name"
     if "%JobStatus%" == "0092" call SimoNOTE "Parameter 2 must be Job Name"
     goto :END
:EOJAOK
     call SimoNOTE "Complete CmdName ezSUB, JobStatus is %JobStatus%"
     goto :END
:END
     exit /B %JobStatus%

EZSCHEDULE Command

The following is a listing of the EZSCHEDULE.cmd command file.

@echo OFF
rem  * ************************************************************************
rem  *               EZSCHEDULE.CMD - a Windows Command File                  *
rem  *           This program is provided by SimoTime Technologies            *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Batch Scheduler Interface
rem  *      Parameter 1 is Server Name
rem  *      Parameter 2 is Job Name, a JCL member name without
rem  *                  an extension
rem  *
     set JESSERVERNAME=%1
     call ..\env1BASE
     call SimoNOTE "****************************************ezSCHEDULE"
     call SimoNOTE "Starting CmdName ezSCHEDULE, User is %USERNAME%"
rem  *
     if "%1" == "" (set JobStatus=0091
                    goto EOJNOK)
     if "%2" == "" (set JobStatus=0092
                    goto EOJNOK)
rem  * Schedule and Monitor the Job
     call SimoNOTE "Continue CmdName ezSCHEDULE, Server is %JESSERVERNAME%, Job is %2 "
     call SimoNOTE "Continue CmdName ezSCHEDULE, %DATE% - %TIME% "
rem  * C:\Windows\System32\cmd.exe /C start /affinity 1 C:\(ProgramFolder)\(program).exe
rem  * C:\Windows\System32\cmd.exe /C start /affinity 6 run MFBSIJCL -j%BaseLib1%\JCL\%2.JCL -r%1 END
     run MFBSIJCL -j%BASEAPP%\JCL\%2.JCL -r%1 %3 END
     echo * ezSCHEDULE, CC=%ERRORLEVEL%
     if not "%ERRORLEVEL%" == "0" set JobStatus=%ERRORLEVEL%
     if not "%JobStatus%" == "0000" goto :EOJNOK
echo * Rename the MFBSI Log file with appended date and time values
     set OLDNAME=%MFBSI_DIR%\%2.LOG
     run MFBSIEOP
     if not "%ERRORLEVEL%" == "0" set JobStatus=%ERRORLEVEL%
     call SimoNOTE "MFJESDIR %OLDNAME% "
     if not "%JobStatus%" == "0000" goto :EOJNOK
     goto :EOJAOK
:EOJNOK
     if "%JobStatus%" == "0091" (call SimoNOTE "Parameter 1 must be Server Name"
                                 goto EOJNOK2)
     if "%JobStatus%" == "0092" (call SimoNOTE "Parameter 2 must be Job Name"
                                 goto EOJNOK2)
     if "%JobStatus%" == "209"  (call SimoNOTE "Requested JCL Member is missing or invalid,"
                                 call SimoNOTE "or requested server not available"
                                 goto EOJNOK2)
     set OLDNAME=%MFBSI_DIR%\%2.LOG
     run MFBSIEOP
:EOJNOK2
     call SimoNOTE "ABENDING CmdName ezSCHEDULE, %JESSERVERNAME%, %2 JobStatus is %JobStatus% "
     goto :END
:EOJAOK
     call SimoNOTE "Complete CmdName ezSCHEDULE, %DATE% - %TIME% "
     call SimoNOTE "Complete CmdName ezSCHEDULE, %JESSERVERNAME%, %2 JobStatus is %JobStatus% "
     goto :END
:END
     exit /B %JobStatus%

SYS1CSDFCTGET Command

This command produces a list of the File Control Table (FCT) defined in the CICS System Definitions (CSD) file. The File Control Table (FCT) contains an entry for each file used by the CICS regions. For the Micro Focus environment this information is stored in the DFHDRDAT file. The following shows the content of the SYS1CSDFCTGET.cmd command.

@echo OFF
rem  * *******************************************************************
rem  *            SYS1CSDFCTGET.cmd - a Windows Command File             *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Glance at the CSD Information for FCTs.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 2006
rem  *
rem  * The 1st step will Prepare the environment.
rem  *
rem  * The 2nd step will extract FCT information from DFHDRDAT.
rem  *
rem  * The 3rd step will post FCT information to a CSV File.
rem  *
rem  * *******************************************************************
rem  * Step 1 of 3,  Prepare the environment...
rem  *
     set CmdName=SYS1CSDFCTGET
     call ..\..\Env1BASE %CmdName%
     if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
rem  *
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting CmdName %CmdName%, V08.06.05, User is %USERNAME%"
     call SimoNOTE "StepInfo Delete previously created files"
     set RDTFILE2=%BaseLib1%\DATA\TXT1\SIMOTIME.FCT.RDTFILE2.TXT
     if exist %RDTFILE2% del %RDTFILE2%
rem  *
rem  * *******************************************************************
rem  * Step 2 of 3, Get FCT Information from RDO File...
rem  *
     call SimoNOTE "StepInfo Create Record Sequential files"
     casrdtex /o%RDTFILE2% /gSIMOGRPA /f /e /ip"c:\SimoSam1\DEVL\SYS1\CONFIG"
rem  *
     if exist %RDTFILE2% goto :PostToCSV
     set JobStatus=0020
     goto :EojNok
rem  *
rem  * *******************************************************************
rem  * Step 3 of 3, Post FCT Information to a CSV File...
rem  *
:PostToCSV
     set CSDGETD1=%RDTFILE2%
     set CSDPUTD1=%BaseLib1%\DATA\XLSS\SIMOTIME.FCT.SAMDEVS1.CSV
     call SimoNOTE "DataTAKE is %CSDGETD1%"
     call SimoNOTE "DataMAKE is %CSDPUTD1%"
     run CSDFCTC1
rem  *
rem  * *******************************************************************
rem  *
:EojAok
     call SimoNOTE "Finished JobName %CmdName%, Job Status is %JobStatus% "
     goto :End
:EojNok
     call SimoNOTE "ABENDING JobName %CmdName%, Job Status is %JobStatus% "
:End
     if not "%1" == "nopause" pause

SYS1CSDPCTGET Command

This command produces a list of the Program Control table (PCT) defined in the CICS System Definitions (CSD) file. The Program Control Table (PCT) contains a definition for each transaction and the program that is used by the transaction. For the Micro Focus environment this information is stored in the DFHDRDAT file. The following shows the content of the SYS1CSDFCTGET.cmd command.

@echo OFF
rem  * *******************************************************************
rem  *            SYS1CSDPCTGET.cmd - a Windows Command File             *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Glance at the CSD Information for PCTs.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 2006
rem  *
rem  * The 1st step will Prepare the environment.
rem  *
rem  * The 2nd step will extract PCT information from DFHDRDAT.
rem  *
rem  * The 3rd step will post PCT information to a CSV File.
rem  *
rem  * *******************************************************************
rem  * Step 1 of 3,  Prepare the environment...
rem  *
     set CmdName=CSDPCTGET
     call ..\..\Env1BASE %CmdName%
     set JobStatus=0000
     if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting JobName %CmdName%, User is %USERNAME%"
     call SimoNOTE "Identify JobStep DeleteQSAM"
     set RDTFILE2=%BaseLib1%\DATA\TXT1\SIMOTIME.PCT.RDTFILE2.TXT
     if exist %RDTFILE2% del %RDTFILE2%
rem  *
rem  * *******************************************************************
rem  * Step 2 of 3, Get PCT Information from RDO File...
rem  *
     casrdtex /o%RDTFILE2% /gSIMOGRPA /x /e /ip"c:\SimoSam1\DEVL\SYS1\CONFIG"
rem  *
     if exist %RDTFILE2% goto :PostToCSV
     set JobStatus=0020
     goto :EojNok
rem  *
rem  * *******************************************************************
rem  * Step 3 of 3, Post PCT Information to a CSV File...
rem  *
:PostToCSV
     set CSDGETD1=%RDTFILE2%
     set CSDPUTD1=%BaseLib1%\DATA\XLSS\SIMOTIME.PCT.SAMDEVS1.CSV
     call SimoNOTE "DataTAKE is %CSDGETD1%"
     call SimoNOTE "DataMAKE is %CSDPUTD1%"
     run CSDPCTC1
rem  *
rem  * *******************************************************************
rem  *
:EojAok
     call SimoNOTE "Produced %CSDPUTD1%"
     call SimoNOTE "Finished JobName %CmdName%, Job Status is %JobStatus%"
     goto :End
:EojNok
     call SimoNOTE "ABENDING JobName %CmdName%, Job Status is %JobStatus%"
:End
     call SimoNOTE "Conclude SysLog is %SYSLOG%"
     if not "%1" == "nopause" pause

Data Files Allocated to a CICS Region

When a CICS Region is active the non-relational data files are usually allocated to the region in a non-share mode. If there is a requirement to perform maintenance on a non-relational data file from a batch environment it could be accomplished using one of the following approaches.

SYS1FILEDISABLE Command

The following shows the content of a command (SYS1FILEDISABLE.cmd) that will close/disable a non-relational data file being used by a CICS region.

@echo OFF
rem  * *******************************************************************
rem  *           SYS1FILEDISABLE.cmd - a Windows Command File            *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Disable and Close a File for a CICS Region
rem  *      Parameter one must be the server name
rem  *      Parameter two must be the data file name
rem  *
rem  * Set the common environment variables
     set ezServerName=%1
     call ..\..\Env1BASE
     call SimoNOTE "****************************************SYS1FILEDISABLE"
     call SimoNOTE "Starting CmdName SYS1FILEDISABLE %ezServerName%, File is %2, User is %USERNAME%"
rem  *
     casfile -r%1 -oc -ed -d%2
rem  *
     call SimoNOTE "Complete CmdName SYS1FILEDISABLE %ezServerName%, File is %2, User is %USERNAME%"

SYS1FILEENABLE Command

The following shows the content of a command (SYS1FILEENABLE.cmd) that will open/enable a non-relational data file for use by a CICS region.

@echo OFF
rem  * *******************************************************************
rem  *            SYS1FILEENABLE.cmd - a Windows Command File            *
rem  *         This program is provided by SimoTime Technologies         *
rem  *           (C) Copyright 1987-2019 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * ESA, Enterprise Server Administration
rem  *      Enable and Open a File for a CICS Region
rem  *      Parameter one must be the server name
rem  *      Parameter two must be the data file name
rem  *
rem  * Set the common environment variables
     set ezServerName=%1
     call ..\..\Env1BASE
     call SimoNOTE "****************************************SYS1FILEENABLE"
     call SimoNOTE "Starting CmdName SYS1FILEENABLE %ezServerName%, File is %2, User is %USERNAME%"
rem  *
     casfile -r%1 -ee -oo -d%2
rem  *
     call SimoNOTE "Complete CmdName SYS1FILEENABLE %ezServerName%, File is %2, User is %USERNAME%"

Summary

The purpose of this suite of programs is to provide a model of Windows Command Files that may be used to start a region within Enterprise Server, submit or schedule batch jobs to a region within Enterprise Server or stop a region within Enterprise Server. Also, this document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.

In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.

SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the  Contact or Feedback  section of this document.

Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.

Note: A SimoTime License is required for the items to be made available on a local system or server.

Current Server or Internet Access

The following links may be to the current server or to the Internet.

Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the icon.

    Explore the JCL Connection for more examples of JCL functionality with programming techniques and sample code.

    Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.

    Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.

    Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

    Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.

Internet Access Required

The following links will require an internet connect.

This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.

Glossary of Terms

    Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Contact or Feedback

This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.

We appreciate hearing from you.

Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com