| |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Submit the Job |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Get Input, display to SYSOUT |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Check for End-of-File |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
Callable I/O Routine, read the file |
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
End-Of-Job |
| |
|
|
|
|
|
|
|
|
Overview, COBOL calling COBOL to Read a Sequential File
|
Color Associations: The light-green boxes are unique to SIMOTIME Technologies using an IBM Mainframe System or Micro Focus Enterprise Developer.
The light-red boxes are unique to the SIMOTIME Technologies using a Linux, UNIX or Windows System and COBOL Technologies such as Micro Focus.
The light-yellow boxes are SIMOTIME Technologies, Third-party Technologies, decision points or program transitions in the processing logic or program generations.
The light-blue boxes identify the input/output data structures such as Documents, Spreadsheets, Data Files, VSAM Data Sets, Partitioned Data Set Members (PDSM's) or Relational Tables.
The light-gray boxes identify a system function or an informational item.
The Calling Convention
The following summarizes the items needed for a "calling program" (CBLQSMC1.CBL) to call a "called program" (CBLQSMC2).
The "calling program" contains the following statement to make the call to the "called program".
CALL 'CBLQSMC2' USING PASS-AREA
The "calling program" needs the following data structure (PASS-AREA) to be defined in the WORKING-STORAGE section.
*****************************************************************
* Data Structure used for calling CBLQSMC2.
* The calling statement is as follows...
* CALL 'CBLQSMC2' USING PASS-AREA
*
01 PASS-AREA.
05 PASS-REQUEST pic X(8).
05 PASS-RESULT pic S9(9) comp.
88 NORMAL-RESULT value 0.
88 COBOL-RESULT-SAME value 8.
88 EOF-RESULT value 16.
05 PASS-RECORD.
10 PASS-KEY pic X(6).
10 PASS-INFO pic X(74).
*****************************************************************
The "called-program" needs the following Linkage Section defined for the pass area.
*****************************************************************
LINKAGE SECTION.
* Data Structure used for passing the address or an address
* list of a data string or strings..
* The Procedure Division statement must also be as follows...
* The PROCEDURE DIVISION using PASS-AREA.
*
01 PASS-AREA.
05 PASS-REQUEST pic X(8).
05 PASS-RESULT pic S9(9) comp.
88 NORMAL-RESULT value 0.
88 COBOL-RESULT-SAME value 8.
88 EOF-RESULT value 16.
05 PASS-RECORD.
10 PASS-KEY pic X(6).
10 PASS-INFO pic X(74).
*****************************************************************
In addition to defining the pass area in the Linkage Section the "called program" needs the Procedure Division statement to be coded as follows.
PROCEDURE DIVISION using PASS-AREA.
The source code listings for both the "calling program" and the "called program" are included within this document.
The JCL Members
The following section describes three (3) JCL members. The first JCL member will execute a COBOL program that calls a second COBOL to access a sequential file. The second JCL member is used to create and populate a sequential file. The third JCL member will delete the sequential file.
COBOL calls COBOL I/O Routine
The following is the JCL member (CBLQSMJ1.jcl) required to run the mainline program. The coding technique is used with the expectation the JCL would be used as a stand alone procedure. The job and DD statements will need to be modified for different mainframe environments.
//CBLQSMJ1 JOB SIMOTIME,ACCOUNT,CLASS=1,MSGCLASS=0,NOTIFY=CSIP1
//* *******************************************************************
//* CBLQSMJ1.JCL - a JCL Member for Batch Job Processing *
//* This program is provided by SimoTime Technologies *
//* (C) Copyright 1987-2019 All Rights Reserved *
//* Web Site URL: http://www.simotime.com *
//* e-mail: helpdesk@simotime.com *
//* *******************************************************************
//*
//* Text - COBOL calling COBOL for QSAM File I/O.
//* Author - SimoTime Technologies
//* Date - January 01, 1987
//*
//* This set of programs illustrate the use of COBOL calling a 370
//* assembler program to do QSAM sequential I/O. The purpose is to
//* show the processing of a QSAM or Sequential File.
//*
//* This set of programs will run on a mainframe under MVS or on a
//* Personal Computer with Windows and Micro Focus Mainframe Express.
//*
//* ************
//* * CBLQSMJ1 *
//* ********jcl*
//* *
//* ************ ************
//* * CBLQSMC1 ************call**** CBLQSMC2 *
//* ********cbl* * ********cbl*
//* * * *
//* * * *
//* * * ************
//* * * * QSAMFILE *
//* * * *******data*
//* * *
//* * *
//* * * ************
//* * ************* DISPLAY *
//* * ****console*
//* *
//* *
//* *
//* ************
//* * EOJ *
//* ************
//*
//* *******************************************************************
//* Step 1 of 1, This is a single step job.
//*
//CBLQSMX1 EXEC PGM=CBLQSMC1
//STEPLIB DD DSN=SIMOTIME.DEMO.LOADLIB1,DISP=SHR
//QSAMFILE DD DSN=SIMOTIME.DATA.QSAM0080,DISP=SHR
//SYSOUT DD SYSOUT=*
//*
Create & Populate a Sequential File
The following is the JCL member (QSMCRTJ1.jcl) to create a new sequential file. Also, this member will delete any previously created file.
//QSMCRTJ1 JOB SIMOTIME,CLASS=1,MSGCLASS=0,NOTIFY=CSIP1
//* *******************************************************************
//* This program is provided by SimoTime Technologies *
//* (C) Copyright 1987-2019 All Rights Reserved *
//* Web Site URL: http://www.simotime.com *
//* e-mail: helpdesk@simotime.com *
//* *******************************************************************
//*
//* Text - Create a Sequential Data Set on disk using IEBGENER.
//* Author - SimoTime Technologies
//* Date - January 24, 1996
//*
//* The first job step (QSAMDELT) will delete any previously created
//* file. The second job step (QSAMCRT1) will create a new file.
//*
//* This set of programs will run on a mainframe under MVS or on a
//* Personal Computer with Windows and Micro Focus Mainframe Express.
//*
//* ************
//* * QSMCRTJ1 *
//* ********jcl*
//* *
//* *
//* ************ ************
//* * IEFBR14 ******* QSAM0080 *
//* ********utl* ***delete***
//* *
//* *
//* ************ ************ ************
//* * SYSIN ******* IEBGENER ******* QSAM0080 *
//* ********jcl* ********utl* *******qsam*
//* *
//* *
//* ************
//* * EOJ *
//* ************
//*
//* *******************************************************************
//* Step 1 of 2 Delete any previously created file...
//*
//QSAMDELT EXEC PGM=IEFBR14
//QSAM0080 DD DSN=SIMOTIME.DATA.QSAM0080,DISP=(MOD,DELETE,DELETE),
// STORCLAS=MFI,
// SPACE=(TRK,5),
// DCB=(RECFM=FB,LRECL=80,BLKSIZE=800,DSORG=PS)
//*
//* *******************************************************************
//* Step 2 of 2 Create and populate a new QSAM file...
//*
//QSAMCRT1 EXEC PGM=IEBGENER
//SYSPRINT DD SYSOUT=*
//SYSIN DD DUMMY
//* :....1....:....2....:....3....:....4....:....5....:....6....:....7....:....8
//SYSUT1 DD *
000100 Anderson Adrian 111 Peachtree Plaza Atlanta GA 26101
000200 Brown Billie 222 Baker Boulevard Baltimore MD 35702
000300 Carson Cameron 333 Crenshaw Blvd. Cupertino CA 96154
000400 Davidson Dion 444 Main Street Wilmington DE 27323
000500 Everest Evan 555 5TH Avenue New York NY 10341
000600 Franklin Francis 666 66TH Avenue Bedrock NY 11903
000700 Garfunkel Gwen 777 77TH Street New York NY 16539
000800 Harrison Hilary 888 88TH Street Pocatello ID 79684
000900 Isley Isabel 999 99TH Avenue Indianapolis IN 38762
001000 Johnson Jamie 1010 Paradise Drive Larkspur CA 90504
001100 Kemper Kelly 1111 Oak Circle Kansas City KS 55651
001200 Lemond Lesley 1212 Lockwood Road Mohave Desert AZ 80303
001300 Mitchell Marlow 1313 Miller Creek Road Anywhere TX 77123
001400 Newman Noel 1414 Park Avenue Santa Monica CA 90210
001500 Osborn Owen 1515 Center Stage Rolling Rock PA 36613
001600 Powell Pierce PO Box 1616 Ventura CA 97712
001700 Quigley Quincy 1717 Farm Hill Road Oshkosh WI 43389
001800 Ripley Ray 1818 Alien Lane Wayout KS 55405
001900 Smith Sammy 1919 Carnoustie Drive Novato CA 94919
002000 Tucker Taylor 2020 Sanger Lane St. Paul MN 43998
002100 Underwood Ulysses 2121 Wall Street New York NY 17623
002200 Van Etten Valerie 2222 Vine Street Hollywood CA 98775
002300 Wilson Wiley 2323 Main Street Boston MA 01472
002400 Xray Xavier 2424 24TH Street Nashville TN 44190
002500 Young Yanni 2525 Yonge Street Toronto ON 6B74A6
002600 Zenith Zebulon 2626 26TH Street Dallas TX 71922
123456 Doe John 123 Main Street Anywhere OR 88156
/*
//SYSUT2 DD DSN=SIMOTIME.DATA.QSAM0080,
// DISP=(NEW,CATLG,DELETE),
// STORCLAS=MFI,
// SPACE=(TRK,5),
// DCB=(RECFM=FB,LRECL=80,BLKSIZE=800,DSORG=PS)
//
Delete the Sequential File
The following is the mainframe JCL (QSMDELJ1.jcl) to delete the sequential file.
//QSMDELJ1 JOB SIMOTIME,CLASS=1,MSGCLASS=0,NOTIFY=CSIP1
//* *******************************************************************
//* This program is provided by SimoTime Technologies *
//* (C) Copyright 1987-2019 All Rights Reserved *
//* Web Site URL: http://www.simotime.com *
//* e-mail: helpdesk@simotime.com *
//* *******************************************************************
//*
//* Text - Delete a Sequential File on disk using IEFBR14.
//* Author - SimoTime Technologies
//* Date - January 24, 1996
//*
//* *******************************************************************
//*
//QSAMDELT EXEC PGM=IEFBR14
//QSAM0080 DD DSN=SIMOTIME.DATA.QSAM0080,DISP=(MOD,DELETE,DELETE),
// STORCLAS=MFI,
// SPACE=(TRK,5),
// DCB=(RECFM=FB,LRECL=80,BLKSIZE=800,DSORG=PS)
//*
The CMD Members or Files
The following section describes three (3) Windows Command files. The first CMD member will execute a COBOL program that calls a second COBOL to access a sequential file. The second CMD member is used to create and populate a sequential file. The third CMD member will delete the sequential file.
COBOL calls COBOL I/O Routine
The following is the Windows Command file (CBLQSME1.cmd) required to run the COBOL program without using mainframe JCL.
@echo OFF
rem * *******************************************************************
rem * CBLQSME1.CMD - a Windows Command File *
rem * This program is provided by SimoTime Technologies *
rem * (C) Copyright 1987-2019 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - COBOL calls COBOL I/O Routine for QSAM access.
rem * Author - SimoTime Enterprises
rem * Date - January 01, 2006
rem *
rem * This set of COBOL programs will use a standard calling interface
rem * between a mainline program and an I/O module to read and display
rem * the contents of a sequential file of 80-byte, fixed-length records.
rem *
rem * ********************************************************************
rem * Step 1 of 2, Set the global environment variables...
rem *
setlocal
call ..\Env1BASE %CmdName%
if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
set CmdName=CblQsmE1
rem *
call SimoNOTE "*******************************************************%CmdName%"
call SimoNOTE "Starting JobName %CmdName%"
rem * ********************************************************************
rem * Step 2 of 2, Execute the sample program...
rem *
set QSAMFILE=%BaseLib1%\DATA\Asc1\SIMOTIME.DATA.QSAM0080.DAT
rem *
run CBLQSMC1
if not "%ERRORLEVEL%" == "0" set JobStatus=0010
if not "%JobStatus%" == "0000" goto :EojNOK
:EojAOK
call SimoNOTE "Finished CmdName %CmdName%, Job Status is %JobStatus%"
goto :End
:EojNOK
call SimoNOTE "ABENDING CmdName %CmdName%, Job Status is %JobStatus%"
echo %DATE% - %TIME% Starting User ABEND Processing...>>%SYSLOG%
set >>%SYSLOG%
echo %DATE% - %TIME% Complete User ABEND Processing...>>%SYSLOG%
goto :End
:End
call SimoNOTE "Conclude SysOut is %SYSOUT%"
if not "%1" == "nopause" pause
exit /B %JobStatus%
Create & Populate a Sequential File
The following is the Windows Command file (QSMCRTE1.cmd) to create a new sequential file. Also, this member will delete any previously created files.
@echo OFF
rem * *******************************************************************
rem * QSMCRTE1.CMD - a Windows Command File *
rem * This program is provided by SimoTime Technologies *
rem * (C) Copyright 1987-2019 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - Create a Sequential Data Set on disk using IEBGENER.
rem * Author - SimoTime Technologies
rem * Date = January 24, 1996
rem *
rem * The first job step (DeleteTEXT) will delete any previously created
rem * files.
rem * The second job step (CreateTEXT) will create a new ASCII/Text file.
rem * The third step will convert the Line Sequential file to a Record
rem * Sequential file.
rem *
rem * This set of programs will run on a Personal Computer with Windows
rem * and Micro Focus Net Express.
rem *
rem *
rem * ************
rem * * QSMCRTE1 *
rem * ********cmd*
rem * *
rem * *
rem * ************
rem * * Env1BASE *
rem * ********cmd*
rem * *
rem * *
rem * ************ ************
rem * * if exist ******* TEXT0080 *
rem * ************ ***delete***
rem * *
rem * *
rem * ************ ************ ************
rem * * SYSIN ******* echo ******* TEXT0080 *
rem * ********cmd* ********utl* *******qsam*
rem * *
rem * *
rem * ************
rem * * EOJ *
rem * ************
rem *
rem * *******************************************************************
call ..\Env1BASE
if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
set JobName=QsmCrtE1
rem *
call SimoNOTE "*******************************************************%JobName%"
call SimoNOTE "Starting JobName %JobName%, v13.03.04, User is %USERNAME%"
call SimoNOTE "Identify JobStep DeleteQSAM"
set TEXT0080=%BaseLib1%\Data\Txt1\TEXT0080.txt
rem *
rem * *******************************************************************
rem * Step 1 of 2 Create and populate a new ASCII/TEXT file...
rem *
call SimoNOTE "Identify JobStep Create an ASCII/Text File"
if exist %TEXT0080% del %TEXT0080%
rem * ..1....:....2....:....3....:....4....:....5....:....6....:....7.
echo 000100 Anderson Adrian 111 Peachtree Plaza Atlanta GA 26101 >%TEXT0080%
echo 000200 Brown Billie 222 Baker Boulevard Baltimore MD 35702 >>%TEXT0080%
echo 000300 Carson Cameron 333 Crenshaw Blvd. Cupertino CA 96154 >>%TEXT0080%
echo 000400 Davidson Dion 444 Main Street Wilmington DE 27323 >>%TEXT0080%
echo 000500 Everest Evan 555 5TH Avenue New York NY 10341 >>%TEXT0080%
echo 000600 Franklin Francis 666 66TH Avenue Bedrock NY 11903 >>%TEXT0080%
echo 000700 Garfunkel Gwen 777 77TH Street New York NY 16539 >>%TEXT0080%
echo 000800 Harrison Hilary 888 88TH Street Pocatello ID 79684 >>%TEXT0080%
echo 000900 Isley Isabel 999 99TH Avenue Indianapolis IN 38762 >>%TEXT0080%
echo 001000 Johnson Jamie 1010 Paradise Drive Larkspur CA 90504 >>%TEXT0080%
echo 001100 Kemper Kelly 1111 Oak Circle Kansas City KS 55651 >>%TEXT0080%
echo 001200 Lemond Lesley 1212 Lockwood Road Mohave Desert AZ 80303 >>%TEXT0080%
echo 001300 Mitchell Marlow 1313 Miller Creek Road Anywhere TX 77123 >>%TEXT0080%
echo 001400 Newman Noel 1414 Park Avenue Santa Monica CA 90210 >>%TEXT0080%
echo 001500 Osborn Owen 1515 Center Stage Rolling Rock PA 36613 >>%TEXT0080%
echo 001600 Powell Pierce PO Box 1616 Ventura CA 97712 >>%TEXT0080%
echo 001700 Quigley Quincy 1717 Farm Hill Road Oshkosh WI 43389 >>%TEXT0080%
echo 001800 Ripley Ray 1818 Alien Lane Wayout KS 55405 >>%TEXT0080%
echo 001900 Smith Sammy 1919 Carnoustie Drive Novato CA 94919 >>%TEXT0080%
echo 002000 Tucker Taylor 2020 Sanger Lane St. Paul MN 43998 >>%TEXT0080%
echo 002100 Underwood Ulysses 2121 Wall Street New York NY 17623 >>%TEXT0080%
echo 002200 Van Etten Valerie 2222 Vine Street Hollywood CA 98775 >>%TEXT0080%
echo 002300 Wilson Wiley 2323 Main Street Boston MA 01472 >>%TEXT0080%
echo 002400 Xray Xavier 2424 24TH Street Nashville TN 44190 >>%TEXT0080%
echo 002500 Young Yanni 2525 Yonge Street Toronto ON 6B74A6>>%TEXT0080%
echo 002600 Zenith Zebulon 2626 26TH Street Dallas TX 71922 >>%TEXT0080%
echo 123456 Doe John 123 Main Street Anywhere OR 88156 >>%TEXT0080%
if exist %TEXT0080% call SimoNOTE "Produced DataSet %TEXT0080%"
if not exist %TEXT0080% set JobStatus=9001
if not %JobStatus% == 0000 goto :EojNok
rem *
rem * *******************************************************************
rem * Step 2 of 2 Convert ASCII/TEXT file to Record Sequential File...
rem *
call SimoNOTE "Identify JobStep Convert Line Sequential to Record Sequential"
set GETLS080=%TEXT0080%
set PUTRS080=%BaseLib1%\Data\Asc1\SIMOTIME.DATA.QSAM0080.DAT
if exist %PUTRS080% del %PUTRS080%
run CV80ALAR
if exist %PUTRS080% call SimoNOTE "Produced DataSet %PUTRS080%"
if not exist %PUTRS080% set JobStatus=9002
if not %JobStatus% == 0000 goto :EojNok
rem *
:EojAok
call SimoNOTE "Finished JobName %JobName%, Job Status is %JobStatus%"
goto :End
:EojNok
call SimoNOTE "NOTE ABENDING JobName %JobName%, Job Status is %JobStatus%"
:End
call SimoNOTE "Conclude SysLog is %SYSLOG%"
if not "%1" == "nopause" pause
Delete the Sequential File
The following is the Windows Command file (QSMDELE1.cmd) to delete the sequential files.
@echo OFF
rem * *******************************************************************
rem * QSMDELE1.CMD - a Windows Command File *
rem * This program is provided by SimoTime Technologies *
rem * (C) Copyright 1987-2019 All Rights Reserved *
rem * Web Site URL: http://www.simotime.com *
rem * e-mail: helpdesk@simotime.com *
rem * *******************************************************************
rem *
rem * Text - Delete the Sequential Data Sets for QSAM0080.
rem * Author - SimoTime Technologies
rem * Date = January 24, 1996
rem *
rem * The 1st job step (DeleteTEXT) will delete TEXT0080.TXT
rem * The 2nd job step (DeleteQSAM) will delete QSAM0080.DAT
rem *
rem * This set of programs will run on a Personal Computer with Windows
rem * and Micro Focus Net Express.
rem *
rem * *******************************************************************
call ..\Env1BASE
if "%SYSLOG%" == "" set syslog=c:\SimoLIBR\LOGS\SimoTime.LOG
set JobName=QsmDelE1
rem *
call SimoNOTE "*******************************************************%JobName%"
call SimoNOTE "Starting JobName %JobName%, v13.03.04, User is %USERNAME%"
rem *
:DeleteTEXT
set TEXT0080=%BaseLib1%\Data\Txt1\TEXT0080.TXT
call SimoNOTE "Identify JobStep Delete %TEXT0080%"
if exist %TEXT0080% del %TEXT0080%
:DeleteQSAM
set QSAM0080=%BaseLib1%\Data\Asc1\SIMOTIME.DATA.QSAM0080.DAT
call SimoNOTE "Identify JobStep Delete %QSAM0080%"
if exist %QSAM0080% del %QSAM0080%
rem *
:EojAok
call SimoNOTE "Finished JobName %JobName%, Job Status is %JobStatus%"
goto :End
:End
call SimoNOTE "Conclude SysLog is %SYSLOG%"
if not "%1" == "nopause" pause
The Mainline COBOL Program
This program (CBLQSMC1.cbl) was written to be used as a teaching and learning aid. The displays are not required and the parameters use full words. The displays would probably be removed and the request codes would probably be a single character in a production environment.
IDENTIFICATION DIVISION.
PROGRAM-ID. CBLQSMC1.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
* *
*****************************************************************
*
*****************************************************************
* Source Member: CBLQSMC1.CBL
*****************************************************************
*
* CBLQSMC1 - Call CBLQSMC2 to access a KSDS, VSAM file.
*
* CALLING PROTOCOL
* ----------------
* Use standard procedure to RUN or ANIMATE.
*
* DESCRIPTION
* -----------
* This program will call a COBOL routine to access a
* QSAM or Sequential file for sequential processing.
*
*
* ************
* * CBLCBLJ1 *
* ********jcl*
* *
* ************
* * IEFBR14 *
* ********utl*
* *
* ************ ************
* * CBLQSMC1 *-------------------* Display *
* ********cbl* ************
* * *
* * ***************call*********
* * *
* * *
* * ************ ************
* * * QSAM0080 *-----* CBLQSMC2 *
* * ********get* ********cbl*
* *
* ************
* * EOJ *
* ************
*
*
*
*****************************************************************
*
* MAINTENANCE
* -----------
* 1997/02/27 Simmons, Created program.
* 1997/02/27 Simmons, No changes to date.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
DATA DIVISION.
WORKING-STORAGE SECTION.
*****************************************************************
* Data-structure for Title and Copyright...
* ------------------------------------------------------------
01 SIM-TITLE.
05 T1 pic X(11) value '* CBLQSMC1 '.
05 T2 pic X(34) value 'Sample, COBOL calls COBOL for I/O '.
05 T3 pic X(10) value ' v03.01.24'.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* CBLQSMC1 '.
05 C2 pic X(20) value 'Copyright 1987-2019 '.
05 C3 pic X(28) value ' SimoTime Technologies '.
05 C4 pic X(20) value ' All Rights Reserved'.
01 SIM-THANKS-01.
05 C1 pic X(11) value '* CBLQSMC1 '.
05 C2 pic X(32) value 'Thank you for using this program'.
05 C3 pic X(32) value ' provided from SimoTime Technolo'.
05 C4 pic X(04) value 'gies'.
01 SIM-THANKS-02.
05 C1 pic X(11) value '* CBLQSMC1 '.
05 C2 pic X(32) value 'Please send all inquires or sugg'.
05 C3 pic X(32) value 'estions to the helpdesk@simotime'.
05 C4 pic X(04) value '.com'.
*****************************************************************
01 REQUEST-OPEN pic X(8) value 'OPEN '.
01 REQUEST-GET pic X(8) value 'GET '.
01 REQUEST-CLOSE pic X(8) value 'CLOSE '.
01 REQUEST-KEY pic X(6).
01 END-OF-FILE pic X(3) value 'NO '.
01 OPERATOR-MESSAGE pic X(48).
*****************************************************************
* Data Structure used for calling CBLQSMC2.
* The calling statement is as follows...
* CALL 'CBLQSMC2' USING PASS-AREA
*
01 PASS-AREA.
05 PASS-REQUEST pic X(8).
05 PASS-RESULT pic S9(9) comp.
88 NORMAL-RESULT value 0.
88 COBOL-RESULT-SAME value 8.
88 EOF-RESULT value 16.
05 PASS-RECORD.
10 PASS-KEY pic X(6).
10 PASS-INFO pic X(74).
*****************************************************************
PROCEDURE DIVISION.
perform Z-POST-COPYRIGHT
display '* CBLQSMC1 OPEN Request...'.
perform OPEN-THE-FILE.
display '* CBLQSMC1 OPEN Complete...'.
perform until END-OF-FILE = 'YES'
if END-OF-FILE = 'NO '
move REQUEST-GET to PASS-REQUEST
move REQUEST-KEY to PASS-KEY
perform GET-NEXT-RECORD
if END-OF-FILE = 'NO '
display PASS-INFO
end-if
end-if
end-perform.
perform CLOSE-THE-FILE.
display '* CBLQSMC1 has COMPLETED...'
perform Z-THANK-YOU.
GOBACK.
*****************************************************************
GET-NEXT-RECORD.
call 'CBLQSMC2' using PASS-AREA.
if NORMAL-RESULT
CONTINUE
else
if EOF-RESULT
move 'YES' to END-OF-FILE
else
move '* CBLQSMC1 QKSD001F, Failure, GET...'
to OPERATOR-MESSAGE
perform Z-ABEND-MESSAGE
add 12 to ZERO giving RETURN-CODE
STOP RUN
end-if
end-if
exit.
*---------------------------------------------------------------*
OPEN-THE-FILE.
add 8 to ZERO giving PASS-RESULT.
move REQUEST-OPEN to PASS-REQUEST.
call 'CBLQSMC2' using PASS-AREA.
if NORMAL-RESULT
CONTINUE
else
move '* CBLQSMC1 QKSD001F, Failure, OPEN...'
to OPERATOR-MESSAGE
perform Z-ABEND-MESSAGE
add 12 to ZERO giving RETURN-CODE
STOP RUN
end-if
exit.
*---------------------------------------------------------------*
CLOSE-THE-FILE.
add 8 to ZERO giving PASS-RESULT.
move REQUEST-CLOSE to PASS-REQUEST.
call 'CBLQSMC2' using PASS-AREA.
if NORMAL-RESULT
CONTINUE
else
move '* CBLQSMC1 QSAM0080, Failure, CLOSE...'
to OPERATOR-MESSAGE
perform Z-ABEND-MESSAGE
add 12 to ZERO giving RETURN-CODE
add 12 to RETURN-CODE
STOP RUN
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative functions *
* for this program. *
*****************************************************************
*****************************************************************
Z-ABEND-MESSAGE.
if OPERATOR-MESSAGE not = SPACES
perform Z-DISPLAY-CONSOLE-MESSAGE
else
move '* CBLQSMC1 is ABENDING...' to OPERATOR-MESSAGE
perform Z-DISPLAY-CONSOLE-MESSAGE
end-if
exit.
*****************************************************************
Z-DISPLAY-CONSOLE-MESSAGE.
display OPERATOR-MESSAGE upon console
move SPACES to OPERATOR-MESSAGE
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE
display SIM-COPYRIGHT
exit.
*****************************************************************
Z-THANK-YOU.
display SIM-THANKS-01
display SIM-THANKS-02
exit.
*****************************************************************
* This example is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The COBOL I/O Routine
The following is the source listing for the I/O routine (CBLQSMC2.cbl). When an I/O failure occurs the file status code will be displayed. Displaying the file status code takes a little extra effort. Many times the file status code is a two character field and each character is a printable numeric value. However, in some cases the second character may be a COMP value. The error handling in the following program will display the file status code correctly for either format.
IDENTIFICATION DIVISION.
PROGRAM-ID. CBLQSMC2.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
* *
*****************************************************************
*
*****************************************************************
* Source Member: CBLQSMC2.CBL
*****************************************************************
*
*>CBLQSMC2 - This is a called routine for QSAM or Sequential
* file I/O.
*
* CALLING PROTOCOL
* ----------------
* USE STANDARD PROCEDURE TO RUN OR ANIMATE.
*
* DESCRIPTION
* -----------
* This program will do QSAM or Sequential file I/O.
*
****************************************************************
*
* MAINTENANCE
* -----------
* 1997/02/27 Simmons, Created program.
* 1997/04/04 Simmons, Added code to display file status.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
*
FILE-CONTROL.
*
SELECT QSAMFILE-FILE
ASSIGN to QSAMFILE
FILE STATUS is QSAMFILE-STATUS
ORGANIZATION is SEQUENTIAL
ACCESS MODE is SEQUENTIAL.
*
DATA DIVISION.
FILE SECTION.
*
FD QSAMFILE-FILE.
01 QSAMFILE-RECORD.
02 QSAMFILE-KEY pic X(6).
02 QSAMFILE-DATA pic X(74).
WORKING-STORAGE SECTION.
*
*****************************************************************
* Data-structure for Title and Copyright...
* ------------------------------------------------------------
01 SIM-TITLE.
05 T1 pic X(11) value '* CBLQSMC2 '.
05 T2 pic X(34) value 'Sample COBOL for Sequential I/O '.
05 T3 pic X(10) value ' v03.01.24'.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* CBLQSMC2 '.
05 C2 pic X(20) value 'Copyright 1987-2019 '.
05 C3 pic X(28) value ' SimoTime Technologies '.
05 C4 pic X(20) value ' All Rights Reserved'.
*
*****************************************************************
* Data-structure used within this program...
* ------------------------------------------------------------
01 QSAMFILE-STATUS.
05 QSAMFILE-STAT1 pic X.
05 QSAMFILE-STAT2 pic X.
*****************************************************************
* The following buffers are used to create a four-byte status *
* code that may be displayed. *
*****************************************************************
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 TWO-BYTES-BINARY pic 9(4) BINARY.
01 TWO-BYTES-ALPHA redefines TWO-BYTES-BINARY.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 IO-STATUS-04.
05 IO-STATUS-0401 pic 9 value 0.
05 IO-STATUS-0403 pic 999 value 0.
*****************************************************************
* Buffer used for posting messages to the console.
*****************************************************************
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* CBLVSMC1 '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(68) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
01 REQUEST-OPEN pic X(8) value 'OPEN '.
01 REQUEST-GET pic X(8) value 'GET '.
01 REQUEST-CLOSE pic X(8) value 'CLOSE '.
01 REQUEST-KEY pic X(6).
01 FIRST-TIME pic X value 'Y'.
*****************************************************************
LINKAGE SECTION.
* Data Structure used for passing the address or an address
* list of a data string or strings..
* The Procedure Division statement must also be as follows...
* The PROCEDURE DIVISION using PASS-AREA.
*
01 PASS-AREA.
05 PASS-REQUEST pic X(8).
05 PASS-RESULT pic S9(9) comp.
88 NORMAL-RESULT value 0.
88 COBOL-RESULT-SAME value 8.
88 EOF-RESULT value 16.
05 PASS-RECORD.
10 PASS-KEY pic X(6).
10 PASS-INFO pic X(74).
*****************************************************************
PROCEDURE DIVISION using PASS-AREA.
MAIN-ROUTINE.
if FIRST-TIME not = 'N'
perform Z-POST-COPYRIGHT
move 'N' to FIRST-TIME
end-if
evaluate PASS-REQUEST
when REQUEST-GET perform QSAMFILE-GET
when REQUEST-OPEN perform QSAMFILE-OPEN
when REQUEST-CLOSE perform QSAMFILE-CLOSE
when OTHER perform INVALID-REQUEST
end-evaluate
GOBACK.
*****************************************************************
INVALID-REQUEST.
display '* CBLQSMC2, Invalid Request, ' PASS-REQUEST
add 24 to ZERO giving PASS-RESULT
exit.
*****************************************************************
QSAMFILE-GET.
read QSAMFILE-FILE INTO PASS-RECORD
if QSAMFILE-STATUS = '00'
subtract PASS-RESULT from PASS-RESULT
else
if QSAMFILE-STATUS = '10'
add 16 to ZERO giving PASS-RESULT
else
add 12 to ZERO giving PASS-RESULT
display '* CBLQSMC2 QSAMFILE-Failed-READ-attempt...'
upon console
move QSAMFILE-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
end-if
end-if
exit.
*---------------------------------------------------------------*
QSAMFILE-OPEN.
open input QSAMFILE-FILE
if QSAMFILE-STATUS = '00'
subtract PASS-RESULT from PASS-RESULT
else
add 12 to ZERO giving PASS-RESULT
display '* CBLQSMC2 QSAMFILE-Failed-OPEN-attempt...'
upon console
move QSAMFILE-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
end-if
exit.
*---------------------------------------------------------------*
QSAMFILE-CLOSE.
close QSAMFILE-FILE
if QSAMFILE-STATUS = '00'
subtract PASS-RESULT from PASS-RESULT
else
add 12 to ZERO giving PASS-RESULT
display '* CBLQSMC2 QSAMFILE-Failed-CLOSE-attempt...'
upon console
move QSAMFILE-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative functions *
* for this program. *
*****************************************************************
*****************************************************************
* Display the file status bytes. This routine will display as *
* four digits. If the full two byte file status is numeric it *
* will display as 00nn. If the 1st byte is a numeric nine (9) *
* the second byte will be treated as a binary number and will *
* display as 9nnn. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
move IO-STAT1 to IO-STATUS-04(1:1)
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
add TWO-BYTES-BINARY to ZERO giving IO-STATUS-0403
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
else
move '0000' to IO-STATUS-04
move IO-STATUS to IO-STATUS-04(3:2)
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
end-if
exit.
*****************************************************************
* Display CONSOLE messages... *
*****************************************************************
Z-DISPLAY-MESSAGE-TEXT.
if MESSAGE-TEXT-2 = SPACES
display MESSAGE-BUFFER(1:79) upon console
else
display MESSAGE-BUFFER upon console
end-if
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE upon console
display SIM-COPYRIGHT upon console
exit.
*****************************************************************
* This example is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
Summary
This suite of programs provides an example of how a mainline COBOL program calls a mainframe COBOL I/O routine to access a QSAM or Sequential file. This document may be used to assist as a tutorial for new programmers or as a quick reference for experienced programmers
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the  icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the  icon.
Explore QSAM or Sequential File Access using a COBOL Program that calls an Assembler program to do the file I/O to read a QSAM or Sequential file and displays information to SYSOUT. The COBOL program is written using the COBOL/2 dialect but also work with COBOL for MVS and COBOL/370.
Explore QSAM or Sequential File Access using a single COBOL Program to read a QSAM or Sequential file and displays information to SYSOUT. The COBOL program is written using the COBOL/2 dialect but also work with COBOL for MVS and COBOL/370.
Explore the JCL Connection for more examples of JCL functionality with programming techniques and sample code.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore An Enterprise System Model that describes and demonstrates how Applications that were running on a Mainframe System and non-relational data that was located on the Mainframe System were copied and deployed in a Microsoft Windows environment with Micro Focus Enterprise Server.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License.
Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is
The SimoTime Home Page
for access to white papers, program examples and product information. This link requires an Internet Connection
Explore
The Micro Focus Web Site
for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
|
1.
|
Send an e-mail to our helpdesk.
|
|
2.
|
Our telephone numbers are as follows.
|
|
2.1.
|
1 415 763-9430 office-helpdesk
|
|
2.2.
|
1 415 827-7045 mobile
|
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
|
QSAM or Sequential File Access using COBOL called by COBOL
|
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |
| 