Directory Compare
Identify Directory Content Changes
  Table of Contents  v-24.01.01 - dircom01.htm 
  Introduction
  Primary Jobs
  Create Two Test Directories
  Compare Directory Lists or Content
  Contents of Two (2) Different Directories
  Same Directory Before & After a Job
  Identify New or Missing Member
  Delete Test Directories and Files
  Ancillary Functions
  Callable Script, Compare Directories
  Set the Environment
  Display and Log Messages
  Summary
  Software Agreement and Disclaimer
  Downloads and Links
  Current Server or Internet Access
  Internet Access Required
  Glossary of Terms
  Contact or Feedback
  Company Overview
The SimoTime Home Page 

Table of Contents Previous Section Next Section Introduction

The Directory Compare Utility Programs may be used to compare the contents of two different directories or to compare the contents of the same directory before and after a job has executed.

When changing, migrating and testing applications a utility program to snapshot the contents of a directory before and after a job is executed and then compare and identify the differences is sometimes required. This information could then be used to track changes and quantify disk utilization by individual batch jobs. This capability is quite useful when migrating a batch application from a Mainframe System to a Windows System that will schedule JCL members to run under control of Micro Focus Enterprise Server.

The source code, data sets and documentation are provided in a single zipped file called DIRCOM01.ZIP. This zipped file may be downloaded from the SimoTime Web site.

This example illustrates the following functions.

1 Create two (2) sample directories that are identical in content.
2 List the contents of a directory to and ASCII/Text File.
3 Compare the two (2) directories by listing the contents of each directory to a separate file and comparing the listing files.
4 Modify the content of one of the directories and re-run the comparison.
  Functions provided by the Directory Compare Utility Program

Note: The compare of the two listing files is done by a COBOL program that was generated by SimoTime technology and compiled with Micro Focus technology.

We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.

Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved

Table of Contents Previous Section Next Section Primary Jobs

This suite of sample programs will show how to create two (2) sample directories with three (3) files in each directory. Next, this example describes how to create two ASCII/Text files with each containing a list of members from the specified directories. Sub-directory names can be omitted by using the "/a-d" parameter of the DIR Command. The files could be sorted using the "/on" parameter that is an attribute of the DIR command. However, the "/on" does not provide a directory listing in an ASCII collating sequence. Instead of the upper case letters being sorted before the lower case letters the cases are intertwined. For example, the "/on" arranges the list "A,a,B,b,C,c,D,d, etc..." and the ASCII collating sequence is "A,B,C,D, etc..." followed by "a,b,c,d, etc...". The files will be processed by the Micro Focus SORT program to drop records that have a space in position 1. Also, the final step in this process uses a COBOL program to compare the two listing files and this program depends on the files being in an ASCII collating sequence by name in order to track inserts and deletes. Also, this example describes how to set environment variables and delete any work files created by a previous run of this procedure.

Table of Contents Previous Section Next Section Create Two Test Directories

The following Command Script (DirComPrepare.cmd) will create two (2) sample directories with small sample files as content.

@echo OFF
rem  * ************************************************************************
rem  *              DIRCOMPREPARE.cmd - a Windows Command File                *
rem  *           This program is provided by SimoTime Technologies            *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  *
rem  * Text    - Create two (2) sample directories
rem  * Author  - SimoTime Technologies
rem  * Date    - November 11, 2003
rem  * Version - 06.07.16
rem  *
rem  * ********************************************************************
rem  * Step   1 of 2  Set the global environment variables...
rem  *
     set CmdName=DirComPrepare
     call ..\Env1BASE %CmdName%
     if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
rem  *
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting CmdName %CmdName%.CMD"
rem  *
rem  * Delete previously created directories.
rem  *
     if exist %BaseLib1%\myDirectoryOne rd /S /Q %BaseLib1%\myDirectoryOne
     if exist %BaseLib1%\myDirectoryTwo rd /S /Q %BaseLib1%\myDirectoryTwo
rem  *
rem  ***************************************************************************
rem  * This section will create two directories and place three files in each
rem  * directory. The contents of each directory should be identical.
rem  *
     md %BaseLib1%\myDirectoryOne
     echo Record One>%BaseLib1%\myDirectoryOne\FILE0010.TXT
     echo Record One>%BaseLib1%\myDirectoryOne\FILE0020.TXT
     echo Record Two>>%BaseLib1%\myDirectoryOne\FILE0020.TXT
     echo Record One>%BaseLib1%\myDirectoryOne\FILE0030.TXT
     echo Record Two>>%BaseLib1%\myDirectoryOne\FILE0030.TXT
     echo Record Three>>%BaseLib1%\myDirectoryOne\FILE0030.TXT
     md %BaseLib1%\myDirectoryTwo
     copy %BaseLib1%\myDirectoryOne\*.* %BaseLib1%\myDirectoryTwo\*.*
rem  *
rem  ***************************************************************************
rem  * Validate the files have been created.
     if not exist %BaseLib1%\myDirectoryTwo\FILE0030.TXT set JobStatus=0203
     if not exist %BaseLib1%\myDirectoryTwo\FILE0020.TXT set JobStatus=0202
     if not exist %BaseLib1%\myDirectoryTwo\FILE0010.TXT set JobStatus=0201
     if not exist %BaseLib1%\myDirectoryOne\FILE0030.TXT set JobStatus=0103
     if not exist %BaseLib1%\myDirectoryOne\FILE0020.TXT set JobStatus=0102
     if not exist %BaseLib1%\myDirectoryOne\FILE0010.TXT set JobStatus=0101
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  ***************************************************************************
:EojAOK
     call SimoNOTE "Finished CmdName %CmdName%.CMD, Job Status is %JobStatus%"
     goto :End
:EojNOK
     call SimoNOTE "ABENDING CmdName %CmdName%.CMD, Job Status is %JobStatus%"
     echo %DATE% - %TIME% Starting User ABEND Processing...>>%SYSLOG%
     set >>%SYSLOG%
     echo %DATE% - %TIME% Complete User ABEND Processing...>>%SYSLOG%
     goto :End
:End
     call SimoNOTE "Conclude SysOut is %SYSOUT%"
     call SimoNOTE "Conclude SysLog is %SYSLOG%"
     if not "%1" == "nopause" pause
     exit /B %JobStatus%

Table of Contents Previous Section Next Section Compare Directory Lists or Content

A common approach to validating the content of a Windows Directory (or FOLDER) is to create a listing of the directory content and then compare the listings. The following shows a few examples.

Table of Contents Previous Section Next Section Contents of Two (2) Different Directories

The following Command Script (DirComTest1st.cmd) will compare the contents of two (2) separate directories.

@echo OFF
rem  * ************************************************************************
rem  *              DIRCOMTEST1ST.cmd - a Windows Command File                *
rem  *          This Batch Job is provided by SimoTime Technologies           *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  *
rem  * Create two files that contain a list of members from the specified
rem  * folders.
rem  *
rem  * The files should not contain directory names because of the "/a-d".
rem  *
rem  * The files could be sorted using the "/on" parameter that is an attribute
rem  * of the DIR command. However, the "/on" does not provide a directory
rem  * listing in an ASCII collating sequence.
rem  * Instead of the upper case letters being sorted before the lower case
rem  * letters the cases are intertwined. This is also referred to as a
rem  * case-insensitive sort. For example, the "/on" arranges the
rem  * list "A,a,B,b,C,c,D,d, etc..." and the ASCII collating sequence
rem  * is "A,B,C,D, etc..." followed by "a,b,c,d, etc...".
rem  *
rem  * The files will be processed by the Micro Focus SORT program to drop
rem  * records that have a space in position 1.
rem  * Also, the final step in this process uses a COBOL program to compare the
rem  * two files and this program depends on the files being in an ASCII
rem  * collating sequence by name in order to track inserts and deletes.
rem  *
rem  * ********************************************************************
rem  * Step   1 of 2  Set the global environment variables...
rem  *
     set CmdName=DIRCOMTEST1ST
     call ..\Env1BASE %CmdName%
     if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
rem  *
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting CmdName %CmdName%.CMD"
rem  *
rem  *
rem  ***************************************************************************
rem  * List the contents of the two directories
rem  *
     dir %BaseLib1%\myDirectoryOne\*.* /a-d >%BASECAT%\Wrk1\Work01.TXT
     dir %BaseLib1%\myDirectoryTwo\*.* /a-d >%BASECAT%\Wrk1\Work02.TXT
rem  ***************************************************************************
rem  * Execute the script to sort and compare the two directory listings
     call ezDirListCompare %BASECAT%\Wrk1\Work01.TXT %BASECAT%\Wrk1\Work02.TXT
     if not "%ERRORLEVEL%" == "0" set JobStatus=0010
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  ***************************************************************************
:EojAOK
     call SimoNOTE "Finished CmdName %CmdName%.CMD, Job Status is %JobStatus% "
     goto :End
:EojNOK
     call SimoNOTE "ABENDING CmdName %CmdName%.CMD, Job Status is %JobStatus% "
     goto :End
:End
     call SimoNOTE "Conclude SysOut is %SYSOUT%"
     call SimoNOTE "Conclude SysLog is %SYSLOG%"
     if not "%1" == "nopause" pause
     exit /B %JobStatus%

Table of Contents Previous Section Next Section Same Directory Before & After a Job

The following Command Script (DirComTest2nd.cmd) will make a listing file of a directory before a job is executed. A job will be executed that will change a file in the directory. A second listing of the contents of the directory is created. The before and after listings are compared.

@echo OFF
rem  * ************************************************************************
rem  *              DIRCOMTEST2ND.cmd - a Windows Command File                *
rem  *          This Batch Job is provided by SimoTime Technologies           *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  *
rem  * Set the global environment variables...
rem  *
     set CmdName=DIRCOMTEST2ND
     call ..\Env1BASE %CmdName%
     if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
rem  *
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting CmdName %CmdName%.CMD"
rem  *
rem  ***************************************************************************
rem  * Compare the content of a single directory before and after a job        *
rem  ***************************************************************************
rem  * List the content of the directory before running a job
     dir %BaseLib1%\myDirectoryOne\*.* /a-d >%BASECAT%\Wrk1\Work01.TXT
rem  *
rem  ***************************************************************************
rem  * Run a job to change the content of one of the files in a directory.
     echo Record New>>%BaseLib1%\myDirectoryOne\FILE0020.TXT
rem  *
rem  ***************************************************************************
rem  * List the content of the directory after running a job
     dir %BaseLib1%\myDirectoryOne\*.* /a-d >%BASECAT%\Wrk1\Work02.TXT
rem  *
rem  ***************************************************************************
rem  * Call the program to sort and compare the two directory listings
     call ezDirListCompare %BASECAT%\Wrk1\Work01.TXT %BASECAT%\Wrk1\Work02.TXT
     if not "%ERRORLEVEL%" == "0" set JobStatus=0010
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  ***************************************************************************
:EojAOK
     call SimoNOTE "Finished CmdName %CmdName%.CMD, Job Status is %JobStatus%"
     goto :End
:EojNOK
     call SimoNOTE "ABENDING CmdName %CmdName%.CMD, Job Status is %JobStatus%"
     goto :End
:End
     call SimoNOTE "Conclude SysOut is %SYSOUT%"
     call SimoNOTE "Conclude SysLog is %SYSLOG%"
     if not "%1" == "nopause" pause
     exit /B %JobStatus%

Table of Contents Previous Section Next Section Identify New or Missing Member

The following Command Script (DirComTest3rd.cmd) will make a listing file of a directory before a job is executed. A job will be executed that will add a new file into a directory. A second listing of the contents of the directory is created. The new or deleted member will be identified.

@echo OFF
rem  * ************************************************************************
rem  *              DIRCOMTEST3RD.cmd - a Windows Command File                *
rem  *          This Batch Job is provided by SimoTime Technologies           *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  *
rem  * Set the global environment variables...
rem  *
     set CmdName=DIRCOMTEST3RD
     call ..\Env1BASE %CmdName%
     if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
rem  *
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting CmdName %CmdName%.CMD"
rem  *
rem  ***************************************************************************
rem  * Run a job to create a new file in a directory.
     echo Record New>>%BaseLib1%\myDirectoryOne\FILE0025.TXT
rem  *
rem  ***************************************************************************
rem  * List the content of the directory after running a job
     dir %BaseLib1%\myDirectoryOne\*.* /a-d >%BASECAT%\Wrk1\Work01.TXT
     dir %BaseLib1%\myDirectoryTwo\*.* /a-d >%BASECAT%\Wrk1\Work02.TXT
rem  *
rem  ***************************************************************************
rem  * Call the program to sort and compare the two directory listings
     call ezDirListCompare %BASECAT%\Wrk1\Work01.TXT %BASECAT%\Wrk1\Work02.TXT
     if not "%ERRORLEVEL%" == "0" set JobStatus=0010
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
rem  ***************************************************************************
:EojAOK
     call SimoNOTE "Finished CmdName %CmdName%.CMD, Job Status is %JobStatus% "
     goto :End
:EojNOK
     call SimoNOTE "ABENDING CmdName %CmdName%.CMD, Job Status is %JobStatus% "
     goto :End
:End
     call SimoNOTE "Conclude SysOut is %SYSOUT%"
     call SimoNOTE "Conclude SysLog is %SYSLOG%"
     start Notepad %SYSOUT%
     if not "%1" == "nopause" pause
     exit /B %JobStatus%

Table of Contents Previous Section Next Section Delete Test Directories and Files

The following Command Script (DirComCleanUp.cmd) will simply delete the sample directories and sample files created within this example.

@echo OFF
rem  * ************************************************************************
rem  *              DIRCOMCLEANUP.cmd - a Windows Command File                *
rem  *           This program is provided by SimoTime Technologies            *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  *
rem  * Text    - Create two (2) sample directories
rem  * Author  - SimoTime Technologies
rem  * Date    - November 11, 2003
rem  * Version - 06.07.16
rem  *
rem  * ********************************************************************
rem  * Step   1 of 2  Set the global environment variables...
rem  *
     set CmdName=DIRCOMCLEANUP
     call ..\Env1BASE %CmdName%
     if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
rem  *
     call SimoNOTE "*******************************************************%CmdName%"
     call SimoNOTE "Starting CmdName %CmdName%.CMD"
rem  *
rem  * Delete previously created directories.
rem  *
     if exist %BaseLib1%\myDirectoryOne rd /S /Q %BaseLib1%\myDirectoryOne
     if exist %BaseLib1%\myDirectoryTwo rd /S /Q %BaseLib1%\myDirectoryTwo
rem  *
rem  ***************************************************************************
:EojAOK
     call SimoNOTE "Finished CmdName %CmdName%.CMD, Job Status is %JobStatus%"
     goto :End
:EojNOK
     call SimoNOTE "ABENDING CmdName %CmdName%.CMD, Job Status is %JobStatus%"
     echo %DATE% - %TIME% Starting User ABEND Processing...>>%SYSLOG%
     set >>%SYSLOG%
     echo %DATE% - %TIME% Complete User ABEND Processing...>>%SYSLOG%
     goto :End
:End
     call SimoNOTE "Conclude SysOut is %SYSOUT%"
     call SimoNOTE "Conclude SysLog is %SYSLOG%"
     if not "%1" == "nopause" pause
     exit /B %JobStatus%

Table of Contents Previous Section Next Section Ancillary Functions

This section provides technical detail about the supporting scripts and programs used or called by the primary jobs.

Table of Contents Previous Section Next Section Callable Script, Compare Directories

The following command file (ezDirListCompare.cmd) is called from other command files to sort and compare the contents of two ASCII/Text files. The ASCII/Text files should contain a list of directory contents.

@echo OFF
rem  * ************************************************************************
rem  *             ezDirListCompare.CMD - a Windows Command File              *
rem  *           This program is provided by SimoTime Technologies            *
rem  *              (C) Copyright 1987-2019 All Rights Reserved               *
rem  *                Web Site URL:   http://www.simotime.com                 *
rem  *                      e-mail:   helpdesk@simotime.com                   *
rem  * ************************************************************************
rem  * Create two files that contains a list of members from the specified
rem  * folders.
rem  *
rem  * The files should not contain directory names because of the "/a-d".
rem  *
rem  * The files could be sorted using the "/on" parameter and attribute of
rem  * the DIR command. However, the "/on" does not provide a directory listing
rem  * in an ASCII collating sequence.
rem  * Instead of the upper case letters being sorted before the lower case
rem  * letters the cases are intertwined. For example, the "/on" arranges the
rem  * list "A,a,B,b,C,c,D,d, etc..." and the ASCII collating sequence
rem  * is "A,B,C,D, etc..." followed by "a,b,c,d, etc...".
rem  *
rem  * The files will be processed by the Micro Focus SORT program to drop
rem  * records that have a space in position 1.
rem  * Also, the final step in this process uses a COBOL program to compare the
rem  * two files and this program depends on the files being in an ASCII
rem  * collating sequence by name in order to track inserts and deletes.
rem  *
rem  * Set environment variables and delete any work files created by a
rem  * previous run of this procedure.
rem  *
     set UtlName=ezDirListCompare
     call ..\Env1BASE %UtlName%
     call SimoNOTE "Starting UtlName %UtlName%.CMD"
     set SIMSRTS1=%BaseCAT%\Wrk1\SIMSRTS1.TXT
     set SIMSRTS2=%BaseCAT%\Wrk1\SIMSRTS2.TXT
rem  *
     call SimoNOTE "Step 010 Delete previously created work files"
     if exist %SIMSRTS1% erase %SIMSRTS1%
     if exist %SIMSRTS2% erase %SIMSRTS2%
rem  *
     call SimoNOTE "Step 020 Sort the Directory Listings"
     call SimoNOTE "DataTake SimDir01=%1"
     call SimoNOTE "DataTake SimDir02=%2"
rem  *
     call SimoNOTE "Step 021 Sort Listing 01 File"
     set SYSOUT_SAVE=%SYSOUT%
     set SYSOUT=%BaseLib1%\LOGS\SYSOUT_ezDirCompareSort01.TXT
     mfsort sort fields=(40,48,ch,a) use %1 org ls record (f 256) give %SIMSRTS1% include cond=(1,1,ss,ne,c' ')
     call SimoNOTE "Step 022 Sort Listing 02 File"
     set SYSOUT=%BaseLib1%\LOGS\SYSOUT_ezDirCompareSort02.TXT
     mfsort sort fields=(40,48,ch,a) use %2 org ls record (f 256) give %SIMSRTS2% include cond=(1,1,ss,ne,c' ')
     set SYSOUT=%SYSOUT_SAVE%
rem  *
rem  * The two sorted files will be compared, any mismatches will be
rem  * written to the SYSLOG file. A Micro Focus COBOL program (DIRCOMC1)
rem  * is used for this process. The source code for the compare program
rem  * was generated by a SimoTime Utility program. Since the two files
rem  * being compared are in sequence by the name field it will be possible
rem  * to track record inserts and deletes.
rem  *
     call SimoNOTE "Step 030 Compare the sorted list"
     set SIMDIR01=%SIMSRTS1%
     set SIMDIR02=%SIMSRTS2%
     run DIRCOMC1
     if not "%ERRORLEVEL%" == "0" set JobStatus=0010
     if not "%JobStatus%" == "0000" goto :EojNOK
rem  *
:EojAok
     call SimoNOTE "Finished UtlName %UtlName%.CMD, Files are equal"
     goto :End
:EojNok
     call SimoNOTE "ABENDING UtlName %UtlName%.CMD, Files are not equal"
:End
     exit /B %JobStatus%

Table of Contents Previous Section Next Section Set the Environment

A command file (ENV1BASE.cmd) located in the sub-directory named ProdLibA) is called from other command files to set commonly used environment variables. This provides a single point of definition. The following is a listing of the contents of the command file.

@echo OFF
rem  * *******************************************************************
rem  *               ENV1BASE.cmd - a Windows Command File               *
rem  *        This program is provided by SimoTime Technologies          *
rem  *           (C) Copyright 1987-2021 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Provide a single point to set common environment variables.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 1996
rem  *
rem  * Set the commonly used environment variables. This is used to provide
rem  * a single point for managing the commonly used environment variables.
rem  *
     set SimoLIBR=c:\SimoLIBR
     set BASELIB1=c:\SIMOSAM1\DEVL
     set BASELIB8=c:\SimoSAM8
     set BaseWIP1=c:\SimoSAM1\WIP1
     set DATAZERO=c:\SIMODATA\DEVL\DATA\ZERO
     set BASEAPP=%BaseLib1%
     set BASESYS=%BaseLib1%\SYS1
     set BASECAT=%BaseLib1%\DATA
     set UMAPALIB=%BASECAT%\ASC1
     set UMAPELIB=%BASECAT%\EBC1
     set SYSLOG=%BASESYS%\LOGS\SYSLOG_USER.DAT
     set SYSOUT=%BASEAPP%\LOGS\SYSOUT_SIMSAM01.txt
     set SLZMSG=%BASEAPP%\LOGS\SLZMSG_USER.TXT
     set PostNOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.TXT
     set SIMONOTE=%BASEAPP%\LOGS\JOBLOG_SIMONOTE.txt
     set USERPOST=%BASEAPP%\LOGS\ASSIGNED_USER_POST_FILE.txt
     if [%1]==[] goto NO_POST
     set SYSOUT=%BaseLib1%\LOGS\SYSOUT_%1.txt
     call SIMONOTE "+ ENV1BASE *"
     call SIMONOTE "+ ENV1BASE ********************************************************************%1"
     call SIMONOTE "+ ENV1BASE is preparing the System Environment..."
     call SIMONOTE "+ SIMOLIBR is %SIMOLIBR%"
     call SIMONOTE "+ MIFOSYS1 is %MIFOSYS1%"
     call SIMONOTE "+ BASELIB1 is %BASELIB1%"
:NO_POST
     call SIMONOTE "+ SIMONOTE Job Log File is %SIMONOTE% "
rem  *
     set MQBASE=C:\Program Files\IBM\WebSphere MQ
rem  *
rem  * Set the location for the Apache-Tomcat Server...
     set CATALINA_HOME=C:\APACHETC\apache-tomcat-7.0.52
rem     set CATALINA_HOME=C:\Program Files (x86)\Java\jdk1.8.0_112
rem  *
rem  * Set the Environment for the Java Environment...
rem     set JAVABASE=C:\APACHETC\apache-tomcat-7.0.52
     set JAVABASE=C:\Program Files (x86)\Java\jdk1.8.0_112
     set JAVASDK="%JAVABASE%\bin"
     set JAVA_HOME=%JAVABASE%
     set JRE_HOME=%JAVABASE%
     set SIMOTCAT=%CATALINA_HOME%\webapps\simotcat
     set SIMPACKS=%CATALINA_HOME%\webapps\simotcat\WEB-INF\classes\simpacks
rem  *
rem  * Set the environment for the Micro Focus technology...
     set MIFOEDEV=C:\Program Files (x86)\Micro Focus\Enterprise Developer
     set MIFOVCBL=C:\Program Files (x86)\Micro Focus\Visual COBOL Build Tools
     set MIFOESTU=C:\Program Files (x86)\Micro Focus\Studio Enterprise Edition 6.0
     set MIFOEMFE="C:\Program Files (x86)\Micro Focus\Mainframe Express"
rem  *
rem  * Large file support, performance tuning and record locking of the File Handler
     set EXTFH=%BASESYS%\CONFIG\EXTFHBIG.CFG
rem  *
rem  * For IMS Support
     set ES_IMSLIB=%BASEAPP%\IMSLIB
     set ES_ACBLIB=%BASEAPP%\IMSLIB
rem  *
rem  * EZASOKETS Check EZASOKETS Enabled box or set ES_EZASOKET_SUPPORT=YES
     set EZACONFG=BASESYS1\CONFIG\EZACONFG.dat
rem  *
rem  * Resource Allocation and Performance for SORT and non-Relational Data
rem  set MFJSENGINE=SYNCSORT
     set SORTSCHEME=1
     set SORTSPACE=750000000
     set TMP=C:\SORTWORK
rem  *
     set ES_ALLOC_OVERRIDE=%BASESYS%\CONFIG\CATMAPA1.cfg
rem  * For CORE_ON_ERROR function, ABEND Dump
rem  *     set COBCONFIG_=%BASESYS%\CONFIG\diagnose.cfg
rem  *
rem  * Consolidated Trace Facility (CTF)
rem  *     set MFTRACE_CONFIG=%BASESYS%\CONFIG\ctf.cfg
rem  *     set MFTRACE_LOGS=c:\ctflogs
rem  *
rem  * For Job Restart, ABEND Recovery
     set MF_UCC11=Y
     set ES_JES_RESTART=Y
rem  *
rem  * Set environment for MFBSI (Micro Focus Batch Scheduling Interface)
     set ES_EMP_EXIT_1=mfbsiemx
     set MFBSI_DIR=%BASESYS%\LOGS\%JESSERVERNAME%
     set MFBSIEOP_CMD=ENABLE
     set MFBSIEOP_CSV=ENABLE
     set MFBSIEOP_HTM=ENABLE
     set MFBSIEOP_XML=ENABLE
rem  *
rem  * Set Behavior and Trace Flags for GETJOBDD
rem  *   Position=12345678/12345678
     set JDDFLAGS=nnnWnnnn/YYnnnnnn
rem  *
rem  * If not already set then set the PATH for Micro Focus Directories
     if "%SIMOPATH%" == "Y" goto JUMPPATH
     if "%MIFOSYS1%" == "EDEV" goto JUMPEDEV
     if "%MIFOSYS1%" == "VCBL" goto JUMPVCBL
     if "%MIFOSYS1%" == "ESTU" goto JUMPESTU
     if "%MIFOSYS1%" == "EMFE" goto JUMPEMFE
:JUMPEDEV
     set path=%BASESYS%\LOADLIB;%MIFOEDEV%\bin;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOEDEV%\CPYLIB
     set MIFOBASE=%MIFOEDEV%
     goto JUMPPATH
:JUMPVCBL
     set path=%MIFOVCBL%\bin;%MIFOVCBL%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set MIFOBASE=%MIFOVCBL%
     goto JUMPPATH
:JUMPESTU
     set MIFOBASE=%MIFOESTU%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
:JUMPEMFE
     set MIFOBASE=%MIFOEMFE%\Base
     set MIFOBIN=%MIFOBASE%\bin
     set path=%BASESYS%\LOADLIB;%MIFOBASE%;%MIFOBIN%;%JAVASDK%;%BASEAPP%\JAVA;%PATH%;
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%;%MIFOBASE%\SOURCE
     goto JUMPPATH
rem  *
:JUMPPATH
     set SIMOPATH=Y
rem  *
     set MAINFRAME_FLOATING_POINT=true
     set COBIDY=%BASEAPP%\COBIDY
     set COBPATH=.;%BASEAPP%\LOADLIB;%BASEAPP%\LOADLIB\GNTS;%BASESYS%\LOADLIB;%SimoLIBR%
     set LIBPATH=.;%BASEAPP%\LOADLIB;%BASEAPP%\LOADLIB\GNTS;%BASESYS%\LOADLIB;%SimoLIBR%
     set TXDIR=%BASESYS%\LOADLIB;%MIFOBASE%
     set CobCpy=%BASEAPP%\CobCpy1;%BASEAPP%\CobCpy2;%BASEAPP%\CobCpy6;%SimoLIBR%
rem  *
     set USERCLASS=%BASELIB1%\LOADLIB
     set CLASSPATH=.
     set CLASSPATH=%CLASSPATH%;%JAVABASE%
     set CLASSPATH=%CLASSPATH%;%JAVABASE%\lib
     set CLASSPATH=%CLASSPATH%;\%USERCLASS%\simpacks
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes
     set CLASSPATH=%CLASSPATH%;C:\APACHETC\apache-tomcat-7.0.52\webapps\simotcat\WEB-INF\classes\simpacks
rem  *
     if "%MIFOSYS1%" == "ESTU" set CLASSPATH=%CLASSPATH%;%MIFOBIN%
     if "%MIFOSYS1%" == "EDEV" set CLASSPATH=%CLASSPATH%;%MIFOEDEV%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%
     if "%MIFOSYS1%" == "VCBL" set CLASSPATH=%CLASSPATH%;%MIFOVCBL%\bin\mfcobol.jar
rem  *
     set JobStatus=0000
     call SIMONOTE "+ ENV1BASE is returning to caller"

Table of Contents Previous Section Next Section Display and Log Messages

The following (SIMONOTE.cmd) is a listing of the contents of the SimoNOTE.CMD command file.

@echo OFF
rem  * *******************************************************************
rem  *               SIMONOTE.cmd - a Windows Command File               *
rem  *         This program is provided by SimoTime Technologies         *
rem  *            (C) Copyright 1987-2019 All Rights Reserved            *
rem  *              Web Site URL:   http://www.simotime.com              *
rem  *                    e-mail:   helpdesk@simotime.com                *
rem  * *******************************************************************
rem  *
rem  * Text    - Display message on screen and write to a log file.
rem  * Author  - SimoTime Technologies
rem  *
rem  * This script may be called from other scripts and expects a single
rem  * parameter enclosed in double quotes. The double quotes will be
rem  * removed. Before writing to the log file a date and time stamp
rem  * will be inserted in front of the message text.
rem  *
rem  * Note: The tilde (~) removes leading/trailing double-quotes.
rem  *
if "%SimoNOTE%" == "" set SimoNOTE=c:\SimoLIBR\LOGS\SimoTime.LOG
echo %date% %time% %~1>> %SimoNOTE%
echo %~1

Table of Contents Previous Section Next Section Summary

The purpose of this suite of programs is to provide an example of how to compare directory contents of two separate directories or the directory contents of a single directory before and after a job is executed. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers.

In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.

SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the  Contact or Feedback  section of this document.

Table of Contents Previous Section Next Section Software Agreement and Disclaimer

Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.

SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.

Table of Contents Previous Section Next Section Downloads and Links

This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an Internet connection, the second group of documents will require an Internet connection.

Note: A SIMOTIME License is required for the items to be made available on a local system or server.

Table of Contents Previous Section Next Section Current Server or Internet Access

The following links may be to the current server or to the Internet.

Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the Link to Internet icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the Link to Server icon.

Link to Internet   Link to Server   Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.

Link to Internet   Link to Server   Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.

Link to Internet   Link to Server   Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.

Table of Contents Previous Section Next Section Internet Access Required

The following links will require an internet connect.

This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SIMOTIME Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.

A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection

Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.

Table of Contents Previous Section Next Section Glossary of Terms

Link to Internet   Link to Server   Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.

Table of Contents Previous Section Next Section Contact or Feedback

This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.

1. Send an e-mail to our helpdesk.
1.1. helpdesk@simotime.com.
2. Our telephone numbers are as follows.
2.1. 1 415 763-9430 office-helpdesk
2.2. 1 415 827-7045 mobile

 

We appreciate hearing from you.

Table of Contents Previous Section Next Section Company Overview

SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.

Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.

Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.

Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com

Return-to-Top
Directory Compare, Identify Directory Content Changes
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved
When technology complements business
http://www.simotime.com