@echo OFF
     set JOB_NAME=PUWHXDW3
rem  * *******************************************************************
rem  *        This Job Script is provided by SimoTime Technologies       *
rem  *           (C) Copyright 1987-2020 All Rights Reserved             *
rem  *             Web Site URL:   http://www.simotime.com               *
rem  *                   e-mail:   helpdesk@simotime.com                 *
rem  * *******************************************************************
rem  *
rem  * Text   - Create a Hex-Dump of a Record Sequential file.
rem  * Author - SimoTime Technologies
rem  * Date   - January 24, 1996
rem  *
rem  * The program executed by this job will read a Record Sequential
rem  * File (RSEQ) containing fixed length records of 1024 bytes.
rem  * The record content consist of concatenated text data strings
rem  * and numeric values that are stored in a Packed-Decimal.
rem  *
rem  *    Numeric Type             COBOL Notation
rem  *    --------------------     ---------------------------------------
rem  * 1. Signed-Zoned-Decimal ... USAGE IS DISPLAY
rem  * 2. Packed-Decimal ......... USAGE IS COMP-3
rem  * 3. Binary ................. USAGE IS COMP
rem  *
rem  * The HEX-Dump information will be written to a new ASCII-encoded
rem  * line sequential or ASCII/Text File. The HEX-Dump information is
rem  * provided in a text format with HTML tags and may be viewed with
rem  * a browser of choice.
rem  * *******************************************************************
rem  *
     call ..\ENV1BASE
     set JOB_STATUS=0
rem  *
     call SIMONOTE "*******************************************************************************%JOB_NAME% "
     call SIMONOTE "* Starting JobName %JOB_NAME%, User is %USERNAME%"
     call SIMONOTE "* Job_Step 01 of 04, Preparing the System and Job environments"
     set SYSOUT=%BaseLib1%\LOGS\SYSOUT_%JOB_NAME%.txt
rem  *
     call SIMONOTE "* --------------------------------------------------------------------------- *"
     call SIMONOTE "* Job_Step 02 of 04, Execute REC_DUMP Program for EBC File"
     set SYSUT1=%BaseLib1%\DATA\EBC1\NVPUWDD1.DAT
     set SYSUT3=%BaseLib1%\PARMLIB\HX1KRST1.txt
     set SYSLUSER=%BaseLib1%\LOGS\hex_nvpuwdd1_ebc.htm
     if exist %SYSLUSER% del %SYSLUSER%
     call SIMONOTE "* DataTake SYSUT1=%SYSUT1% "
     call SIMONOTE "* SYSLUSER %SYSLUSER% "
     call SIMONOTE "* DataCNTL SYSUT3=%SYSUT3% "
     run HX1KRSC3
     if not "%ERRORLEVEL%" == "0" set JOB_STATUS=20
     if not "%JOB_STATUS%" == "0" goto EOJTAG
     if not exist %SYSLUSER% set JOB_STATUS=22
     if not "%JOB_STATUS%" == "0" goto EOJTAG
rem  *
     call SIMONOTE "* --------------------------------------------------------------------------- *"
     call SIMONOTE "* Job_Step 03 of 04, Execute REC_DUMP Program for ASC File"
     set SYSUT1=%BaseLib1%\DATA\ASC1\NVPUWDD1.DAT
     set SYSUT3=%BaseLib1%\PARMLIB\HX1KRST1.txt
     set SYSLUSER=%BaseLib1%\LOGS\hex_nvpuwdd1_asc.htm
     if exist %SYSLUSER% del %SYSLUSER%
     call SIMONOTE "* DataTake SYSUT1=%SYSUT1% "
     call SIMONOTE "* SYSLUSER %SYSLUSER% "
     call SIMONOTE "* DataCNTL SYSUT3=%SYSUT3% "
     run HX1KRSC3
     if not "%ERRORLEVEL%" == "0" set JOB_STATUS=30
     if not "%JOB_STATUS%" == "0" goto EOJTAG
     if not exist %SYSLUSER% set JOB_STATUS=32
     if not "%JOB_STATUS%" == "0" goto EOJTAG
rem  *
:EOJTAG
     call SIMONOTE "* --------------------------------------------------------------------------- *"
     call SIMONOTE "* JOB_STEP 04 of 04, End of Job Processing"
     call SIMONOTE "* SIMONOTE Job Log is %SIMONOTE% "
     if "%JOB_STATUS%" == "0" goto EOJAOK
:EOJNOK
     call SIMONOTE "* ABENDING JOB_STATUS=%JOB_STATUS% JobName %JOB_NAME% "
     goto :EOJEND
:EOJAOK
     call SIMONOTE "* Finished JOB_STATUS=%JOB_STATUS% JobName %JOB_NAME% "
     goto :EOJEND
:EOJEND
     call SIMONOTE "* Conclude SYSOUT is %SYSOUT% "
     if not "%1" == "nopause" pause
     exit /B %JOB_STATUS%