Write to a Log File
|
SIMOV32K, Hex-Dump Write to a Log File |
|
| The SimoTime Home Page |
Introduction
This document provides a brief description of the SIMOV32K program and a listing of the COBOL source code for viewing.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2024
SimoTime Technologies and Services
All Rights Reserved
What it Does
The SIMOV32K program (or callable routine) is a callable routine that will write a message to a Log File. The file format is record sequential with the record size varying from 64 to 32,760 characters. SYSPROBE is the logical name of the log file used by the program.
How to Use
The following will cause the SIMOV32K routine to write "Hello World" as a text string to the SYSPROBE log file.
MOVE 'Hello World' to SIMOV32K-MESSAGE
add 48 to ZERO giving SIMOV32K-LENGTH
MOVE 'POST' to SIMOV32K-REQUEST
CALL 'SIMOV32K' using SIMOV32K-PASS-AREA
SIMOV32K-MESSAGE
In the preceding example the text "Hello World" will be displayed on the screen and written to the log file
The following will cause the SIMOV32K routine to write multiple records in a Hex-Dump format to the SYSPROBE log file.
MOVE 'Hello World' to SIMOV32K-MESSAGE
add 48 to ZERO giving SIMOV32K-LENGTH
MOVE 'DUMP' to SIMOV32K-REQUEST
CALL 'SIMOV32K' using SIMOV32K-PASS-AREA
SIMOV32K-MESSAGE
The following is an example of a Hex-Dump output to SYSPROBE.
Hello World 222466662567662222222222222222222222222222222222 00085CCF07F2C40000000000000000000000000000000000 .....%%?..?.%...................................
A copy file is provided to define the pass area to be used when calling SIMOV32K. The following statement is required in the WORKING STORAGE section of the calling program.
COPY PASSV32K.
Note: The maximum length for the message text is 32,760 characters.
The COBOL Source Code
The following (SIMOV32K.cbl) is the COBOL Source Code.
*set ASSIGN(EXTERNAL) NOOPTIONAL-FILE SEQUENTIAL(LINE)
IDENTIFICATION DIVISION.
PROGRAM-ID. SIMOV32K.
*AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
* *
*****************************************************************
* Source Member: SIMOV32K.CBL
*****************************************************************
*
* SIMOV32K - Call SIMOV32K to write record to the Message file.
*
* CALLING PROTOCOL
* ----------------
* Use standard procedure to EXECUTE, RUN or ANIMATE.
*
* DESCRIPTION
* -----------
* This program will write a message to the SYSRUSER file.
*
* REQUIREMENTS
* ------------
* The COBOL/390 dialect is required for Y2K date processing.
* The following directives are required for Micro Focus.
* ASSIGN(EXTERNAL) Map COBOL file name to externally defined name
* SEQUENTIAL(LINE) Treat COBOL SEQUENTIAL as a LINE SEQUENTIAL
* NOOPTIONAL-FILE The OPEN EXTEND file must exist or post error
*
*****************************************************************
*
* MAINTENANCE
* -----------
* 1997/12/18 Simmons, Created program.
* 1997/12/18 Simmons, No changes to date.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
*****************************************************************
SELECT SYSRUSER-FILE
ASSIGN to SYSRUSER
ORGANIZATION is SEQUENTIAL
ACCESS MODE is SEQUENTIAL
FILE STATUS is SYSRUSER-LOG-STATUS.
*****************************************************************
*
DATA DIVISION.
FILE SECTION.
*
*****************************************************************
FD SYSRUSER-FILE
DATA RECORD IS SYSRUSER-RECORD
RECORDING MODE is V
RECORD is VARYING in SIZE from 4 to 32756
DEPENDING ON MESSAGE-LENGTH.
01 SYSRUSER-RECORD.
05 SYSRUSER-DATA pic X(32756).
*****************************************************************
WORKING-STORAGE SECTION.
01 SYSRUSER-LOG-STATUS.
05 SYSRUSER-LOG-STAT1 pic X.
05 SYSRUSER-LOG-STAT2 pic X.
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 IO-STATUS-04.
05 IO-STATUS-0401 pic 9 value 0.
05 IO-STATUS-0403 pic 999 value 0.
01 TWO-BYTES-BINARY pic 9(4) BINARY.
01 TWO-BYTES-ALPHA redefines TWO-BYTES-BINARY.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 SYSRUSER-OPEN-FLAG pic X value 'N'.
01 FIRST-TIME pic X value 'Y'.
*****************************************************************
* Message Buffer used by the Z-DISPLAY-TO-SYSOUT routine. *
*****************************************************************
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(011) value '* SIMOV32K '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(068) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
01 MSG-LSB pic 9(5) value 267.
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
01 WORK-04 pic X(4).
01 LINE-LENGTH pic 9(5) value 80.
*****************************************************************
* Define the format for the Hexp-Dump Output. *
*****************************************************************
01 DUMP-FLAGS.
05 DUMP-ASC pic X value 'Y'.
05 DUMP-EBC pic X value 'Y'.
05 DUMP-HEX pic X value 'Y'.
05 DUMP-RPI pic X value 'Y'.
05 DUMP-DET-GRP.
10 DUMP-DET pic X value 'Y'.
10 DUMP-DET-2 pic XX value 'NE'.
05 DUMP-SUM pic X value 'Y'.
05 DUMP-VID pic X value 'N'.
05 DUMP-STATUS pic x VALUE 'Y'.
05 filler pic X(6) value SPACES.
*****************************************************************
01 DUMP-INFO.
10 DUMP-INFO-ASCII pic X(32756).
10 DUMP-INFO-UPPER pic X(32756).
10 DUMP-INFO-LOWER pic X(32756).
10 DUMP-INFO-EBCDIC pic X(32756).
01 FIVE-BYTES pic X(5).
01 IDX-1 pic 9(3) BINARY.
01 IDX-1R REDEFINES IDX-1.
05 IDX-1R-01 pic X.
05 IDX-1R-02 pic X.
01 IDX-2 pic 9(3) BINARY.
01 D-LEN pic 9(5) value 128.
01 D-POS pic 9(5) value 1.
01 WORK-DATE.
05 WORK-DATE-08 pic X(8).
01 WORK-TIME pic X(8).
01 MESSAGE-LENGTH pic 9(5) value 1024.
01 COUNTER-LENGTH pic 9(5) value 1024.
01 DISPLAY-LEN pic 9(5) value 1024.
01 DISPLAY-POS pic 9(5) value 1.
01 LOG-DATE pic X(10) value 'yyyy/nn/nn'.
01 LOG-TIME pic X(11) value 'nn:nn:nn:nn'.
COPY PASSDUMP.
COPY HEXTAB02.
*****************************************************************
LINKAGE SECTION.
COPY PASSULOG.
*****************************************************************
PROCEDURE DIVISION using ULOG-PASS-AREA, ULOG-MESSAGE.
add 8 to ZERO giving ULOG-STATUS
move ULOG-REQUEST to WORK-04
evaluate WORK-04
when 'POST' perform POST-TO-OUTPUT-DEVICES
when 'TEXT' perform TEXT-TO-LOG
if SYSRUSER-OPEN-FLAG = 'Y'
and SYSRUSER-LOG-STATUS = '00'
move ZERO to ULOG-STATUS
end-if
when 'HYPE' perform HYPE-TEXT-TO-LOG
when 'DUMP' perform DUMP-TO-SYSRUSER
when 'CLOS' perform ULOG-CLOSE
when 'MAKE' perform ULOG-OPEN-OUTPUT
when 'OPEN' perform ULOG-OPEN-EXTEND
when 'PREP' perform PROCESS-PREPARE-REQUEST
when OTHER GOBACK
end-evaluate
GOBACK.
*****************************************************************
DETERMINE-LENGTH-OF-MESSAGE.
add 1024 to ZERO giving MESSAGE-LENGTH
if ULOG-MESSAGE(513:512) = SPACES
add 512 to ZERO giving MESSAGE-LENGTH
if ULOG-MESSAGE(257:256) = SPACES
add 256 to ZERO giving MESSAGE-LENGTH
if ULOG-MESSAGE(129:128) = SPACES
add 128 to ZERO giving MESSAGE-LENGTH
if ULOG-MESSAGE(65:64) = SPACES
add 64 to ZERO giving MESSAGE-LENGTH
end-if
end-if
else
if ULOG-MESSAGE(385:128) = SPACES
add 384 to ZERO giving MESSAGE-LENGTH
end-if
end-if
else
if ULOG-MESSAGE(769:256) = SPACES
add 768 to ZERO giving MESSAGE-LENGTH
else
if ULOG-MESSAGE(897:128) = SPACES
add 896 to ZERO giving MESSAGE-LENGTH
end-if
end-if
end-if
perform
until MESSAGE-LENGTH = 0
or ULOG-MESSAGE(MESSAGE-LENGTH:1) not = SPACE
if ULOG-MESSAGE(MESSAGE-LENGTH:1) = SPACE
subtract 1 from MESSAGE-LENGTH
end-if
end-perform
add 27 to MESSAGE-LENGTH
exit.
*****************************************************************
* Display Messages to SYSOUT Device or SYSTEM Operator Console *
*****************************************************************
DISPLAY-ULOG-MESSAGE.
add MESSAGE-LENGTH to ZERO giving COUNTER-LENGTH
if WORK-04(1:3) = 'OUT'
add 120 to LINE-LENGTH
else
add 80 to LINE-LENGTH
end-if
add 1 to ZERO giving DISPLAY-POS
perform until COUNTER-LENGTH < 1
if COUNTER-LENGTH > LINE-LENGTH
add LINE-LENGTH to ZERO giving DISPLAY-LEN
else
add COUNTER-LENGTH to ZERO giving DISPLAY-LEN
end-if
perform DISPLAY-ULOG-MESSAGE-02
add DISPLAY-LEN to DISPLAY-POS
*
if DISPLAY-LEN > ZERO
and DISPLAY-LEN < COUNTER-LENGTH
subtract DISPLAY-LEN from COUNTER-LENGTH
else
move ZERO to COUNTER-LENGTH
end-if
end-perform
exit.
*---------------------------------------------------------------*
DISPLAY-ULOG-MESSAGE-02.
if work-04(1:3) = 'OUT'
display ULOG-MESSAGE(DISPLAY-POS:DISPLAY-LEN)
else
display ULOG-MESSAGE(DISPLAY-POS:DISPLAY-LEN)
upon console
end-if
exit.
*****************************************************************
DUMP-TO-SYSRUSER.
if SYSRUSER-OPEN-FLAG not = 'Y'
perform ULOG-OPEN-EXTEND
end-if
move SPACES to SYSRUSER-DATA
add ULOG-LENGTH to ZERO giving MESSAGE-LENGTH
move all SPACES to DUMP-INFO
perform varying IDX-2 from 1 by 1
until IDX-2 > ULOG-LENGTH
add 1 to ZERO giving IDX-1
move ULOG-MESSAGE(IDX-2:1) to IDX-1R-02
add 1 to IDX-1
move TAB-X1(IDX-1) to FIVE-BYTES
move FIVE-BYTES(1:1) to DUMP-INFO-UPPER(IDX-2:1)
move FIVE-BYTES(2:1) to DUMP-INFO-LOWER(IDX-2:1)
move FIVE-BYTES(3:1) to DUMP-INFO-EBCDIC(IDX-2:1)
move FIVE-BYTES(4:1) to DUMP-INFO-ASCII(IDX-2:1)
end-perform
if DUMP-ASC = 'Y'
move DUMP-INFO-ASCII(1:ULOG-LENGTH) to SYSRUSER-DATA
perform ULOG-WRITE
end-if
if DUMP-HEX = 'Y'
move DUMP-INFO-UPPER(1:ULOG-LENGTH) to SYSRUSER-DATA
perform ULOG-WRITE
move DUMP-INFO-LOWER(1:ULOG-LENGTH) to SYSRUSER-DATA
perform ULOG-WRITE
end-if
if DUMP-EBC = 'Y'
move DUMP-INFO-EBCDIC(1:ULOG-LENGTH) to SYSRUSER-DATA
perform ULOG-WRITE
end-if
exit.
*****************************************************************
GET-DATE-AND-TIME.
accept WORK-DATE from DATE YYYYMMDD
accept WORK-TIME from TIME
move WORK-DATE(1:4) to LOG-DATE(1:4)
move WORK-DATE(5:2) to LOG-DATE(6:2)
move WORK-DATE(7:2) to LOG-DATE(9:2)
move WORK-TIME(1:2) to LOG-TIME(1:2)
move WORK-TIME(3:2) to LOG-TIME(4:2)
move WORK-TIME(5:2) to LOG-TIME(7:2)
move WORK-TIME(7:2) to LOG-TIME(10:2)
exit.
*****************************************************************
PROCESS-PREPARE-REQUEST.
move 'SYSLOG-MODE is &&&&&&&& and &&&&' to MESSAGE-TEXT
inspect MESSAGE-TEXT
replacing first '&&&&&&&&' by ULOG-SYSLOG-MODE
inspect MESSAGE-TEXT
replacing first '&&&&' by ULOG-SYSLOG-FORMAT
perform Z-DISPLAY-TO-SYSOUT
move 'SYSOUT-MODE is &&&&&&&& and &&&&' to MESSAGE-TEXT
inspect MESSAGE-TEXT
replacing first '&&&&&&&&' by ULOG-SYSOUT-MODE
inspect MESSAGE-TEXT
replacing first '&&&&' by ULOG-SYSOUT-FORMAT
perform Z-DISPLAY-TO-SYSOUT
move 'SYSCON-MODE is &&&&&&&& and &&&&' to MESSAGE-TEXT
inspect MESSAGE-TEXT
replacing first '&&&&&&&&' by ULOG-SYSCON-MODE
inspect MESSAGE-TEXT
replacing first '&&&&' by ULOG-SYSCON-FORMAT
perform Z-DISPLAY-TO-SYSOUT
exit.
*****************************************************************
POST-TO-OUTPUT-DEVICES.
if ULOG-LENGTH < 1 or > 32756
add 1024 to ZERO giving MESSAGE-LENGTH
else
add ULOG-LENGTH to ZERO giving MESSAGE-LENGTH
end-if
if ULOG-SYSOUT-MODE = 'ENABLED '
move ULOG-MESSAGE(1:MESSAGE-LENGTH) to MESSAGE-TEXT
perform Z-DISPLAY-TO-SYSOUT
end-if
if ULOG-SYSCON-MODE = 'ENABLED '
move ULOG-MESSAGE(1:MESSAGE-LENGTH) to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
end-if
move ULOG-MESSAGE(1:MESSAGE-LENGTH) to SYSRUSER-DATA
perform ULOG-WRITE
exit.
*****************************************************************
HYPE-TEXT-TO-LOG.
if SYSRUSER-OPEN-FLAG not = 'Y'
perform ULOG-OPEN-EXTEND
end-if
move SPACES to SYSRUSER-DATA
if ULOG-LENGTH > 0
and ULOG-LENGTH < 32757
move ULOG-MESSAGE(1:ULOG-LENGTH)
to SYSRUSER-DATA(1:ULOG-LENGTH)
add ULOG-LENGTH to ZERO giving MESSAGE-LENGTH
else
move '* Invalid Message Length...' to SYSRUSER-DATA(1:27)
add 27 to ZERO giving MESSAGE-LENGTH
end-if
perform ULOG-WRITE
exit.
*****************************************************************
TEXT-TO-LOG.
if SYSRUSER-OPEN-FLAG not = 'Y'
perform ULOG-OPEN-EXTEND
end-if
move SPACES to SYSRUSER-DATA
if ULOG-LENGTH < 1 or > 32756
add 1024 to ZERO giving MESSAGE-LENGTH
else
add ULOG-LENGTH to ZERO giving MESSAGE-LENGTH
end-if
if DUMP-VID = 'Y'
move ULOG-MESSAGE(1:MESSAGE-LENGTH) to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
end-if
move ULOG-MESSAGE(1:MESSAGE-LENGTH) to SYSRUSER-DATA
perform ULOG-WRITE
exit.
*****************************************************************
* I/O ROUTINES TO CREATE THE MESSAGE FILE, SIMOV32K...
*****************************************************************
ULOG-WRITE.
write SYSRUSER-RECORD
if SYSRUSER-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if SYSRUSER-LOG-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if.
if APPL-AOK
CONTINUE
else
move 'FAILED-WRITE, Log file, SYSRUSER' to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
move SYSRUSER-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
ULOG-OPEN-EXTEND.
add 8 to ZERO giving APPL-RESULT.
open EXTEND SYSRUSER-FILE
if SYSRUSER-LOG-STATUS = '00'
move 'SYSRUSER, Open as EXTEND file' to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSRUSER-OPEN-FLAG
else
close SYSRUSER-FILE
* move 'SYSRUSER, Open as OUTPUT file' to MESSAGE-TEXT
* perform Z-DISPLAY-TO-CONSOLE
open output SYSRUSER-FILE
if SYSRUSER-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSRUSER-OPEN-FLAG
end-if
end-if
if APPL-AOK
CONTINUE
else
move 'FAILED-OPEN, Log file, SYSRUSER' to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
move SYSRUSER-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
ULOG-OPEN-OUTPUT.
add 8 to ZERO giving APPL-RESULT.
open OUTPUT SYSRUSER-FILE
if SYSRUSER-LOG-STATUS = '00'
* move 'SYSRUSER, Open as OUTPUT file' to MESSAGE-TEXT
* perform Z-DISPLAY-TO-CONSOLE
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSRUSER-OPEN-FLAG
else
close SYSRUSER-FILE
* move 'SYSRUSER, Open as OUTPUT file' to MESSAGE-TEXT
* perform Z-DISPLAY-TO-CONSOLE
open output SYSRUSER-FILE
if SYSRUSER-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSRUSER-OPEN-FLAG
end-if
end-if
if APPL-AOK
CONTINUE
else
move 'FAILED-OPEN, Log file, SYSRUSER' to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
move SYSRUSER-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
ULOG-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close SYSRUSER-FILE
if SYSRUSER-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'FAILED-CLOSE, Log file, SYSRUSER' to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
move SYSRUSER-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative functions *
* for this program. *
*****************************************************************
*****************************************************************
* ABEND the program and return to caller... *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-TO-CONSOLE
end-if
move 'Writing to log file is ABENDING...' to MESSAGE-TEXT
perform Z-DISPLAY-TO-CONSOLE
add 12 to ZERO giving RETURN-CODE
GOBACK.
*****************************************************************
Z-CALCULATE-MESSAGE-LSB.
add 267 to ZERO giving MSG-LSB
perform until MSG-LSB < 80
or MESSAGE-BUFFER(MSG-LSB:1) not = SPACE
if MESSAGE-BUFFER(MSG-LSB:1) = SPACE
subtract 1 from MSG-LSB
end-if
end-perform
exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* two digits if the full two byte file status is numeric. If *
* second byte is non-numeric then it will be treated as a *
* binary number. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
move IO-STAT1 to IO-STATUS-04(1:1)
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
add TWO-BYTES-BINARY to ZERO giving IO-STATUS-0403
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-TO-CONSOLE
perform Z-DISPLAY-TO-SYSOUT
else
move '0000' to IO-STATUS-04
move IO-STATUS to IO-STATUS-04(3:2)
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-TO-CONSOLE
perform Z-DISPLAY-TO-SYSOUT
end-if
exit.
*****************************************************************
* Display a message to SYSOUT Device... *
*****************************************************************
Z-DISPLAY-TO-SYSOUT.
perform Z-CALCULATE-MESSAGE-LSB
display MESSAGE-BUFFER(1:MSG-LSB)
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
* Display a message to Console Device... *
*****************************************************************
Z-DISPLAY-TO-CONSOLE.
perform Z-CALCULATE-MESSAGE-LSB
display MESSAGE-BUFFER(1:MSG-LSB) upon console
exit.
*****************************************************************
* This example is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The COBOL Copy File
The following (PASSV32K.cpy) is the COBOL copy file used when calling the SIMOV32K program.
*****************************************************************
* PASSV32K is a COBOL Copy File *
* Data Structure or Pass Area used for calling SIMOV32K. *
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
*****************************************************************
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
* SIMOV32K-REQUEST Type of request, must be one of the *
* following values. *
* POST - Write a message to a user-defined SYSLOG *
* file that uses the ULOG Application *
* Programming Interface. *
* DUMP - Write multiple records in Hex-Dump *
* format to the output file. *
* SIMOV32K-STATUS This is an indicator as to the success *
* or failure of the request. A value of *
* zero (0000) indicates the routine was *
* successful. A non-zero value indicates *
* a failure. *
* SIMOV32K-LENGTH Logical Record Length. *
* SIMOV32K-MESSAGE Contains the message text. *
*****************************************************************
01 SIMOV32K-PASS-AREA.
05 SIMOV32K-REQUEST pic X(4).
05 SIMOV32K-STATUS pic 9999.
05 SIMOV32K-LENGTH pic 9(5).
05 SIMOV32K-PROPERTIES.
10 SIMOV32K-SYSLOG-MODE pic X(8).
10 SIMOV32K-SYSLOG-FORMAT pic X(4).
10 SIMOV32K-SYSOUT-MODE pic X(8).
10 SIMOV32K-SYSOUT-FORMAT pic X(4).
10 SIMOV32K-SYSCON-MODE pic X(8).
10 SIMOV32K-SYSCON-FORMAT pic X(4).
05 SIMOV32K-DUMP-FLAGS.
10 SIMOV32K-DUMP-ASC pic X.
10 SIMOV32K-DUMP-EBC pic X.
10 SIMOV32K-DUMP-HEX pic X.
10 SIMOV32K-DUMP-RPI pic X.
10 SIMOV32K-DUMP-DTL pic X.
01 SIMOV32K-MESSAGE pic X(32756).
*** PASSV32K - End-of-Copy File - - - - - - - - - - - PASSV32K *
*****************************************************************
*
Summary
This document provides a brief description of the SIMOV32K program and a listing of the COBOL source code for viewing. This document may be used as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact, Comment or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the 
icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the 
icon.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Comments or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| SIMOV32K, Hex-Dump Routine, write to Log File |
| Copyright © 1987-2024 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |