SimoLOGS, the COBOL Source Code
|
Trace or Display Function SimoLOGS, the COBOL Source Code |
|
| The SimoTime Home Page |
Introduction
This document provides a brief description of the SimoLOGS program and a listing of the COBOL source code for viewing.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2024
SimoTime Technologies and Services
All Rights Reserved
What it Does
The SimoLOGS program (or callable routine) will display and/or write a buffer of information to the screen and a log file. The display and/or logging is optional. The default action is to display the information to the system console.
How to Use
The following will cause the SimoLOGS routine to display "Hello World" to the SYSOUT device and write an entry to the SYSLOG file.
MOVE 'Hello World' to SIMOLOGS-MESSAGE
MOVE 'OUT2' to SIMOLOGS-REQUEST
CALL 'SIMOLOGS' using SIMOLOGS-PASS-AREA
In the preceding example the text "Hello World" will be displayed on the screen and written to the log file
A copy file is provided to define the pass area to be used when calling SimoLOGS. The following statement is required in the WORKING STORAGE section of the calling program.
COPY PASSLOGS.
The following is the source code for the copy file that defines the pass area for calling SimoLOGS.
*****************************************************************
* PASSLOGS is a COBOL Copy File *
* Data Structure or Pass Area used for calling SIMOLOGS. *
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
*****************************************************************
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
* SIMOLOGS-REQUEST Type of request, must be one of the *
* following values. *
* BOTH - Display message on the console, *
* Write message to the SYSLOG file. *
* FILE - Write message to the SYSLOG file. *
* NOTE - Display message on the console, *
* Write message to the SYSLOG file. *
* SHOW - Display message on the console. *
* *
* OPR1 - Display message to Console Operator. *
* OPR2 - Display message to Console Operator, *
* write message to the SYSLOG file. *
* OUT1 - Display message to SYSOUT. *
* OUT2 - Display message to SYSOUT, *
* write message to SYSLOG file. *
* LOG1 - Write message to the SYSLOG file. *
* SIMOLOGS-STATUS This is an indicator as to the success *
* or failure of the request. A value of *
* zero (0000) indicates the routine was *
* successful. A non-zero value indicates *
* a failure. *
* SIMOLOGS-MESSAGE Contains the message text. *
*****************************************************************
01 SIMOLOGS-PASS-AREA.
05 SIMOLOGS-REQUEST pic X(4).
05 SIMOLOGS-STATUS pic 9999.
05 SIMOLOGS-MESSAGE pic X(1024).
*** PASSLOGS - End-of-Copy File - - - - - - - - - - - PASSLOGS *
*****************************************************************
*
Note: The maximum length for the message text is 1,024 characters.
The COBOL Source Code
The following (SIMOLOGS.cbl) is the COBOL Source Code.
*set ASSIGN(EXTERNAL) NOOPTIONAL-FILE SEQUENTIAL(LINE)
IDENTIFICATION DIVISION.
PROGRAM-ID. SIMOLOGS.
AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Copyright (C) 1987-2019 SimoTime Technologies. *
* *
* All rights reserved. Unpublished, all rights reserved under *
* copyright law and international treaty. Use of a copyright *
* notice is precautionary only and does not imply publication *
* or disclosure. *
* *
* Permission to use, copy, modify and distribute this software *
* for any non-commercial purpose and without fee is hereby *
* granted, provided the SimoTime copyright notice appear on all *
* copies of the software. The SimoTime name or Logo may not be *
* used in any advertising or publicity pertaining to the use *
* of the software without the written permission of SimoTime *
* Technologies. *
* *
* Permission to use, copy, modify and distribute this software *
* for any commercial purpose requires a fee to be paid to *
* SimoTime Technologies. Once the fee is received by SimoTime *
* the latest version of the software will be delivered and a *
* license will be granted for use within an enterprise, *
* provided the SimoTime copyright notice appear on all copies *
* of the software. The SimoTime name or Logo may not be used *
* in any advertising or publicity pertaining to the use of the *
* software without the written permission of SimoTime *
* Technologies. *
* *
* SimoTime Technologies makes no warranty or representations *
* about the suitability of the software for any purpose. It is *
* provided "AS IS" without any expressed or implied warranty, *
* including the implied warranties of merchantability, fitness *
* for a particular purpose and non-infringement. SimoTime *
* Technologies shall not be liable for any direct, indirect, *
* special or consequential damages resulting from the loss of *
* use, data or projects, whether in an action of contract or *
* tort, arising out of or in connection with the use or *
* performance of this software *
* *
* SimoTime Technologies *
* 15 Carnoustie Drive *
* Novato, CA 94949-5849 *
* 415.883.6565 *
* *
* RESTRICTED RIGHTS LEGEND *
* Use, duplication, or disclosure by the Government is subject *
* to restrictions as set forth in subparagraph (c)(1)(ii) of *
* the Rights in Technical Data and Computer Software clause at *
* DFARS 52.227-7013 or subparagraphs (c)(1) and (2) of *
* Commercial Computer Software - Restricted Rights at 48 *
* CFR 52.227-19, as applicable. Contact SimoTime Technologies, *
* 15 Carnoustie Drive, Novato, CA 94949-5849. *
* *
*****************************************************************
* This program is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
* *
*****************************************************************
* Source Member: SIMOLOGS.CBL
*****************************************************************
*
* SIMOLOGS - Call SIMOLOGS to write record to the Message file.
*
* CALLING PROTOCOL
* ----------------
* Use standard procedure to EXECUTE, RUN or ANIMATE.
*
* DESCRIPTION
* -----------
* This program will write a message to the SYSLOG file.
*
* REQUIREMENTS
* ------------
* The COBOL/390 dialect is required for Y2K date processing.
* The following directives are required for Micro Focus.
* ASSIGN(EXTERNAL) Map COBOL file name to externally defined name
* SEQUENTIAL(LINE) Treat COBOL SEQUENTIAL as a LINE SEQUENTIAL
* NOOPTIONAL-FILE The OPEN EXTEND file must exist or post error
*
*****************************************************************
*
* MAINTENANCE
* -----------
* 1997/12/18 Simmons, Created program.
* 1997/12/18 Simmons, No changes to date.
*
*****************************************************************
*
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
*****************************************************************
SELECT SYSLOG-FILE
ASSIGN to SYSLOG
ORGANIZATION is SEQUENTIAL
ACCESS MODE is SEQUENTIAL
FILE STATUS is SYSLOG-LOG-STATUS.
*****************************************************************
*
DATA DIVISION.
FILE SECTION.
*
*****************************************************************
FD SYSLOG-FILE
DATA RECORD IS SYSLOG-RECORD
RECORDING MODE is V
RECORD is VARYING in SIZE from 64 to 1051
DEPENDING ON MESSAGE-LENGTH.
01 SYSLOG-RECORD.
05 SYSLOG-DAY pic X(3).
05 filler pic X.
05 SYSLOG-DATE pic X(10).
05 filler pic X.
05 SYSLOG-TIME pic X(11).
05 filler pic X.
05 SYSLOG-DATA pic X(1024).
*****************************************************************
WORKING-STORAGE SECTION.
01 SYSLOG-LOG-STATUS.
05 SYSLOG-LOG-STAT1 pic X.
05 SYSLOG-LOG-STAT2 pic X.
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 TWO-BYTES.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 TWO-BYTES-BINARY redefines TWO-BYTES pic 9(4) comp.
01 SYSLOG-OPEN-FLAG pic X value 'N'.
01 FIRST-TIME pic X value 'Y'.
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* SIMOLOGS '.
05 MESSAGE-TEXT pic X(68).
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
01 WORK-04 pic X(4).
01 LINE-LENGTH pic 9(5) value 80.
01 WORK-DATE.
05 WORK-DATE-08 pic X(8).
01 WORK-TIME pic X(8).
01 SYSOUT-LENGTH pic 9(5) value 121.
01 MESSAGE-LENGTH pic 9(5) value 1024.
01 COUNTER-LENGTH pic 9(5) value 1024.
01 DISPLAY-LEN pic 9(5) value 1024.
01 DISPLAY-POS pic 9(5) value 1.
01 LOG-DATE pic X(10) value 'yyyy/nn/nn'.
01 LOG-TIME pic X(11) value 'nn:nn:nn:nn'.
COPY PASSDUMP.
*****************************************************************
LINKAGE SECTION.
COPY PASSLOGS.
*****************************************************************
PROCEDURE DIVISION using SIMOLOGS-PASS-AREA.
add 8 to ZERO giving SIMOLOGS-STATUS
move SIMOLOGS-REQUEST to WORK-04
evaluate WORK-04
* Display to System Operator Console...
when 'OPR1' perform DETERMINE-LENGTH-OF-MESSAGE
perform DISPLAY-SIMOLOGS-MESSAGE
when 'OPR2' perform DETERMINE-LENGTH-OF-MESSAGE
perform WRITE-TO-LOG
perform DISPLAY-SIMOLOGS-MESSAGE
* No Display, Write to SYSLOG File
when 'LOG1' perform DETERMINE-LENGTH-OF-MESSAGE
perform WRITE-TO-LOG
* Display to user-defined SYSOUT device...
when 'OUT1' perform DETERMINE-LENGTH-OF-MESSAGE
perform DISPLAY-SIMOLOGS-MESSAGE
when 'OUT2' perform DETERMINE-LENGTH-OF-MESSAGE
perform WRITE-TO-LOG
perform DISPLAY-SIMOLOGS-MESSAGE
when 'DUMP' perform DUMP-BUFFER
when 'MAKE' add 1 to ZERO giving DISPLAY-POS
add 80 to ZERO giving DISPLAY-LEN
perform SIMOLOGS-OPEN-OUTPUT
perform SIMOLOGS-CLOSE
when OTHER perform DETERMINE-LENGTH-OF-MESSAGE
perform DISPLAY-SIMOLOGS-MESSAGE
end-evaluate
if APPL-AOK
subtract SIMOLOGS-STATUS from SIMOLOGS-STATUS
end-if
GOBACK.
*****************************************************************
DUMP-BUFFER.
perform DETERMINE-LENGTH-OF-MESSAGE
perform WRITE-TO-LOG
exit.
*****************************************************************
DETERMINE-LENGTH-OF-MESSAGE.
add 1024 to ZERO giving MESSAGE-LENGTH
if SIMOLOGS-MESSAGE(513:512) = SPACES
add 512 to ZERO giving MESSAGE-LENGTH
if SIMOLOGS-MESSAGE(257:256) = SPACES
add 256 to ZERO giving MESSAGE-LENGTH
if SIMOLOGS-MESSAGE(129:128) = SPACES
add 128 to ZERO giving MESSAGE-LENGTH
if SIMOLOGS-MESSAGE(65:64) = SPACES
add 64 to ZERO giving MESSAGE-LENGTH
end-if
end-if
else
if SIMOLOGS-MESSAGE(385:128) = SPACES
add 384 to ZERO giving MESSAGE-LENGTH
end-if
end-if
else
if SIMOLOGS-MESSAGE(769:256) = SPACES
add 768 to ZERO giving MESSAGE-LENGTH
else
if SIMOLOGS-MESSAGE(897:128) = SPACES
add 896 to ZERO giving MESSAGE-LENGTH
end-if
end-if
end-if
perform
until MESSAGE-LENGTH = 0
or SIMOLOGS-MESSAGE(MESSAGE-LENGTH:1) not = SPACE
if SIMOLOGS-MESSAGE(MESSAGE-LENGTH:1) = SPACE
subtract 1 from MESSAGE-LENGTH
end-if
end-perform
add MESSAGE-LENGTH to ZERO giving SYSOUT-LENGTH
add 27 to MESSAGE-LENGTH
exit.
*****************************************************************
* Display Messages to SYSOUT Device or SYSTEM Operator Console *
*****************************************************************
DISPLAY-SIMOLOGS-MESSAGE.
add SYSOUT-LENGTH to ZERO giving COUNTER-LENGTH
if WORK-04(1:3) = 'OUT'
add 121 to LINE-LENGTH
else
add 80 to LINE-LENGTH
end-if
add 1 to ZERO giving DISPLAY-POS
perform until COUNTER-LENGTH < 1
if COUNTER-LENGTH > LINE-LENGTH
add LINE-LENGTH to ZERO giving DISPLAY-LEN
else
add COUNTER-LENGTH to ZERO giving DISPLAY-LEN
end-if
perform DISPLAY-SIMOLOGS-MESSAGE-02
add DISPLAY-LEN to DISPLAY-POS
*
if DISPLAY-LEN > ZERO
and DISPLAY-LEN < COUNTER-LENGTH
subtract DISPLAY-LEN from COUNTER-LENGTH
else
move ZERO to COUNTER-LENGTH
end-if
end-perform
exit.
*---------------------------------------------------------------*
DISPLAY-SIMOLOGS-MESSAGE-02.
if work-04(1:3) = 'OUT'
display SIMOLOGS-MESSAGE(DISPLAY-POS:DISPLAY-LEN)
else
display SIMOLOGS-MESSAGE(DISPLAY-POS:DISPLAY-LEN)
upon console
end-if
exit.
*****************************************************************
GET-DATE-AND-TIME.
accept WORK-DATE from DATE YYYYMMDD
accept WORK-TIME from TIME
move WORK-DATE(1:4) to LOG-DATE(1:4)
move WORK-DATE(5:2) to LOG-DATE(6:2)
move WORK-DATE(7:2) to LOG-DATE(9:2)
move WORK-TIME(1:2) to LOG-TIME(1:2)
move WORK-TIME(3:2) to LOG-TIME(4:2)
move WORK-TIME(5:2) to LOG-TIME(7:2)
move WORK-TIME(7:2) to LOG-TIME(10:2)
exit.
*****************************************************************
WRITE-TO-LOG.
if SYSLOG-OPEN-FLAG not = 'Y'
perform SIMOLOGS-OPEN-EXTEND
end-if
if SYSLOG-OPEN-FLAG = 'Y'
perform GET-DATE-AND-TIME
move all SPACES to SYSLOG-RECORD
move '***' to SYSLOG-DAY
move LOG-DATE to SYSLOG-DATE
move LOG-TIME to SYSLOG-TIME
move SIMOLOGS-MESSAGE to SYSLOG-DATA
perform SIMOLOGS-WRITE
perform SIMOLOGS-CLOSE
move 'N' to SYSLOG-OPEN-FLAG
else
move 'Failed to OPEN the SYSLOG File' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
if SIMOLOGS-REQUEST = 'OUT2'
move 'OUT1' to SIMOLOGS-REQUEST
move 'Display messages upon SYSOUT Device'
to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
else
move 'OPR1' to SIMOLOGS-REQUEST
move 'Display messages upon System Operator Console'
to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
end-if
end-if
exit.
*****************************************************************
* I/O ROUTINES TO CREATE THE MESSAGE FILE, SIMOLOGS...
*****************************************************************
SIMOLOGS-WRITE.
if MESSAGE-LENGTH > 1051
add 1051 to MESSAGE-LENGTH giving MESSAGE-LENGTH
end-if
if MESSAGE-LENGTH < 64
add 64 to MESSAGE-LENGTH giving MESSAGE-LENGTH
end-if
write SYSLOG-RECORD.
if SYSLOG-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if SYSLOG-LOG-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if.
if APPL-AOK
CONTINUE
else
move 'FAILED-WRITE, Log file, SYSLOG' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move SYSLOG-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
SIMOLOGS-OPEN-EXTEND.
add 8 to ZERO giving APPL-RESULT.
open EXTEND SYSLOG-FILE
if SYSLOG-LOG-STATUS = '00'
* move 'SYSLOG, Open as EXTEND file' to MESSAGE-TEXT
* perform Z-DISPLAY-CONSOLE-MESSAGE
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSLOG-OPEN-FLAG
else
close SYSLOG-FILE
* move 'SYSLOG, Open as OUTPUT file' to MESSAGE-TEXT
* perform Z-DISPLAY-CONSOLE-MESSAGE
open output SYSLOG-FILE
if SYSLOG-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSLOG-OPEN-FLAG
end-if
end-if
if APPL-AOK
CONTINUE
else
move 'FAILED-OPEN, Log file, SYSLOG' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move SYSLOG-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
SIMOLOGS-OPEN-OUTPUT.
add 8 to ZERO giving APPL-RESULT.
open OUTPUT SYSLOG-FILE
if SYSLOG-LOG-STATUS = '00'
* move 'SYSLOG, Open as OUTPUT file' to MESSAGE-TEXT
* perform Z-DISPLAY-CONSOLE-MESSAGE
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSLOG-OPEN-FLAG
else
close SYSLOG-FILE
* move 'SYSLOG, Open as OUTPUT file' to MESSAGE-TEXT
* perform Z-DISPLAY-CONSOLE-MESSAGE
open output SYSLOG-FILE
if SYSLOG-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'Y' to SYSLOG-OPEN-FLAG
end-if
end-if
if APPL-AOK
CONTINUE
else
move 'FAILED-OPEN, Log file, SYSLOG' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move SYSLOG-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
SIMOLOGS-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close SYSLOG-FILE
if SYSLOG-LOG-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'FAILED-CLOSE, Log file, SYSLOG' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move SYSLOG-LOG-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
* perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative functions *
* for this program. *
*****************************************************************
*****************************************************************
* ABEND the program and return to caller... *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-CONSOLE-MESSAGE
end-if
move 'Writing to log file is ABENDING...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
add 12 to ZERO giving RETURN-CODE
GOBACK.
*****************************************************************
* Display the file status bytes. This routine will display as *
* two digits if the full two byte file status is numeric. If *
* second byte is non-numeric then it will be treated as a *
* binary number. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS NUMERIC
display '* SIMOLOGS FILE-STATUS-' IO-STATUS upon console
else
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
display '* SIMOLOGS FILE-STATUS-'
IO-STAT1 '/' TWO-BYTES-BINARY upon console
end-if
exit.
*****************************************************************
* Display a message generated by this program. *
*****************************************************************
Z-DISPLAY-CONSOLE-MESSAGE.
display MESSAGE-BUFFER upon console
move SPACES to MESSAGE-TEXT
exit.
*****************************************************************
* This example is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The COBOL Copy File
The following (PASSLOGS.cpy) is the COBOL copy file used when calling the SIMOLOGS program.
*****************************************************************
* PASSLOGS is a COBOL Copy File *
* Data Structure or Pass Area used for calling SIMOLOGS. *
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
*****************************************************************
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
* SIMOLOGS-REQUEST Type of request, must be one of the *
* following values. *
* BOTH - Display message on the console, *
* Write message to the SYSLOG file. *
* FILE - Write message to the SYSLOG file. *
* NOTE - Display message on the console, *
* Write message to the SYSLOG file. *
* SHOW - Display message on the console. *
* *
* OPR1 - Display message to Console Operator. *
* OPR2 - Display message to Console Operator, *
* write message to the SYSLOG file. *
* OUT1 - Display message to SYSOUT. *
* OUT2 - Display message to SYSOUT, *
* write message to SYSLOG file. *
* LOG1 - Write message to the SYSLOG file. *
* SIMOLOGS-STATUS This is an indicator as to the success *
* or failure of the request. A value of *
* zero (0000) indicates the routine was *
* successful. A non-zero value indicates *
* a failure. *
* SIMOLOGS-MESSAGE Contains the message text. *
*****************************************************************
01 SIMOLOGS-PASS-AREA.
05 SIMOLOGS-REQUEST pic X(4).
05 SIMOLOGS-STATUS pic 9999.
05 SIMOLOGS-MESSAGE pic X(1024).
*** PASSLOGS - End-of-Copy File - - - - - - - - - - - PASSLOGS *
*****************************************************************
*
Summary
This document provides a brief description of the SimoLOGS program and a listing of the COBOL source code for viewing. This document may be used as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact, Comment or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first group of documents may be available from a local system or via an internet connection, the second group of documents will require an internet connection.
Note: A SimoTime License is required for the items to be made available on a local system or server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Note: The latest versions of the SimoTime Documents and Program Suites are available on the Internet and may be accessed using the 
icon. If a user has a SimoTime Enterprise License the Documents and Program Suites may be available on a local server and accessed using the 
icon.
Explore the COBOL Connection for more examples of COBOL programming techniques and sample code.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available to download for review and evaluation purposes. Other uses will require a SimoTime Software License. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Comments or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| Trace or Display Function using COBOL |
| Copyright © 1987-2024 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |