SIMOPR80 - Eighty-Column Card File
|
Write, Record Sequential SIMOPR80 - Eighty-Column Card File |
|
| The SimoTime Home Page |
Introduction
This document provides a listing of the COBOL source code for a callable routine that provides write access to a Record Sequential file. This program is included in the SimoCARD suite of programs.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2024
SimoTime Technologies and Services
All Rights Reserved
How to Use
The SIMOPR80 program provides an easy to use, callable routine for accessing or writing records to a record sequential file with a fixed record length of 80-bytes.
First, the pass area (or data structure) must be defined in the WORKING-STORAGE section of the program that will call SIMOPR80. A COBOL copy file is provided for this purpose and the same copy file is used in the LINKAGE section of SIMOPR80.
COPY PASSPR80.
Next, the data items in the pass area need to be initialized prior to calling SIMOPR80.
move 'OPEN ' to PR80-FILE-REQUEST
move ZERO to PR80-FILE-STATUS
move SPACES to PR80-PASS-80
Next, the following shows the line of code that makes the call to SIMOPR80.
call 'SIMOPR80' using PR80-PASS-AREA
The following is a list of the parameters required when using the PR80-PASS-AREA to call the SimoPR80 routine.
| Parameter | Description | ||||||||
| PR80-PASS-REQUEST | This parameter must be provided by the calling program.
|
||||||||
| PR80-PASS-STATUS | A zero (0) value indicates a successful completion of the request. A non-zero value indicates the request could not be completed successfully. | ||||||||
| PR80-PASS-80 | This parameter will contain the logical record for a WRITE request. |
Note: A listing of the COBOL copy file is provided in a following section of this document.
Mapping the Data File Name
The SIMOPR80 program that writes a record sequential file uses the file name of "PUT080RS" when accessing the file. To have the program access the correct file the location and name of the physical file must be mapped to the name used by the program. This is accomplished by using an environment variable. The following shows how this is accomplished.
set PUT080RS=d:\mydirectory\filename.ext
The COBOL Source Code
The following (SIMOPR80.cbl) is a listing of the COBOL Source Code.
IDENTIFICATION DIVISION.
PROGRAM-ID. SIMOPR80.
AUTHOR. SIMOTIME TECHNOLOGIES.
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT PUT080RS-FILE ASSIGN TO PUT080RS
ORGANIZATION IS SEQUENTIAL
ACCESS MODE IS SEQUENTIAL
FILE STATUS IS PUT080RS-STATUS.
*****************************************************************
DATA DIVISION.
FILE SECTION.
FD PUT080RS-FILE
DATA RECORD IS PUT080RS-REC.
01 PUT080RS-REC.
05 PUT080RS-DATA-01 PIC X(80).
*****************************************************************
WORKING-STORAGE SECTION.
01 SIM-TITLE.
05 T1 pic X(11) value '* SIMOPR80 '.
05 T2 pic X(34) value 'Sequential 80 File I/O for Writes '.
05 T3 pic X(10) value 'v06.10.06 '.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* SIMOPR80 '.
05 C2 pic X(20) value 'Copyright 1987-2019 '.
05 C3 pic X(28) value ' SimoTime Technologies '.
05 C4 pic X(20) value ' All Rights Reserved'.
01 PUT080RS-STATUS.
05 PUT080RS-STATUS-L pic X.
05 PUT080RS-STATUS-R pic X.
01 PUT080RS-EOF pic X value 'N'.
01 PUT080RS-OPEN-FLAG pic X value 'C'.
*****************************************************************
* The following buffers are used to create a four-byte status *
* code that may be displayed. *
*****************************************************************
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 IO-STATUS-04.
05 IO-STATUS-0401 pic 9 value 0.
05 IO-STATUS-0403 pic 999 value 0.
01 TWO-BYTES-BINARY pic 9(4) BINARY.
01 TWO-BYTES-ALPHA redefines TWO-BYTES-BINARY.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
*****************************************************************
* Message Buffer used by the Z-DISPLAY-MESSAGE-TEXT routine. *
*****************************************************************
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* SIMOPR80 '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(68) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
*****************************************************************
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
01 READ-FLAGS.
05 READ-1 pic X value 'Y'.
05 READ-2 pic X value 'Y'.
01 DUMP-FLAGS.
05 DUMP-ASC pic X value 'Y'.
05 DUMP-EBC pic X value 'Y'.
05 DUMP-HEX pic X value 'Y'.
01 WORK-08 pic X(8) value SPACES.
01 ASC-EBC-FLAG pic X value 'A'.
01 FIRST-TIME pic X value 'Y'.
COPY ASCEBCB1.
COPY ASCEBCB2.
*****************************************************************
LINKAGE SECTION.
COPY PASSPR80.
*****************************************************************
PROCEDURE DIVISION using PR80-PASS-AREA.
move PR80-FILE-REQUEST to WORK-08
move 'A' to ASC-EBC-FLAG
evaluate WORK-08
when 'WRITE ' move PR80-PASS-80 to PUT080RS-DATA-01
perform PUT080RS-WRITE
when 'WRITEE2A' move PR80-PASS-80 to PUT080RS-DATA-01
inspect PUT080RS-DATA-01
converting E-INFO to A-INFO
perform PUT080RS-WRITE
when 'OPEN ' perform PUT080RS-OPEN-OUTPUT
when 'CLOSE ' perform PUT080RS-CLOSE
when other perform TRY-EBCDIC
end-evaluate
if PUT080RS-STATUS = '00'
move 0 to PR80-FILE-STATUS
else
add 4 to ZERO giving PR80-PASS-STATUS
end-if
if ASC-EBC-FLAG = 'E'
inspect PR80-PASS-STATUS converting A-INFO to E-INFO
inspect PR80-FILE-STATUS converting A-INFO to E-INFO
end-if
if FIRST-TIME = 'Y'
perform Z-POST-COPYRIGHT
display '* SimoPR80 ASC-EBC-FLAG is '
ASC-EBC-FLAG upon console
move 'N' to FIRST-TIME
end-if
GOBACK.
*****************************************************************
TRY-EBCDIC.
inspect WORK-08 converting E-INFO to A-INFO
evaluate WORK-08
when 'WRITE ' move 'E' to ASC-EBC-FLAG
move PR80-PASS-80 to PUT080RS-DATA-01
perform PUT080RS-WRITE
when 'WRITEE2A' move 'E' to ASC-EBC-FLAG
move PR80-PASS-80 to PUT080RS-DATA-01
inspect PUT080RS-DATA-01
converting E-INFO to A-INFO
perform PUT080RS-WRITE
when 'OPEN ' move 'E' to ASC-EBC-FLAG
perform PUT080RS-OPEN-OUTPUT
when 'CLOSE ' move 'E' to ASC-EBC-FLAG
perform PUT080RS-CLOSE
when other add 16 to ZERO giving PR80-PASS-STATUS
end-evaluate
exit.
*****************************************************************
* I/O Routines for the Control File... *
*****************************************************************
PUT080RS-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close PUT080RS-FILE
if PUT080RS-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'CLOSE Failure with PUT080RS' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move PUT080RS-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
PUT080RS-WRITE.
write PUT080RS-REC
if PUT080RS-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if PUT080RS-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'Y' to PUT080RS-EOF
else
move 'READ Failure with PUT080RS' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move PUT080RS-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
end-if
exit.
*---------------------------------------------------------------*
PUT080RS-OPEN-OUTPUT.
add 8 to ZERO giving APPL-RESULT.
open output PUT080RS-FILE
if PUT080RS-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'O' to PUT080RS-OPEN-FLAG
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'OPEN Failure with PUT080RS' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move PUT080RS-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-ROUTINES provide administrative functions *
* for this program. *
*****************************************************************
* ABEND the program, post a message to the console and issue *
* a STOP RUN. *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-MESSAGE-TEXT
end-if
move 'PROGRAM-IS-ABENDING...' to MESSAGE-TEXT
perform Z-DISPLAY-MESSAGE-TEXT
move IO-STATUS-04 to PR80-FILE-STATUS
add 12 to ZERO giving RETURN-CODE
add 12 to ZERO giving PR80-PASS-STATUS
* GOBACK.
exit.
*****************************************************************
* Display CONSOLE messages... *
*****************************************************************
Z-DISPLAY-MESSAGE-TEXT.
if MESSAGE-TEXT-2 = SPACES
display MESSAGE-BUFFER(1:79)
else
display MESSAGE-BUFFER
end-if
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* four digits. If the full two byte file status is numeric it *
* will display as 00nn. If the 1st byte is a numeric nine (9) *
* the second byte will be treated as a binary number and will *
* display as 9nnn. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
move IO-STAT1 to IO-STATUS-04(1:1)
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
add TWO-BYTES-BINARY to ZERO giving IO-STATUS-0403
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
else
move '0000' to IO-STATUS-04
move IO-STATUS to IO-STATUS-04(3:2)
move 'File Status is: nnnn' to MESSAGE-TEXT
move IO-STATUS-04 to MESSAGE-TEXT(17:4)
perform Z-DISPLAY-MESSAGE-TEXT
end-if
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE upon console
display SIM-COPYRIGHT upon console
exit.
*****************************************************************
* A product of SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The COBOL Copy File
The following (PASSPR80.cpy) is a listing of the COBOL Copy file that defines the structure for the data items in the pass area.
*****************************************************************
* Data Structure or Pass Area used for calling SIMOGT80. *
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
*****************************************************************
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
01 PR80-PASS-AREA.
05 PR80-PASS-REQUEST PIC X(8).
05 PR80-PASS-STATUS PIC 9(4).
05 PR80-FILE-REQUEST PIC X(8).
05 PR80-FILE-STATUS PIC 9(4).
05 PR80-PASS-80 PIC X(80).
*** PASSPR80 - End-of-Copy File - - - - - - - - - - - PASSPR80 *
*****************************************************************
*
Summary
The primary purpose of this document is to provide a COBOL Source member for viewing. This document may be used as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact, Comment or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document.
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the 
icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the 
icon.
Explore a Suite of Utility Programs that process sequential files with 80 byte records. This includes programs for the Mainframe and Micro Focus environments that do data file conversion and data file comparison.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Comments or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| Write Access for a Record Sequential File |
| Copyright © 1987-2024 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |