Fixed Sequential to ZOS v4-32760
|
CBLVLRC2, File Convert Fixed Sequential to ZOS v4-32760 |
|
| The SimoTime Home Page |
Introduction
This document includes the COBOL source code for the program that does a file format convert of a record sequential file with 80 bytes fixed length records to a mainframe (or ZOS) formatted sequential file with variable length records with the size varying from 4 to 32,760 bytes. The logical record content is the same for both files.
We have made a significant effort to ensure the documents and software technologies are correct and accurate. We reserve the right to make changes without notice at any time. The function delivered in this version is based upon the enhancement requests from a specific group of users. The intent is to provide changes as the need arises and in a timeframe that is dependent upon the availability of resources.
Copyright © 1987-2025
SimoTime Technologies and Services
All Rights Reserved
The COBOL Program
The following source code (CBLVLRC2.cbl) is the COBOL program that does file format conversion
IDENTIFICATION DIVISION.
PROGRAM-ID. CBLVLRC2.
*AUTHOR. SIMOTIME TECHNOLOGIES.
*****************************************************************
* Source Member: CBLVLRC2.CBL
* Copy Files: PASSBSIO.CPY
* ASCEBCB1.CPY
* Calls to: SIMOBSIO
*****************************************************************
*
* ************
* * CBLVLRC2 *
* ********cmd*
* *
* ************
* * if exist *
* ********stmt*
* *
* ************ ************ ************
* * ALPHARSE *-----* CBLVLRC2 *-----* BSIODSN1 *
* *******rseq* ********cbl* ********zos*
* * *
* * * ************
* * *-call--* SIMOBSIO *
* * ********cbl*
* *
* ************
* * EOJ *
* ************
*
*****************************************************************
ENVIRONMENT DIVISION.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
SELECT ALPHARSE-FILE ASSIGN to ALPHARSE
ORGANIZATION is SEQUENTIAL
ACCESS MODE is SEQUENTIAL
FILE STATUS is ALPHARSE-STATUS.
*****************************************************************
DATA DIVISION.
FILE SECTION.
FD ALPHARSE-FILE
DATA RECORD is ALPHARSE-RECORD.
01 ALPHARSE-RECORD.
05 ALPHARSE-DATA-01 pic X(80).
*****************************************************************
WORKING-STORAGE SECTION.
01 SIM-TITLE.
05 T1 pic X(11) value '* CBLVLRC2 '.
05 T2 pic X(34) value 'RSEQ-F80-EBC to BSIO-4-32760-EBC '.
05 T3 pic X(10) value ' v08.03.04'.
05 T4 pic X(24) value ' http://www.simotime.com'.
01 SIM-COPYRIGHT.
05 C1 pic X(11) value '* CBLVLRC2 '.
05 C2 pic X(20) value 'Copyright 1987-2018 '.
05 C3 pic X(28) value ' SimoTime Technologies '.
05 C4 pic X(20) value ' All Rights Reserved'.
01 SIM-THANKS-01.
05 C1 pic X(11) value '* CBLVLRC2 '.
05 C2 pic X(32) value 'Thank you for using this sample '.
05 C3 pic X(32) value 'by SimoTime Technologies '.
05 C4 pic X(04) value ' '.
01 SIM-THANKS-02.
05 C1 pic X(11) value '* CBLVLRC2 '.
05 C2 pic X(32) value 'Please send comments or suggesti'.
05 C3 pic X(32) value 'ons to helpdesk@simotime.com '.
05 C4 pic X(04) value ' '.
01 MESSAGE-BUFFER.
05 MESSAGE-HEADER pic X(11) value '* CBLVLRC2 '.
05 MESSAGE-TEXT.
10 MESSAGE-TEXT-1 pic X(68) value SPACES.
10 MESSAGE-TEXT-2 pic X(188) value SPACES.
01 ALPHARSE-STATUS.
05 ALPHARSE-STATUS-L pic X.
05 ALPHARSE-STATUS-R pic X.
01 ALPHARSE-EOF pic X value 'N'.
01 ALPHARSE-OPEN-FLAG pic X value 'C'.
01 IO-STATUS.
05 IO-STAT1 pic X.
05 IO-STAT2 pic X.
01 TWO-BYTES.
05 TWO-BYTES-LEFT pic X.
05 TWO-BYTES-RIGHT pic X.
01 TWO-BYTES-BINARY redefines TWO-BYTES pic 9(4) comp.
*****************************************************************
* Data-structure for environment variable get routine... *
*****************************************************************
01 ENV-VAR-NAME pic X(16) value SPACES.
01 ENV-VAR-VALUE pic X(256) value SPACES.
01 PROGRAM-COMMAND-LINE pic x(256) value SPACES.
01 APPL-RESULT pic S9(9) comp.
88 APPL-AOK value 0.
88 APPL-EOF value 16.
01 DEBUG-LEVEL pic 9(2) value 2.
01 FILE-TYPE pic X(3) value 'V '.
01 TEXT-LENGTH pic 9(5) value 0.
01 VARIABLE-RECORD-HEADER.
05 VREC-HDR-1 pic 9(3) COMP VALUE 0.
05 VREC-HDR-2 pic 9(3) COMP VALUE 0.
01 RECORD-LENGTH-DISPLAY.
05 filler pic X(15) value 'Record length: '.
05 RECORD-LENGTH-VALUE pic 9(5) value 0.
01 RECORD-MIN-DISPLAY.
05 filler pic X(15) value 'Record MIN is: '.
05 RECORD-MIN-VALUE pic 9(4) value 0.
01 RECORD-MAX-DISPLAY.
05 filler pic X(15) value 'Record MAX is: '.
05 RECORD-MAX-VALUE pic 9(4) value 0.
01 BSIOPUT1-TOTAL.
05 filler pic X(23) value 'BSIOID01 line count is '.
05 BSIOPUT1-COUNT pic 9(7) value 0.
01 ALPHARSE-TOTAL.
05 filler pic X(23) value 'ALPHARSE line count is '.
05 ALPHARSE-LOC pic 9(7) value 0.
*****************************************************************
* The following copy file is the pass area for calling SIMOBSIO,
* the byte stream I/O routine.
*****************************************************************
*
COPY PASSBSIO.
*
*****************************************************************
* The following copy file is the ASCII and EBCDIC conversion
* tables. The tables may also be used UPPER/lower case converts.
*****************************************************************
COPY ASCEBCB1.
*
*****************************************************************
PROCEDURE DIVISION.
perform Z-POST-COPYRIGHT
* Get the fully qualified File Name
move SPACES to ENV-VAR-NAME
move 'BSIODSN1' to ENV-VAR-NAME
perform GET-ENVIRONMENT-VARIABLE
if ENV-VAR-VALUE not = SPACES
move ENV-VAR-VALUE to PSIO-FILENAME
else
move 'Invalid file name for BSIO Function'
to MESSAGE-TEXT
perform Z-ABEND-PROGRAM
end-if
* Get the File Format, should be V or VB
move SPACES to ENV-VAR-NAME
move 'BSIOFMT1' to ENV-VAR-NAME
perform GET-ENVIRONMENT-VARIABLE
inspect ENV-VAR-VALUE converting 'bv' to 'BV'
if ENV-VAR-VALUE = 'V '
or ENV-VAR-VALUE = 'VB '
move ENV-VAR-VALUE to FILE-TYPE
else
move 'V ' to FILE-TYPE
move 'File Format must be V or VB'
to MESSAGE-TEXT
perform Z-ABEND-PROGRAM
end-if
add 80 to zero giving PSIO-MAX-SIZE
perform ALPHARSE-OPEN
perform BSIO-OPEN-PUT
evaluate FILE-TYPE
when 'V ' perform BSIO-PUT-VREC4-V
when 'VB ' perform BSIO-PUT-VREC4-V
when other move 'Invalid File Type, must be V or VB'
to MESSAGE-TEXT
perform Z-ABEND-PROGRAM
end-evaluate
perform BSIO-CLOSE
perform ALPHARSE-CLOSE
move BSIOPUT1-TOTAL to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
perform Z-THANK-YOU.
GOBACK.
*****************************************************************
* I/O ROUTINES FOR BYTE-Stream I/O... *
*****************************************************************
BSIO-PUT-VREC4-V.
move ZERO to PSIO-OFFSET
move 'WRITE ' to PSIO-REQUEST
perform until ALPHARSE-STATUS not = '00'
perform ALPHARSE-READ
if ALPHARSE-STATUS = '00'
perform CALCULATE-STRING-LENGTH
add TEXT-LENGTH to 4 giving VREC-HDR-1
move VARIABLE-RECORD-HEADER to PSIO-BUFFER(1:4)
move ALPHARSE-RECORD to PSIO-BUFFER(5:TEXT-LENGTH)
add TEXT-LENGTH to 4 giving PSIO-LENGTH
call 'SIMOBSIO' using PSIO-PASS-AREA
add PSIO-LENGTH to PSIO-OFFSET
add 1 to BSIOPUT1-COUNT
end-if
end-perform
exit.
*---------------------------------------------------------------*
BSIO-OPEN-PUT.
move 'CREATE ' to PSIO-REQUEST
call 'SIMOBSIO' using PSIO-PASS-AREA
* move 'OPENPUT ' to PSIO-REQUEST
* call 'SIMOBSIO' using PSIO-PASS-AREA
move PSIO-FILENAME to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
if PSIO-RETURN = 0
move 'AOK, OPEN Input File for BSIO' to MESSAGE-TEXT
else
move 'NOK, OPEN Input File FAILURE ' to MESSAGE-TEXT
perform Z-ABEND-PROGRAM
end-if
perform Z-DISPLAY-CONSOLE-MESSAGE
exit.
*---------------------------------------------------------------*
BSIO-CLOSE.
move 'FILEINFO' to PSIO-REQUEST
call 'SIMOBSIO' using PSIO-PASS-AREA
if PSIO-RETURN = 0
move 'AOK, File Info Request for BSIO' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move PSIO-FILE-SIZE to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
else
move 'NOK, File Info Request FAILURE ' to MESSAGE-TEXT
perform Z-ABEND-PROGRAM
end-if
move 'CLOSE ' to PSIO-REQUEST
call 'SIMOBSIO' using PSIO-PASS-AREA
exit.
*****************************************************************
CALCULATE-STRING-LENGTH.
add 80 to ZERO giving TEXT-LENGTH
perform until TEXT-LENGTH = 0
or ALPHARSE-RECORD(TEXT-LENGTH:1) not = X'40'
if ALPHARSE-RECORD(TEXT-LENGTH:1) = X'40'
subtract 1 from TEXT-LENGTH
end-if
end-perform
exit.
*****************************************************************
* Get an environment variable. *
*****************************************************************
GET-ENVIRONMENT-VARIABLE.
move SPACES to ENV-VAR-VALUE
accept ENV-VAR-VALUE from ENVIRONMENT ENV-VAR-NAME
on exception add 8 to ZERO giving RETURN-CODE
end-accept
if RETURN-CODE not = 0
move SPACES to ENV-VAR-VALUE
end-if
exit.
*****************************************************************
* I/O ROUTINES FOR ALPHARSE... *
*****************************************************************
ALPHARSE-CLOSE.
add 8 to ZERO giving APPL-RESULT.
close ALPHARSE-FILE
if ALPHARSE-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'ALPHARSE-Failure-CLOSE...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move ALPHARSE-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*---------------------------------------------------------------*
ALPHARSE-READ.
read ALPHARSE-FILE
if ALPHARSE-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
else
if ALPHARSE-STATUS = '10'
add 16 to ZERO giving APPL-RESULT
else
add 12 to ZERO giving APPL-RESULT
end-if
end-if
if APPL-AOK
CONTINUE
else
if APPL-EOF
move 'Y' to ALPHARSE-EOF
else
move 'ALPHARSE-Failure-GET...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move ALPHARSE-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
end-if
exit.
*---------------------------------------------------------------*
ALPHARSE-OPEN.
add 8 to ZERO giving APPL-RESULT.
open input ALPHARSE-FILE
if ALPHARSE-STATUS = '00'
subtract APPL-RESULT from APPL-RESULT
move 'O' to ALPHARSE-OPEN-FLAG
else
add 12 to ZERO giving APPL-RESULT
end-if
if APPL-AOK
CONTINUE
else
move 'ALPHARSE-Failure-OPEN...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
move ALPHARSE-STATUS to IO-STATUS
perform Z-DISPLAY-IO-STATUS
perform Z-ABEND-PROGRAM
end-if
exit.
*****************************************************************
* The following Z-Routines perform administrative tasks *
* for this program. *
*****************************************************************
* ABEND the program, post a message to the console and issue *
* a STOP RUN. *
*****************************************************************
Z-ABEND-PROGRAM.
if MESSAGE-TEXT not = SPACES
perform Z-DISPLAY-CONSOLE-MESSAGE
end-if
move 'PROGRAM-IS-ABENDING...' to MESSAGE-TEXT
perform Z-DISPLAY-CONSOLE-MESSAGE
add 12 to ZERO giving RETURN-CODE
STOP RUN.
* exit.
*****************************************************************
* Display CONSOLE messages... *
*****************************************************************
Z-DISPLAY-CONSOLE-MESSAGE.
if MESSAGE-TEXT-2 = SPACES
display MESSAGE-BUFFER(1:79)
else
display MESSAGE-BUFFER
end-if
move all SPACES to MESSAGE-TEXT
exit.
*****************************************************************
* Display the file status bytes. This routine will display as *
* two digits if the full two byte file status is numeric. If *
* second byte is non-numeric then it will be treated as a *
* binary number. *
*****************************************************************
Z-DISPLAY-IO-STATUS.
if IO-STATUS not NUMERIC
or IO-STAT1 = '9'
subtract TWO-BYTES-BINARY from TWO-BYTES-BINARY
move IO-STAT2 to TWO-BYTES-RIGHT
display '* CBLVLRC2 File-Status-' IO-STAT1 '/'
TWO-BYTES-BINARY
else
display '* CBLVLRC2 File-Status-' IO-STATUS
end-if
exit.
*****************************************************************
Z-POST-COPYRIGHT.
display SIM-TITLE
display SIM-COPYRIGHT
exit.
*****************************************************************
Z-THANK-YOU.
display SIM-THANKS-01
display SIM-THANKS-02
exit.
*****************************************************************
* This example is provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
The COBOL Copy Files
The following are the COBOL copy files used by the program.
COBOL Copy File, ASCEBCB1
The following (ASCEBCB1.cpy) is the source code for the copy file that defines an ASCII table and an EBCDIC table that are used for data conversion(between ASCII and EBCIDC) and case conversion (between upper and lower case).
*****************************************************************
* AE9437B1.cpy - a COBOL Copy File *
* Copyright (C) 1987-2018 SimoTime Technologies *
* All Rights Reserved *
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
* The following tables are used by the INSPECT statement to do *
* the conversion between EBCDIC and ASCII. *
* *
* inspect FIELD-NAME converting EBCDIC-INFO to ASCII-INFO *
* inspect FIELD-NAME converting ASCII-INFO to EBCDIC-INFO *
* *
* The tables include the alphabet for upper and lower case, the *
* digits 0-9, the special characters (US) and the alternate *
* codes for A, E, I, O, and U with the appropriate acute, *
* grave, umlaut, circumflex and tilde. *
* To display the alternate codes the Courier New (Fixed) or *
* Times New Roman (Proportional) font should be used. *
* *
* SimoZAPS contains four tables that may be used for various *
* Upper/Lower Case or EBCDIC/ASCII conversion requirements. *
* ASCEBCB1.CPY - includes a full character set for the alphabet *
* (upper/lower case), digit, special characters *
* and alternate codes for characters with the *
* acute, grave, umlaut, tilde and circumflex. *
* Caution: this table does not convert the Y *
* characters with an umlat. *
* ASCEBCB2.CPY - includes the character set for the translation *
* between EBCDIC/ASCII of signed/unsigned, *
* zoned-decimal, numeric fields. *
* ASCEBCB3.CPY - includes the character set for the alternate *
* codes with the acute, grave, umlaut, tilde and *
* circumflex. This is primarily used for case *
* conversion. *
* Note: this table converts the Y characters *
* with an umlat, this will convert high-values *
* X'FF' to X'DF' *
* ASCEBCB4.CPY - includes the character set for the alphabet *
* (upper/lower case), digit, special characters. *
* This is primarily used in the US where the *
* alternate codes may not be required. *
* ASCEBCB5.CPY - includes a full character set for the alphabet *
* (upper/lower case), digit, special characters *
* and alternate codes for characters with the *
* acute, grave, umlaut, tilde and circumflex. *
* Caution: this table will convert the Y *
* characters with an umlat. *
*****************************************************************
*
* ------------------------------------------------------------
01 EBCDIC-DATA.
05 FILLER pic X(16)
value X'000102030405060708090A0B0C0D0E0F'. 000-015
05 FILLER pic X(16)
value X'101112131415161718191A1B1C1D1E1F'. 016-031
05 FILLER pic X(16)
value X'202122232425262728292A2B2C2D2E2F'. 032-047
05 FILLER pic X(16)
value X'303132333435363738393A3B3C3D3E3F'. 048-063
05 FILLER pic X(16)
value X'404142434445464748494A4B4C4D4E4F'. 064-079
05 FILLER pic X(16)
value X'505152535455565758595A5B5C5D5E5F'. 080=095
05 FILLER pic X(16)
value X'606162636465666768696A6B6C6D6E6F'. 096-111
05 FILLER pic X(16)
value X'707172737475767778797A7B7C7D7E7F'. 112-127
05 FILLER pic X(16)
value X'808182838485868788898A8B8C8D8E8F'. 128-143
05 FILLER pic X(16)
value X'909192939495969798999A9B9C9D9E9F'. 144-159
05 FILLER pic X(16)
value X'A0A1A2A3A4A5A6A7A8A9AAABACADAEAF'. 160-175
05 FILLER pic X(16)
value X'B0B1B2B3B4B5B6B7B8B9BABBBCBDBEBF'. 176-191
05 FILLER pic X(16)
value X'C0C1C2C3C4C5C6C7C8C9CACBCCCDCECF'. 192-207
05 FILLER pic X(16)
value X'D0D1D2D3D4D5D6D7D8D9DADBDCDDDEDF'. 208-223
05 FILLER pic X(16)
value X'E0E1E2E3E4E5E6E7E8E9EAEBECEDEEEF'. 224-239
05 FILLER pic X(16)
value X'F0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFF'. 240-255
01 E-INFO redefines EBCDIC-DATA pic X(256).
01 EBCDIC-TABLE redefines EBCDIC-DATA.
05 EBCDIC-BYTE pic X occurs 256 times.
*
* ------------------------------------------------------------
01 ASCII-DATA.
05 FILLER pic X(16)
value X'000102039C09867F978D8E0B0C0D0E0F'. 000-015
05 FILLER pic X(16)
value X'101112139D8508871819928F1C1D1E1F'. 016-031
05 FILLER pic X(16)
value X'80818283840A171B88898A8B8C050607'. 032-047
05 FILLER pic X(16)
value X'909116939495960498999A9B14159E1A'. 048-063
05 FILLER pic X(16)
value X'20A0E2E4E0E1E3E5E7F1A22E3C282B7C'. 064-079
05 FILLER pic X(16)
value X'26E9EAEBE8EDEEEFECDF21242A293BAC'. 080=095
05 FILLER pic X(16)
value X'2D2FC2C4C0C1C3C5C7D1A62C255F3E3F'. 096-111
05 FILLER pic X(16)
value X'F8C9CACBC8CDCECFCC603A2340273D22'. 112-127
05 FILLER pic X(16)
value X'D8616263646566676869ABBBF0FDFEB1'. 128-143
05 FILLER pic X(16)
value X'B06A6B6C6D6E6F707172AABAE6B8C6A4'. 144-159
05 FILLER pic X(16)
value X'B57E737475767778797AA1BFD0DDDEAE'. 160-175
05 FILLER pic X(16)
value X'5EA3A5B7A9A7B6BCBDBE5B5DAFA8B4D7'. 176-191
05 FILLER pic X(16)
value X'7B414243444546474849ADF4F6F2F3F5'. 192-207
05 FILLER pic X(16)
value X'7D4A4B4C4D4E4F505152B9FBFCF9FAFF'. 208-223
05 FILLER pic X(16)
value X'5CF7535455565758595AB2D4D6D2D3D5'. 224-239
05 FILLER pic X(16)
value X'30313233343536373839B3DBDCD9DAFF'. 240-255
01 A-INFO redefines ASCII-DATA pic X(256).
01 ASCII-TABLE redefines ASCII-DATA.
05 ASCII-BYTE pic X occurs 256 times.
*
*** AE0437B1 - End-of-Copy File - - - - - - - - - - - AE0437B1 *
*****************************************************************
*
COBOL Copy File, PASSBSIO
The following (PASSBSIO.cpy) is the source code for the copy file that defines the data structure of the pass area used to call SIMOBSIO.
*****************************************************************
* PASSBSIO is a COBOL Copy File *
* Data Structure or Pass Area used for calling SIMOBSIO. *
* Copyright (C) 1987-2019 SimoTime Technologies *
* All Rights Reserved *
*****************************************************************
* Provided by SimoTime Technologies *
* Our e-mail address is: helpdesk@simotime.com *
* Also, visit our Web Site at http://www.simotime.com *
*****************************************************************
*
01 PSIO-PASS-AREA.
05 PSIO-REQUEST pic X(8).
05 PSIO-RETURN pic 9(4).
05 PSIO-FILENAME pic X(256).
05 PSIO-FILE-SIZE pic 9(12).
05 PSIO-OFFSET pic 9(12).
05 PSIO-LENGTH pic 9(7).
05 PSIO-MAX-SIZE pic 9(7).
05 PSIO-BUFFER pic X(32760).
*
*** PASSBSIO - End-of-Copy File - - - - - - - - - - - PASSBSIO *
*****************************************************************
*
Summary
This program does a file format convert of a record sequential file with 80 bytes fixed length records to a mainframe (or ZOS) formatted sequential file with variable length records with the size varying from 4 to 32,760 bytes. The purpose of this document is to assist as a tutorial for new programmers or as a quick reference for experienced programmers.
In the world of programming there are many ways to solve a problem. This documentation and software were developed and tested on systems that are configured for a SIMOTIME environment based on the hardware, operating systems, user requirements and security requirements. Therefore, adjustments may be needed to execute the jobs and programs when transferred to a system of a different architecture or configuration.
SIMOTIME Services has experience in moving or sharing data or application processing across a variety of systems. For additional information about SIMOTIME Services or Technologies please contact us using the information in the Contact or Feedback section of this document.
Software Agreement and Disclaimer
Permission to use, copy, modify and distribute this software, documentation or training material for any purpose requires a fee to be paid to SimoTime Technologies. Once the fee is received by SimoTime the latest version of the software, documentation or training material will be delivered and a license will be granted for use within an enterprise, provided the SimoTime copyright notice appear on all copies of the software. The SimoTime name or Logo may not be used in any advertising or publicity pertaining to the use of the software without the written permission of SimoTime Technologies.
SimoTime Technologies makes no warranty or representations about the suitability of the software, documentation or learning material for any purpose. It is provided "AS IS" without any expressed or implied warranty, including the implied warranties of merchantability, fitness for a particular purpose and non-infringement. SimoTime Technologies shall not be liable for any direct, indirect, special or consequential damages resulting from the loss of use, data or projects, whether in an action of contract or tort, arising out of or in connection with the use or performance of this software, documentation or training material.
Downloads and Links
This section includes links to documents with additional information that are beyond the scope and purpose of this document. The first sub-section requires an internet connection, the second sub-section references locally available documents.
Note: A SimoTime License is required for the items to be made available on a local server.
Current Server or Internet Access
The following links may be to the current server or to the Internet.
Explore How to FTP (using BINARY mode) a File with Variable Length Records from a Mainframe System to a Windows System and then convert the Mainframe format to a Micro Focus format. The mainline program will call the SIMOVREC and SIMOBSIO modules that are available from SimoTime in a separate package.
Explore The ASCII and EBCDIC Translation Tables. These tables are provided for individuals that need to better understand the bit structures and differences of the encoding formats.
Explore The File Status Return Codes that are used to interpret the results of accessing VSAM data sets and/or QSAM files.
Explore the File Formats and various Numeric Formats being used in a multi-system complex consisting of Mainframe (z/OS), Linux, UNIX or Windows systems.
Internet Access Required
The following links will require an internet connect.
This suite of programs and documentation is available for download. Link to an Evaluation zPAK Option that includes the program members, documentation and control files.
Explore The Micro Focus Web Site for more information about products (including Micro Focus COBOL) and services available from Micro Focus. This link requires an Internet Connection.
A good place to start is The SimoTime Home Page for access to white papers, program examples and product information. This link requires an Internet Connection
Glossary of Terms
Explore the Glossary of Terms for a list of terms and definitions used in this suite of documents and white papers.
Contact or Feedback
This document was created and is maintained by SimoTime Technologies. If you have any questions, suggestions, comments or feedback please use the following contact information.
| 1. | Send an e-mail to our helpdesk. |
| 1.1. | helpdesk@simotime.com. |
| 2. | Our telephone numbers are as follows. |
| 2.1. | 1 415 763-9430 office-helpdesk |
| 2.2. | 1 415 827-7045 mobile |
We appreciate hearing from you.
Company Overview
SimoTime Technologies was founded in 1987 and is a privately owned company. We specialize in the creation and deployment of business applications using new or existing technologies and services. We have a team of individuals that understand the broad range of technologies being used in today's environments. Our customers include small businesses using Internet technologies to corporations using very large mainframe systems.
Quite often, to reach larger markets or provide a higher level of service to existing customers it requires the newer Internet technologies to work in a complementary manner with existing corporate mainframe systems. We specialize in preparing applications and the associated data that are currently residing on a single platform to be distributed across a variety of platforms.
Preparing the application programs will require the transfer of source members that will be compiled and deployed on the target platform. The data will need to be transferred between the systems and may need to be converted and validated at various stages within the process. SimoTime has the technology, services and experience to assist in the application and data management tasks involved with doing business in a multi-system environment.
Whether you want to use the Internet to expand into new market segments or as a delivery vehicle for existing business functions simply give us a call or check the web site at http://www.simotime.com
| Return-to-Top |
| COBOL program for File Format Conversion |
| Copyright © 1987-2025 SimoTime Technologies and Services All Rights Reserved |
| When technology complements business |
| http://www.simotime.com |