CICS, Access a VSAM Data Set
|
Customer Update CICS, Access a VSAM Data Set |
|
| The SimoTime Home Page |
Introduction
The transaction identifier (or Tran ID) for this menu option is "CUU1" and the program is "CU2UPD". This program will prompt a user for the customer number. Once a customer number is entered the program accesses the Customer Master File (CUSTMAST) and displays the customer information at the 3270 Terminal. A user may update the record or continue to enter customer numbers or exit the program. If a customer record is not found a message is displayed.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved
Update the Customer File
After selecting the menu option or starting the transaction "CUU1" the following screen should be displayed. The cursor should be position at the first character for the "New Customer #" field. When entering a customer number it is not necessary to type the leading zeroes. For example, customer number "000000000019" only requires "19 " followed by one space character (the program will remove any characters after the initial space character and right-adjust the field with leading zero-fill). Press the "Enter" key to retrieve and display the customer information. The following screen shows the results after pressing the "Enter" key.
CU2UPD1 Data Files and VSAM Data Sets 2009/08/03
STOA Customer Update Option 14:32:51:92
New Customer #: 000000001900
Customer #: 000000001900
Last Name: Smith
First: Sammy Middle:
Addr-1: 1919 Carnoustie Drive
Addr-2:
City: Novato
State/Province: CA Postal Code: 94919
*--------------------------Telephone Numbers--------------------------*
Home Work Cell
Last Activity Date: Time: Token:
PF3=Menu F9=Updt F12=Esc |
Once the information has been retrieved the customer information may be changed and Program Function Key (F9) may be used to update the customer master file. If another customer needs to be viewed and updated simply position the cursor to the first position of the "New Customer #" field and enter a new customer number.
Note: PF3 will end this transaction and display the sub-Menu for "Data Files and VSAM Data Sets". PF12 will end this session and return to the CICS prompt screen.
Technical Details
This section provides additional detail about the COBOL Programs, BMS Screens and Data Structures.
Customer File, Access & Structure
The following describes the source members used to access the Customer Master File or define its record structure.
COBOL Program, Customer File Update
The following (CU2UPD.cbl) is the COBOL source code for the "Inquiry" Program that accesses the Customer Master File and displays record information to a 3270 device.
IDENTIFICATION DIVISION.
PROGRAM-ID. CU2UPD.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
* MAINTENANCE
* -----------
* 1989/02/27 Simmons, Created program.
* 1997/03/17 Simmons, Updated for SYSID.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
*****************************************************************
DATA DIVISION.
WORKING-STORAGE SECTION.
01 VERSION-NUMBER pic X(9) value 'V01.00.00'.
01 PF-ROW-23.
05 filler pic X(3) value SPACES.
05 PF-ROW-23-04 pic X(8) value SPACES.
05 PF-ROW-23-12 pic X(8) value SPACES.
05 PF-ROW-23-20 pic X(8) value 'F3=Menu '.
05 PF-ROW-23-28 pic X(8) value SPACES.
05 PF-ROW-23-36 pic X(8) value SPACES.
05 PF-ROW-23-44 pic X(8) value SPACES.
05 PF-ROW-23-52 pic X(8) value SPACES.
05 PF-ROW-23-60 pic X(8) value SPACES.
05 PF-ROW-23-68 pic X(8) value 'F12=Esc '.
05 filler pic X(3) value SPACES.
01 EOJ-MESSAGE pic X(50)
value ' - Enter Tran ID . . . completed CU2UPD'.
01 RECORD-LENGTH-512 pic S9(4) comp value 512.
01 DATA-RESP-CODE pic 9(08) comp.
01 XCTL-RESP-CODE pic 9(08) comp.
01 NUMBER-WORK-16 pic 9(16) value 0.
01 X-EIB-MESSAGE.
05 filler pic X(8) value 'EIBRESP='.
05 X-EIB-RESP pic 9(10) value 0.
05 filler pic X(11) value ', EIBRESP2='.
05 X-EIB-RESP2 pic 9(10) value 0.
05 filler pic X value SPACE.
05 X-EIB-USER-MSG pic X(38) value SPACES.
01 CUSTOMER-READ-KEY pic X(12).
01 MSG-LINE-1 pic X(78) value LOW-VALUES.
01 MSG-LINE-2 pic X(78) value LOW-VALUES.
01 SYS-ID pic X(4).
01 WORK-DATE.
05 WORK-DATE-CC pic X(02).
05 WORK-DATE-YY pic 9(02).
05 WORK-DATE-MM pic X(02).
05 WORK-DATE-DD pic 9(02).
01 WORK-TIME.
05 WORK-TIME-HH pic X(02).
05 WORK-TIME-NN pic X(02).
05 WORK-TIME-SS pic X(02).
05 WORK-TIME-TT pic X(02).
01 Z-WORK-12 pic X(12) value SPACES.
01 IX-12 pic 9(3) value 0.
01 PROGRAM-NAME pic x(8) value SPACES.
01 WS-RESPONSE pic S9(8) comp.
01 WS-REASON-CODE pic S9(8) comp.
01 LOCAL-TRAN-ID pic X(4) value 'CUU1'.
01 PROGRAM-FLAGS.
05 P-FLAG-ANIM pic X value 'N'.
05 P-FLAG-JOURNAL pic X value 'Y'.
01 WORK-ITEMS.
05 WS-ESD128-RIDFLD PIC S9(8) COMP VALUE +0.
05 WS-ESD01K-RIDFLD PIC S9(8) COMP VALUE +0.
05 WS-ESD350-RIDFLD PIC S9(8) COMP VALUE +0.
01 ESD128-RECORD.
05 ESD128-DATA pic X(128) value SPACES.
01 ESD128-FILE pic X(8) value 'ESDSC128'.
01 ESD01K-RECORD.
05 ESD01K-DATA pic X(128) value SPACES.
01 ESD01K-FILE pic X(8) value 'ESDSC01K'.
01 ESD350-RECORD.
05 ESD350-DATA pic X(350) value SPACES.
01 ESD350-FILE pic X(8) value 'ESDSC350'.
COPY CU2UPD1.
COPY DFHBMSCA.
COPY DFHAID.
* COPY DFHEIBLK.
COPY CUSTCB01.
*****************************************************************
LINKAGE SECTION.
01 DFHCOMMAREA.
03 LS-CUSTNO pic X(12).
03 filler pic X(4096).
*****************************************************************
PROCEDURE DIVISION.
* if P-FLAG-ANIM = 'Y'
* CALL 'CBL_DEBUGBREAK'
* end-if.
perform CLEAR-MESSAGES
EXEC CICS HANDLE CONDITION
ERROR (GENERAL-ERROR-ROUTINE)
MAPFAIL (MAP-FAIL-ROUTINE)
NOTFND (GENERAL-ERROR-ROUTINE)
END-EXEC.
evaluate TRUE
when EIBCALEN = ZERO
perform SCREEN-IO-SEND-UPDATE
* when EIBAID = DFHPF1
* call 'CBPIPEC1'
* move 'Help Info should be displayed in browser'
* to MSG-LINE-1
* perform RECOVERY-ROUTINE
when EIBAID = DFHPF3
perform END-OF-PROGRAM-03
when EIBAID = DFHPF9
perform UPDATE-CUSTOMER-INFORMATION
when EIBAID = DFHPF12
perform END-OF-PROGRAM-12
when EIBAID = DFHENTER
perform GET-CUSTOMER-INFORMATION
when other
move 'Type a new request and press the ENTER key'
to MSG-LINE-1
perform RECOVERY-ROUTINE
end-evaluate.
* Should never get to here...
perform END-OF-PROGRAM-12.
*****************************************************************
BUILD-HEADER-INFO.
EXEC CICS ASSIGN
SYSID(SYS-ID)
END-EXEC.
move 'CU2UPD1 ' to SYSPAGEO
move SYS-ID to SYS-IDO.
perform Z-GET-DATE-AND-TIME.
exit.
*****************************************************************
CUSTMAST-READ.
move LS-CUSTNO to CUSTOMER-READ-KEY.
EXEC CICS READ
DATASET ('CUSTMAST')
INTO (CUST-RECORD)
LENGTH (RECORD-LENGTH-512)
RIDFLD (CUSTOMER-READ-KEY)
KEYLENGTH (12)
RESP (DATA-RESP-CODE)
END-EXEC.
exit.
*****************************************************************
CUSTMAST-READ-UPDATE.
EXEC CICS READ
DATASET ('CUSTMAST')
INTO (CUST-RECORD)
LENGTH (RECORD-LENGTH-512)
RIDFLD (CUSTOMER-READ-KEY)
KEYLENGTH (12)
UPDATE
RESP (DATA-RESP-CODE)
END-EXEC.
exit.
*****************************************************************
CUSTMAST-REWRITE.
EXEC CICS REWRITE
DATASET ('CUSTMAST')
FROM (CUST-RECORD)
LENGTH (RECORD-LENGTH-512)
RESP (DATA-RESP-CODE)
END-EXEC.
exit.
*****************************************************************
CUSTMAST-WRITE.
EXEC CICS WRITE
DATASET ('CUSTMAST')
FROM (CUST-RECORD)
LENGTH (RECORD-LENGTH-512)
RIDFLD (CUSTOMER-READ-KEY)
RESP (DATA-RESP-CODE)
END-EXEC.
exit.
*****************************************************************
CLEAR-MESSAGES.
move SPACES to MSG-LINE-1
move SPACES to MSG-LINE-2
move SPACES to SYSMSG1O
move SPACES to SYSMSG2O
exit.
*****************************************************************
DATA-FILE-TO-SCREEN.
move CUST-NUMBER to REQNUMBO
move CUST-NUMBER to CUNUMBO
move CUST-LAST-NAME to CULNAMEO
move CUST-FIRST-NAME to CUFNAMEO
move CUST-MID-NAME to CUMNAMEO
move CUST-ADDRESS-1 to CUADR1O
move CUST-ADDRESS-2 to CUADR2O
move CUST-CITY to CUCITYO
move CUST-STATE to CUSTATEO
move CUST-POSTAL-CODE to CUZIPO
move CUST-PHONE-HOME to CUPHONHO
move CUST-PHONE-WORK to CUPHONWO
move CUST-PHONE-CELL to CUPHONCO
move CUST-LADATE to CULDATEO
move CUST-LATIME to CULTIMEO
if CUST-TOKEN is NUMERIC
move CUST-TOKEN to CUTOKENO
else
move CUST-TOKEN to CUTOKENO
exit.
*****************************************************************
DATA-INITIALIZE-SCREEN-RECORD.
move SPACES to REQNUMBO
CUNUMBO
CULNAMEO
CUFNAMEO
CUMNAMEO
CUADR1O
CUADR2O
CUCITYO
CUSTATEO
CUZIPO
CUPHONHO
CUPHONWO
CUPHONCO
CULDATEO
CULTIMEO
CUTOKENO
SYSMSG1O
SYSMSG2O
exit.
*****************************************************************
DATA-SCREEN-TO-FILE.
* move REQNUMBI to CUST-NUMBER
move CUNUMBI to CUST-NUMBER
move CULNAMEI to CUST-LAST-NAME
move CUFNAMEI to CUST-FIRST-NAME
move CUMNAMEI to CUST-MID-NAME
move CUADR1I to CUST-ADDRESS-1
move CUADR2I to CUST-ADDRESS-2
move CUCITYI to CUST-CITY
move CUSTATEI to CUST-STATE
move CUZIPI to CUST-POSTAL-CODE
move CUPHONHI to CUST-PHONE-HOME
move CUPHONWI to CUST-PHONE-WORK
move CUPHONCI to CUST-PHONE-CELL
move CULDATEI to CUST-LADATE
move CULTIMEI to CUST-LATIME
move CUTOKENI to CUST-TOKEN
exit.
*****************************************************************
END-OF-PROGRAM-03.
move 'MN1FMS ' to PROGRAM-NAME
perform TRANSFER-CONTROL
* Should never get to here...
exit.
*****************************************************************
END-OF-PROGRAM-12.
EXEC CICS SEND
FROM (EOJ-MESSAGE)
LENGTH (50)
ERASE
END-EXEC
EXEC CICS SEND
CONTROL FREEKB
END-EXEC
EXEC CICS RETURN
END-EXEC
exit.
*****************************************************************
GENERAL-ERROR-ROUTINE.
move ' General Error'
to X-EIB-USER-MSG
add EIBRESP to ZERO giving X-EIB-RESP
add EIBRESP2 to ZERO giving X-EIB-RESP2
move X-EIB-MESSAGE to MSG-LINE-2.
perform RECOVERY-ROUTINE
* Should never get to here...
exit.
*****************************************************************
GET-CUSTOMER-INFORMATION.
perform SCREEN-IO-GET-DATA-FOR-INQUIRY
perform CUSTMAST-READ
if DATA-RESP-CODE = ZEROS
move 'F9=Updt ' to PF-ROW-23-44
perform DATA-FILE-TO-SCREEN
else
perform DATA-INITIALIZE-SCREEN-RECORD
perform Z-GET-DATE-AND-TIME
move WORK-DATE to CUST-LADATE
move WORK-TIME to CUST-LATIME
move 999 to CUST-TOKEN
move LS-CUSTNO to REQNUMBO
move LS-CUSTNO to CUNUMBO
move CUST-LADATE to CULDATEO
move CUST-LATIME to CULTIMEO
move CUST-TOKEN to CUTOKENO
move 'F9=Add ' to PF-ROW-23-44
move LS-CUSTNO to MSG-LINE-1
* move '* Customer number not found,please try again... '
move '* Record not found, try again or Add New Record '
to MSG-LINE-1(14:48)
perform POST-MSG-2-EIBRESP
perform RECOVERY-ROUTINE
end-if.
perform SCREEN-IO-SEND-UPDATE
* Should never get to here...
exit.
*****************************************************************
MAP-FAIL-ROUTINE.
move ' Map Failure'
to X-EIB-USER-MSG
add EIBRESP to ZERO giving X-EIB-RESP
add EIBRESP2 to ZERO giving X-EIB-RESP2
move X-EIB-MESSAGE to MSG-LINE-2.
perform RECOVERY-ROUTINE
* Should never get to here...
exit.
*****************************************************************
POST-MSG-2-EIBRESP.
if X-EIB-USER-MSG = SPACES
move ' EIB Response'
to X-EIB-USER-MSG
end-if
add EIBRESP to ZERO giving X-EIB-RESP
add EIBRESP2 to ZERO giving X-EIB-RESP2
move X-EIB-MESSAGE to MSG-LINE-2.
exit.
*****************************************************************
RECOVERY-ROUTINE.
move MSG-LINE-1 to SYSMSG1O.
move MSG-LINE-2 to SYSMSG2O.
move -1 to REQNUMBL
perform SCREEN-IO-SEND-UPDATE
* Should never get to here...
exit.
*****************************************************************
SCREEN-IO-GET-DATA-FOR-INQUIRY.
EXEC CICS RECEIVE
MAP ('CU2UPD1')
MAPSET ('CU2UPD1')
RESP(WS-RESPONSE)
RESP2(WS-REASON-CODE)
END-EXEC.
* Field Length > zero...
if REQNUMBL > ZERO
move REQNUMBI to Z-WORK-12
perform Z-RIGHT-ADJUST-Z-WORK-12
move Z-WORK-12 to REQNUMBI
move REQNUMBI to LS-CUSTNO
else
move 'Please enter a 12 digit customer number...'
to MSG-LINE-1
perform RECOVERY-ROUTINE
end-if.
exit.
*****************************************************************
SCREEN-IO-GET-DATA-FOR-UPDATE.
EXEC CICS RECEIVE
MAP ('CU2UPD1')
MAPSET ('CU2UPD1')
END-EXEC.
if REQNUMBL > ZERO
move REQNUMBI to Z-WORK-12
perform Z-RIGHT-ADJUST-Z-WORK-12
move Z-WORK-12 to REQNUMBI
move REQNUMBI to LS-CUSTNO
end-if.
exit.
*****************************************************************
SCREEN-IO-SEND-UPDATE.
perform BUILD-HEADER-INFO
move PF-ROW-23 to PFROW23O
EXEC CICS SEND
MAP ('CU2UPD1')
MAPSET ('CU2UPD1')
ERASE
END-EXEC
move LOW-VALUES to CU2UPD1O
EXEC CICS RETURN
TRANSID (LOCAL-TRAN-ID)
COMMAREA (CU2UPD1O)
LENGTH (4096)
END-EXEC
* Should never get to here...
exit.
*****************************************************************
TRANSFER-CONTROL.
EXEC CICS XCTL
PROGRAM(PROGRAM-NAME)
RESP(XCTL-RESP-CODE)
END-EXEC
* Should never get to here...
move 'Program not found, &&&&&&&&' to MSG-LINE-1.
inspect MSG-LINE-1 replacing first '&&&&&&&&'
by PROGRAM-NAME
move -1 to REQNUMBL.
perform RECOVERY-ROUTINE.
* exit.
*****************************************************************
UPDATE-CUSTOMER-INFORMATION.
perform SCREEN-IO-GET-DATA-FOR-UPDATE
if CUTOKENI = 999
perform UPDATE-CUSTOMER-INFORMATION-02
else
perform UPDATE-CUSTOMER-INFORMATION-01
end-if
exit.
*****************************************************************
UPDATE-CUSTOMER-INFORMATION-01.
* Attempt to update an existing record
move CUNUMBI to CUSTOMER-READ-KEY
perform CUSTMAST-READ-UPDATE
if DATA-RESP-CODE not = 0
add DATA-RESP-CODE to ZERO giving NUMBER-WORK-16
move 'ReRead Failed, ' to MSG-LINE-1(1:16)
move CUNUMBI to MSG-LINE-1(16:12)
move CUST-NUMBER to MSG-LINE-1(30:12)
move VERSION-NUMBER to MSG-LINE-1(70:9)
perform GENERAL-ERROR-ROUTINE
end-if.
perform DATA-SCREEN-TO-FILE
perform Z-GET-DATE-AND-TIME
move WORK-DATE to CUST-LADATE
move WORK-TIME to CUST-LATIME
move ZEROES to CUST-TOKEN
perform CUSTMAST-REWRITE
if DATA-RESP-CODE = 0
move
'Update Completed, type new request and press ENTER key'
to MSG-LINE-1(1:54)
move MSG-LINE-1 to SYSMSG1O
move ' ' to PF-ROW-23-44
perform SCREEN-IO-SEND-UPDATE
else
add DATA-RESP-CODE to ZERO giving NUMBER-WORK-16
move 'Update Failed, ' to MSG-LINE-1(1:16)
move CUNUMBI to MSG-LINE-1(16:12)
move CUST-NUMBER to MSG-LINE-1(30:12)
move VERSION-NUMBER to MSG-LINE-1(70:9)
perform GENERAL-ERROR-ROUTINE
end-if.
* Should never get to here...
exit.
*****************************************************************
UPDATE-CUSTOMER-INFORMATION-02.
* Attempt to add a new record
move CUNUMBI to CUSTOMER-READ-KEY
perform DATA-SCREEN-TO-FILE
perform Z-GET-DATE-AND-TIME
move WORK-DATE to CUST-LADATE
move WORK-TIME to CUST-LATIME
move ZEROES to CUST-TOKEN
perform CUSTMAST-WRITE
if DATA-RESP-CODE = 0
move
'Write Completed, type new request and press ENTER key '
to MSG-LINE-1(1:54)
move MSG-LINE-1 to SYSMSG1O
move ' ' to PF-ROW-23-44
perform SCREEN-IO-SEND-UPDATE
else
add DATA-RESP-CODE to ZERO giving NUMBER-WORK-16
move 'Write Failed, ' to MSG-LINE-1(1:16)
move CUNUMBI to MSG-LINE-1(16:12)
move CUST-NUMBER to MSG-LINE-1(30:12)
move VERSION-NUMBER to MSG-LINE-1(70:9)
perform GENERAL-ERROR-ROUTINE
end-if.
* Should never get to here...
exit.
*****************************************************************
* Delete all characters to the right of the first space then
* right-adjust with zero fill. This routine works with a single,
* twelve character field and does not require a work area.
*****************************************************************
Z-RIGHT-ADJUST-Z-WORK-12.
inspect Z-WORK-12
replacing CHARACTERS by ' ' after initial ' '
perform until Z-WORK-12(12:1) not = SPACE
if Z-WORK-12(12:1) = SPACE
add 11 to ZERO giving IX-12
perform 11 times
move Z-WORK-12(IX-12:1) to Z-WORK-12(IX-12 + 1:1)
subtract 1 from IX-12
end-perform
move ZERO to Z-WORK-12(1:1)
end-if
end-perform
exit.
*****************************************************************
Z-GET-DATE-AND-TIME.
accept WORK-DATE from DATE YYYYMMDD
accept WORK-TIME from TIME
move 'ccyy/mm/dd' to SYSDATEO
move WORK-DATE(1:4) to SYSDATEO(1:4)
move WORK-DATE(5:2) to SYSDATEO(6:2)
move WORK-DATE(7:2) to SYSDATEO(9:2)
move 'hh:mm:ss:dd' to SYSTIMEO
move WORK-TIME(1:2) to SYSTIMEO(1:2)
move WORK-TIME(3:2) to SYSTIMEO(4:2)
move WORK-TIME(5:2) to SYSTIMEO(7:2)
move WORK-TIME(7:2) to SYSTIMEO(10:2)
exit.
BMS Member, Customer File Update
The following (CU2UPD1.bms) is the BMS source code for the "Update" screen map that is used to display and update the Customer Master Record to a 3270 device.
***********************************************************************
* This BMS Member is provided by SimoTime Technologies *
* (C) Copyright 1987-2019 All Rights Reserved *
* Web Site URL: http://www.simotime.com *
* e-mail: helpdesk@simotime.com *
***********************************************************************
CU2UPD1 DFHMSD CTRL=(FREEKB), -
LANG=COBOL, -
MODE=INOUT, -
STORAGE=AUTO, -
TERM=3270, -
TIOAPFX=YES, -
TYPE=&&SYSPARM
*
CU2UPD1 DFHMDI SIZE=(24,80), -
TIOAPFX=YES
SYSPAGE DFHMDF ATTRB=(ASKIP,FSET,NORM), -
LENGTH=8, -
POS=(1,1), -
INITIAL='CU2UPD1 '
DFHMDF LENGTH=0, -
POS=(1,11)
DFHMDF ATTRB=(ASKIP,BRT), -
LENGTH=29, -
POS=(1,25), -
INITIAL='Data Files and VSAM Data Sets'
* UPDATE-MAP-DATE
SYSDATE DFHMDF ATTRB=(ASKIP,NORM), -
LENGTH=10, -
POS=(1,69)
SYS-ID DFHMDF ATTRB=(ASKIP,NORM), -
LENGTH=4, -
POS=(2,1)
DFHMDF ATTRB=(ASKIP,BRT), -
LENGTH=22, -
POS=(2,28), -
INITIAL='Customer Update Option'
* UPDATE-MAP-TIME
SYSTIME DFHMDF ATTRB=(ASKIP,NORM), -
LENGTH=11, -
POS=(2,68)
DFHMDF ATTRB=(ASKIP,BRT), -
LENGTH=15, -
POS=(4,5), -
INITIAL='New Customer #:'
REQNUMB DFHMDF ATTRB=(BRT,IC,UNPROT), -
LENGTH=12, -
POS=(4,21)
DFHMDF LENGTH=0, -
POS=(4,34)
DFHMDF ATTRB=(ASKIP,NORM), -
LENGTH=11, -
POS=(6,9), -
INITIAL='Customer #:'
CUNUMB DFHMDF ATTRB=(ASKIP,BRT,FSET), -
LENGTH=12, -
POS=(6,21)
DFHMDF LENGTH=10, -
POS=(7,10), -
INITIAL='Last Name:'
* UPDATE-LAST-NAME
CULNAME DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=28, -
POS=(7,21)
DFHMDF LENGTH=6, -
POS=(8,14), -
INITIAL='First:'
* UPDATE-FIRST-NAME
CUFNAME DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=20, -
POS=(8,21)
DFHMDF ATTRB=(ASKIP), -
LENGTH=7, -
POS=(8,47), -
INITIAL='Middle:'
* UPDATE-MIDDLE-NAME
CUMNAME DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=20, -
POS=(8,55)
DFHMDF LENGTH=7, -
POS=(10,13), -
INITIAL='Addr-1:'
CUADR1 DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=48, -
POS=(10,21)
DFHMDF LENGTH=7, -
POS=(11,13), -
INITIAL='Addr-2:'
CUADR2 DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=48, -
POS=(11,21)
DFHMDF LENGTH=5, -
POS=(12,15), -
INITIAL='City:'
CUCITY DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=28, -
POS=(12,21)
DFHMDF LENGTH=15, -
POS=(13,5), -
INITIAL='State/Province:'
CUSTATE DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=28, -
POS=(13,21)
DFHMDF LENGTH=12, -
POS=(13,51), -
INITIAL='Postal Code:'
CUZIP DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=12, -
POS=(13,64)
DFHMDF LENGTH=71, -
POS=(15,7), -
INITIAL='*--------------------------Telephone Numbers----
-----------------------*'
DFHMDF LENGTH=4, -
POS=(16,2), -
INITIAL='Home'
CUPHONH DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=18, -
POS=(16,7)
DFHMDF LENGTH=4, -
POS=(16,28), -
INITIAL='Work'
CUPHONW DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=18, -
POS=(16,33)
DFHMDF LENGTH=4, -
POS=(16,55), -
INITIAL='Cell'
CUPHONC DFHMDF ATTRB=(BRT,FSET,UNPROT), -
LENGTH=18, -
POS=(16,60)
DFHMDF LENGTH=19, -
POS=(18,11), -
INITIAL='Last Activity Date:'
CULDATE DFHMDF ATTRB=(BRT,FSET,PROT), -
LENGTH=10, -
POS=(18,31)
DFHMDF LENGTH=5, -
POS=(18,43), -
INITIAL='Time:'
CULTIME DFHMDF ATTRB=(BRT,FSET,PROT), -
LENGTH=11, -
POS=(18,49)
DFHMDF LENGTH=6, -
POS=(18,62), -
INITIAL='Token:'
CUTOKEN DFHMDF ATTRB=(BRT,FSET,PROT), -
LENGTH=3, -
POS=(18,69)
* UPDATE-ERROR-MESSAGE
SYSMSG1 DFHMDF ATTRB=(BRT,PROT), -
LENGTH=78, -
POS=(21,1)
* UPDATE-ERROR-MESSAGE
SYSMSG2 DFHMDF ATTRB=(BRT,PROT), -
LENGTH=78, -
POS=(22,1)
PFROW23 DFHMDF ATTRB=(ASKIP,BRT), -
LENGTH=78, -
POS=(23,1)
DFHMSD TYPE=FINAL
END
COBOL Copy File, Record Structure
The following (CUSTCB01.cpy) is the source code for the COBOL Copy File that defines the record structure for the Customer Master File.
*****************************************************************
* CUSTCB01.cpy - a COBOL Copy Member *
* Customer Master File used for Quality Assurance Testing *
* This is a VSAM Keyed-Sequential-Data-Set or KSDS *
* Copyright (C) 1987-2020 SimoTime Technologies *
* All Rights Reserved *
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
* CUST-RECORD size is 512 bytes.
* RMIN is 512 RMAX is 512
* KPOS is 1 KLEN is 012
*
....:.*..1....:....2....:....3....:....4....:....5....:....6....:....7....:....8
01 CUST-RECORD.
05 CUST-NUMBER PIC X(12). col A
05 CUST-DATA.
10 CUST-STATUS PIC X. col B
10 CUST-NAME.
15 CUST-LAST-NAME PIC X(28). col C
15 CUST-FIRST-NAME PIC X(20). col D
15 CUST-MID-NAME PIC X(20). col E
10 CUST-ADDRESS-1 PIC X(48). col F
10 CUST-ADDRESS-2 PIC X(48). col G
10 CUST-CITY PIC X(28). col H
10 CUST-STATE PIC X(28). col I
10 CUST-POSTAL-CODE PIC X(12). col J
10 CUST-PHONE-HOME PIC X(18). col K
10 CUST-PHONE-WORK PIC X(18). col L
10 CUST-PHONE-CELL PIC X(18). col M
10 CUST-CREDIT-LIMIT PIC 9(7) COMP-3. col N
10 CUST-DISCOUNT OCCURS 3 TIMES.
15 CUST-DISCOUNT-CODE PIC S9(3) COMP. col ORU
15 CUST-DISCOUNT-RATE PIC S9(2)V999. col PSV
15 CUST-DISCOUNT-DATE PIC X(8). col QTW
10 CUST-LADATE PIC X(8). col X
10 CUST-LATIME PIC X(8). col Y
10 CUST-TOKEN PIC 9(3). col Z
10 FILLER PIC X(145).
*
*** CUSTCB01 - End-of-Copy File - - - - - - - - - - - CUSTCB01 *
*****************************************************************
*
Summary
The purpose of this suite of program is to provide examples that use command level CICS in COBOL programs to access VSAM, Key-Sequenced-Data-Sets (KSDS) and display the information using standard BMS screen definitions to a 3270 terminal or terminal emulator. This document may be used as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the 
icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the 
icon.
Explore the CICS Connection for more examples of mainframe CICS coding techniques and sample code.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| Customer Master, Record Update, Access to a VSAM Data Set using CICS |
| Copyright © 1987-2025 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |